script/public-inbox-index

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a public-inbox.
   5 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   6 # highly recommended: eatmydata public-inbox-index INBOX_DIR
   7
   8 use strict;
   9 use warnings;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 my $usage = "public-inbox-index INBOX_DIR";
  12 use PublicInbox::Admin;
  13 PublicInbox::Admin::require_or_die('-index');
  14 use PublicInbox::Xapcmd;
  15
  16 my $compact_opt;
  17 my $opt = { quiet => -1, compact => 0, maxsize => undef };
  18 GetOptions($opt, qw(verbose|v+ reindex compact|c+ jobs|j=i prune
  19                 indexlevel|L=s maxsize|max-size=s))
  20         or die "bad command-line args\n$usage";
  21 die "--jobs must be positive\n" if defined $opt->{jobs} && $opt->{jobs} <= 0;
  22
  23 if ($opt->{compact}) {
  24         require PublicInbox::Xapcmd;
  25         PublicInbox::Xapcmd::check_compact();
  26         $compact_opt = { -coarse_lock => 1, compact => 1 };
  27 }
  28
  29 my $cfg = PublicInbox::Config->new;
  30 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, undef, $cfg);
  31 PublicInbox::Admin::require_or_die('-index');
  32 unless (@ibxs) { print STDERR "Usage: $usage\n"; exit 1 }
  33 my $mods = {};
  34 my $max_size = $opt->{maxsize} // $cfg->{lc('publicInbox.indexMaxSize')};
  35 if (defined $max_size) {
  36         PublicInbox::Admin::parse_unsigned(\$max_size) or
  37                 die "`publicInbox.indexMaxSize=$max_size' not parsed\n";
  38 }
  39
  40 foreach my $ibx (@ibxs) {
  41         # XXX: users can shoot themselves in the foot, with opt->{indexlevel}
  42         $ibx->{indexlevel} //= $opt->{indexlevel} //
  43                         PublicInbox::Admin::detect_indexlevel($ibx);
  44         $ibx->{index_max_size} = $max_size;
  45         PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
  46 }
  47
  48 PublicInbox::Admin::require_or_die(keys %$mods);
  49 PublicInbox::Admin::progress_prepare($opt);
  50 for my $ibx (@ibxs) {
  51         $ibx = PublicInbox::InboxWritable->new($ibx);
  52         if ($opt->{compact} >= 2) {
  53                 PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
  54         }
  55         PublicInbox::Admin::index_inbox($ibx, undef, $opt);
  56         PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt) if $compact_opt;
  57 }