script/public-inbox-index

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   3 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   4 # Basic tool to create a Xapian search index for a git repository
   5 # configured for public-inbox.
   6 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   7 # highly recommended: eatmydata public-inbox-index GIT_DIR
   8
   9 use strict;
  10 use warnings;
  11 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  12 my $usage = "public-inbox-index GIT_DIR";
  13 use PublicInbox::Config;
  14 eval { require PublicInbox::SearchIdx };
  15 if ($@) {
  16         print STDERR "Search::Xapian required for $0\n";
  17         exit 1;
  18 }
  19
  20 my $reindex;
  21 my %opts = ( '--reindex' => \$reindex );
  22 GetOptions(%opts) or die "bad command-line args\n$usage";
  23
  24 my @dirs;
  25
  26 sub resolve_git_dir {
  27         my ($cd) = @_;
  28         my @cmd = qw(git rev-parse --git-dir);
  29         my $cmd = join(' ', @cmd);
  30         my $pid = open my $fh, '-|';
  31         defined $pid or die "forking $cmd failed: $!\n";
  32         if ($pid == 0) {
  33                 if (defined $cd) {
  34                         chdir $cd or die "chdir $cd failed: $!\n";
  35                 }
  36                 exec @cmd;
  37                 die "Failed to exec $cmd: $!\n";
  38         } else {
  39                 my $dir = eval {
  40                         local $/;
  41                         <$fh>;
  42                 };
  43                 close $fh or die "error in $cmd: $!\n";
  44                 chomp $dir;
  45                 return $cd if ($dir eq '.' && defined $cd);
  46                 $dir;
  47         }
  48 }
  49
  50 if (@ARGV) {
  51         @dirs = map { resolve_git_dir($_) } @ARGV;
  52 } else {
  53         @dirs = (resolve_git_dir());
  54 }
  55
  56 sub usage { print STDERR "Usage: $usage\n"; exit 1 }
  57 usage() unless @dirs;
  58
  59 foreach my $dir (@dirs) {
  60         index_dir($dir);
  61 }
  62
  63 sub index_dir {
  64         my ($git_dir) = @_;
  65         -d $git_dir or die "$git_dir does not appear to be a git repository\n";
  66         my $s = PublicInbox::SearchIdx->new($git_dir, 1);
  67         $s->index_sync({ reindex => $reindex });
  68 }