script/public-inbox-index

   1 #!perl -w
   2 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a public-inbox.
   5 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   6 # highly recommended: eatmydata public-inbox-index INBOX_DIR
   7
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 my $usage = 'public-inbox-index [options] INBOX_DIR';
  12 my $help = <<EOF; # the following should fit w/o scrolling in 80x24 term:
  13 usage: $usage
  14
  15   Create and update search indices
  16
  17 options:
  18
  19   --no-fsync          speed up indexing, risk corruption on power outage
  20   --indexlevel=LEVEL  `basic', 'medium', or `full' (default: full)
  21   --compact | -c      run public-inbox-compact(1) after indexing
  22   --sequential-shard  index Xapian shards sequentially for slow storage
  23   --jobs=NUM          set or disable parallelization (NUM=0)
  24   --batch-size=BYTES  flush changes to OS after a given number of bytes
  25   --max-size=BYTES    do not index messages larger than the given size
  26   --reindex           index previously indexed data (if upgrading)
  27   --rethread          regenerate thread IDs (if upgrading, use sparingly)
  28   --prune             prune git storage on discontiguous history
  29   --verbose | -v      increase verbosity (may be repeated)
  30   --help | -?         show this help
  31
  32 BYTES may use `k', `m', and `g' suffixes (e.g. `10m' for 10 megabytes)
  33 See public-inbox-index(1) man page for full documentation.
  34 EOF
  35 my $compact_opt;
  36 my $opt = { quiet => -1, compact => 0, maxsize => undef, fsync => 1 };
  37 GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune
  38                 fsync|sync! xapianonly|xapian-only
  39                 indexlevel|L=s maxsize|max-size=s batchsize|batch-size=s
  40                 sequentialshard|seq-shard|sequential-shard
  41                 help|?))
  42         or die "bad command-line args\n$usage";
  43 if ($opt->{help}) { print $help; exit 0 };
  44 die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;
  45 if ($opt->{xapianonly} && !$opt->{reindex}) {
  46         die "--xapian-only requires --reindex\n";
  47 }
  48
  49 # require lazily to speed up --help
  50 require PublicInbox::Admin;
  51 PublicInbox::Admin::require_or_die('-index');
  52
  53 if ($opt->{compact}) {
  54         require PublicInbox::Xapcmd;
  55         PublicInbox::Xapcmd::check_compact();
  56         $compact_opt = { -coarse_lock => 1, compact => 1 };
  57         if (defined(my $jobs = $opt->{jobs})) {
  58                 $compact_opt->{jobs} = $jobs;
  59         }
  60 }
  61
  62 my $cfg = PublicInbox::Config->new; # Config is loaded by Admin
  63 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, undef, $cfg);
  64 PublicInbox::Admin::require_or_die('-index');
  65 unless (@ibxs) { print STDERR "Usage: $usage\n"; exit 1 }
  66
  67 my $max_size = $opt->{maxsize} // $cfg->{lc('publicInbox.indexMaxSize')};
  68 if (defined $max_size) {
  69         PublicInbox::Admin::parse_unsigned(\$max_size) or
  70                 die "`publicInbox.indexMaxSize=$max_size' not parsed\n";
  71 }
  72
  73 my $bs = $opt->{batchsize} // $cfg->{lc('publicInbox.indexBatchSize')};
  74 if (defined $bs) {
  75         PublicInbox::Admin::parse_unsigned(\$bs) or
  76                 die "`publicInbox.indexBatchSize=$bs' not parsed\n";
  77 }
  78 no warnings 'once';
  79 local $PublicInbox::SearchIdx::BATCH_BYTES = $bs if defined($bs);
  80 use warnings 'once';
  81
  82 # out-of-the-box builds of Xapian 1.4.x are still limited to 32-bit
  83 # https://getting-started-with-xapian.readthedocs.io/en/latest/concepts/indexing/limitations.html
  84 local $ENV{XAPIAN_FLUSH_THRESHOLD} ||= '4294967295' if defined($bs);
  85
  86 my $s = $opt->{sequentialshard} //
  87                         $cfg->{lc('publicInbox.indexSequentialShard')};
  88 if (defined $s) {
  89         my $v = $cfg->git_bool($s);
  90         defined($v) or
  91                 die "`publicInbox.indexSequentialShard=$s' not boolean\n";
  92         $opt->{sequentialshard} = $v;
  93 }
  94
  95 my $mods = {};
  96 foreach my $ibx (@ibxs) {
  97         # XXX: users can shoot themselves in the foot, with opt->{indexlevel}
  98         $ibx->{indexlevel} //= $opt->{indexlevel} // ($opt->{xapianonly} ?
  99                         'full' : PublicInbox::Admin::detect_indexlevel($ibx));
 100         $ibx->{index_max_size} = $max_size;
 101         PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
 102 }
 103
 104 PublicInbox::Admin::require_or_die(keys %$mods);
 105 require PublicInbox::InboxWritable;
 106 PublicInbox::Admin::progress_prepare($opt);
 107 for my $ibx (@ibxs) {
 108         $ibx = PublicInbox::InboxWritable->new($ibx);
 109         if ($opt->{compact} >= 2) {
 110                 PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
 111         }
 112         $ibx->{-no_fsync} = 1 if !$opt->{fsync};
 113
 114         my $ibx_opt = $opt;
 115         if (defined(my $s = $ibx->{indexsequentialshard})) {
 116                 defined(my $v = $cfg->git_bool($s)) or die <<EOL;
 117 publicInbox.$ibx->{name}.indexSequentialShard not boolean
 118 EOL
 119                 $ibx_opt = { %$opt, sequentialshard => $v };
 120         }
 121         PublicInbox::Admin::index_inbox($ibx, undef, $ibx_opt);
 122         if ($compact_opt) {
 123                 local $compact_opt->{jobs} = 0 if $ibx_opt->{sequentialshard};
 124                 PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
 125         }
 126 }