script/public-inbox-index

   1 #!perl -w
   2 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a public-inbox.
   5 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   6 # highly recommended: eatmydata public-inbox-index INBOX_DIR
   7
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 my $usage = 'public-inbox-index [options] INBOX_DIR';
  12 my $help = <<EOF; # the following should fit w/o scrolling in 80x24 term:
  13 usage: $usage
  14
  15   Create and update search indices
  16
  17 options:
  18
  19   --no-fsync          speed up indexing, risk corruption on power outage
  20   -L LEVEL            `basic', `medium', or `full' (default: full)
  21   --compact | -c      run public-inbox-compact(1) after indexing
  22   --sequential-shard  index Xapian shards sequentially for slow storage
  23   --jobs=NUM          set or disable parallelization (NUM=0)
  24   --batch-size=BYTES  flush changes to OS after a given number of bytes
  25   --max-size=BYTES    do not index messages larger than the given size
  26   --reindex           index previously indexed data (if upgrading)
  27   --rethread          regenerate thread IDs (if upgrading, use sparingly)
  28   --prune             prune git storage on discontiguous history
  29   --verbose | -v      increase verbosity (may be repeated)
  30   --help | -?         show this help
  31
  32 BYTES may use `k', `m', and `g' suffixes (e.g. `10m' for 10 megabytes)
  33 See public-inbox-index(1) man page for full documentation.
  34 EOF
  35 my $opt = { quiet => -1, compact => 0, max_size => undef, fsync => 1 };
  36 GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune
  37                 fsync|sync! xapian_only|xapian-only
  38                 indexlevel|index-level|L=s max_size|max-size=s
  39                 batch_size|batch-size=s
  40                 sequential_shard|seq-shard|sequential-shard
  41                 help|?))
  42         or die "bad command-line args\n$usage";
  43 if ($opt->{help}) { print $help; exit 0 };
  44 die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;
  45 if ($opt->{xapian_only} && !$opt->{reindex}) {
  46         die "--xapian-only requires --reindex\n";
  47 }
  48
  49 # require lazily to speed up --help
  50 require PublicInbox::Admin;
  51 PublicInbox::Admin::require_or_die('-index');
  52
  53 my $cfg = PublicInbox::Config->new; # Config is loaded by Admin
  54 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, undef, $cfg);
  55 PublicInbox::Admin::require_or_die('-index');
  56 unless (@ibxs) { print STDERR "Usage: $usage\n"; exit 1 }
  57
  58 my $mods = {};
  59 foreach my $ibx (@ibxs) {
  60         # XXX: users can shoot themselves in the foot, with opt->{indexlevel}
  61         $ibx->{indexlevel} //= $opt->{indexlevel} // ($opt->{xapian_only} ?
  62                         'full' : PublicInbox::Admin::detect_indexlevel($ibx));
  63         PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
  64 }
  65
  66 PublicInbox::Admin::require_or_die(keys %$mods);
  67 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
  68 local %ENV = (%ENV, %$env) if $env;
  69 require PublicInbox::InboxWritable;
  70 PublicInbox::Admin::progress_prepare($opt);
  71 for my $ibx (@ibxs) {
  72         $ibx = PublicInbox::InboxWritable->new($ibx);
  73         if ($opt->{compact} >= 2) {
  74                 PublicInbox::Xapcmd::run($ibx, 'compact', $opt->{compact_opt});
  75         }
  76         $ibx->{-no_fsync} = 1 if !$opt->{fsync};
  77
  78         my $ibx_opt = $opt;
  79         if (defined(my $s = $ibx->{lc('indexSequentialShard')})) {
  80                 defined(my $v = $cfg->git_bool($s)) or die <<EOL;
  81 publicInbox.$ibx->{name}.indexSequentialShard not boolean
  82 EOL
  83                 $ibx_opt = { %$opt, sequential_shard => $v };
  84         }
  85         PublicInbox::Admin::index_inbox($ibx, undef, $ibx_opt);
  86         if (my $copt = $opt->{compact_opt}) {
  87                 local $copt->{jobs} = 0 if $ibx_opt->{sequential_shard};
  88                 PublicInbox::Xapcmd::run($ibx, 'compact', $copt);
  89         }
  90 }