script/public-inbox-index

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a git repository
   5 # configured for public-inbox.
   6 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   7 # highly recommended: eatmydata public-inbox-index GIT_DIR
   8
   9 use strict;
  10 use warnings;
  11 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  12 use Cwd 'abs_path';
  13 my $usage = "public-inbox-index GIT_DIR";
  14 use PublicInbox::Config;
  15 my $config = eval { PublicInbox::Config->new } || eval {
  16         warn "public-inbox unconfigured for serving, indexing anyways...\n";
  17         {}
  18 };
  19 eval { require PublicInbox::SearchIdx };
  20 if ($@) {
  21         print STDERR "Search::Xapian required for $0\n";
  22         exit 1;
  23 }
  24
  25 my $reindex;
  26 my %opts = ( '--reindex' => \$reindex );
  27 GetOptions(%opts) or die "bad command-line args\n$usage";
  28
  29 my @dirs;
  30
  31 sub resolve_git_dir {
  32         my ($cd) = @_;
  33         my @cmd = qw(git rev-parse --git-dir);
  34         my $cmd = join(' ', @cmd);
  35         my $pid = open my $fh, '-|';
  36         defined $pid or die "forking $cmd failed: $!\n";
  37         if ($pid == 0) {
  38                 if (defined $cd) {
  39                         chdir $cd or die "chdir $cd failed: $!\n";
  40                 }
  41                 exec @cmd;
  42                 die "Failed to exec $cmd: $!\n";
  43         } else {
  44                 my $dir = eval {
  45                         local $/;
  46                         <$fh>;
  47                 };
  48                 close $fh or die "error in $cmd: $!\n";
  49                 chomp $dir;
  50                 return abs_path($cd) if ($dir eq '.' && defined $cd);
  51                 abs_path($dir);
  52         }
  53 }
  54
  55 if (@ARGV) {
  56         @dirs = map { resolve_git_dir($_) } @ARGV;
  57 } else {
  58         @dirs = (resolve_git_dir());
  59 }
  60
  61 sub usage { print STDERR "Usage: $usage\n"; exit 1 }
  62 usage() unless @dirs;
  63
  64 foreach my $k (keys %$config) {
  65         $k =~ /\Apublicinbox\.([^\.]+)\.mainrepo\z/ or next;
  66         my $name = $1;
  67         my $v = $config->{$k};
  68         for my $i (0..$#dirs) {
  69                 next if $dirs[$i] ne $v;
  70                 my $ibx = $config->lookup_name($name);
  71                 $dirs[$i] = $ibx if $ibx;
  72         }
  73 }
  74
  75 foreach my $dir (@dirs) {
  76         index_dir($dir);
  77 }
  78
  79 sub index_dir {
  80         my ($git_dir) = @_;
  81         if (!ref $git_dir && ! -d $git_dir) {
  82                 die "$git_dir does not appear to be a git repository\n";
  83         }
  84         my $s = PublicInbox::SearchIdx->new($git_dir, 1);
  85         $s->index_sync({ reindex => $reindex });
  86 }