script/public-inbox-index

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a public-inbox.
   5 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   6 # highly recommended: eatmydata public-inbox-index INBOX_DIR
   7
   8 use strict;
   9 use warnings;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 my $usage = "public-inbox-index INBOX_DIR";
  12 use PublicInbox::Admin;
  13 PublicInbox::Admin::require_or_die('-index');
  14 use PublicInbox::Xapcmd;
  15
  16 my $compact_opt;
  17 my $opt = { quiet => -1, compact => 0, maxsize => undef, sync => 1 };
  18 GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune sync!
  19                 indexlevel|L=s maxsize|max-size=s batchsize|batch-size=s
  20                 sequentialshard|seq-shard|sequential-shard))
  21         or die "bad command-line args\n$usage";
  22 die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;
  23
  24 if ($opt->{compact}) {
  25         require PublicInbox::Xapcmd;
  26         PublicInbox::Xapcmd::check_compact();
  27         $compact_opt = { -coarse_lock => 1, compact => 1 };
  28         if (defined(my $jobs = $opt->{jobs})) {
  29                 $compact_opt->{jobs} = $jobs;
  30         }
  31 }
  32
  33 my $cfg = PublicInbox::Config->new;
  34 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, undef, $cfg);
  35 PublicInbox::Admin::require_or_die('-index');
  36 unless (@ibxs) { print STDERR "Usage: $usage\n"; exit 1 }
  37
  38 my $max_size = $opt->{maxsize} // $cfg->{lc('publicInbox.indexMaxSize')};
  39 if (defined $max_size) {
  40         PublicInbox::Admin::parse_unsigned(\$max_size) or
  41                 die "`publicInbox.indexMaxSize=$max_size' not parsed\n";
  42 }
  43
  44 if (my $bs = $opt->{batchsize} // $cfg->{lc('publicInbox.indexBatchSize')}) {
  45         PublicInbox::Admin::parse_unsigned(\$bs) or
  46                 die "`publicInbox.indexBatchSize=$bs' not parsed\n";
  47         $PublicInbox::SearchIdx::BATCH_BYTES = $bs;
  48 }
  49
  50 my $s = $opt->{sequentialshard} //
  51                         $cfg->{lc('publicInbox.indexSequentialShard')};
  52 if (defined $s) {
  53         my $v = $cfg->git_bool($s);
  54         defined($v) or
  55                 die "`publicInbox.indexSequentialShard=$s' not boolean\n";
  56         $opt->{sequentialshard} = $v;
  57 }
  58
  59 my $mods = {};
  60 foreach my $ibx (@ibxs) {
  61         # XXX: users can shoot themselves in the foot, with opt->{indexlevel}
  62         $ibx->{indexlevel} //= $opt->{indexlevel} //
  63                         PublicInbox::Admin::detect_indexlevel($ibx);
  64         $ibx->{index_max_size} = $max_size;
  65         PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
  66 }
  67
  68 PublicInbox::Admin::require_or_die(keys %$mods);
  69 PublicInbox::Admin::progress_prepare($opt);
  70 for my $ibx (@ibxs) {
  71         $ibx = PublicInbox::InboxWritable->new($ibx);
  72         if ($opt->{compact} >= 2) {
  73                 PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
  74         }
  75         $ibx->{-no_sync} = 1 if !$opt->{sync};
  76
  77         my $ibx_opt = $opt;
  78         if (defined(my $s = $ibx->{indexsequentialshard})) {
  79                 defined(my $v = $cfg->git_bool($s)) or die <<EOL;
  80 publicInbox.$ibx->{name}.indexSequentialShard not boolean
  81 EOL
  82                 $ibx_opt = { %$opt, sequentialshard => $v };
  83         }
  84         PublicInbox::Admin::index_inbox($ibx, undef, $ibx_opt);
  85         PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt) if $compact_opt;
  86 }