script/public-inbox-index

   1 #!perl -w
   2 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a public-inbox.
   5 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   6 # highly recommended: eatmydata public-inbox-index INBOX_DIR
   7
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 my $usage = 'public-inbox-index [options] INBOX_DIR';
  12 my $help = <<EOF; # the following should fit w/o scrolling in 80x24 term:
  13 usage: $usage
  14
  15   Create and update search indices
  16
  17 options:
  18
  19   --no-fsync          speed up indexing, risk corruption on power outage
  20   -L LEVEL            `basic', `medium', or `full' (default: full)
  21   --compact | -c      run public-inbox-compact(1) after indexing
  22   --sequential-shard  index Xapian shards sequentially for slow storage
  23   --jobs=NUM          set or disable parallelization (NUM=0)
  24   --batch-size=BYTES  flush changes to OS after a given number of bytes
  25   --max-size=BYTES    do not index messages larger than the given size
  26   --reindex           index previously indexed data (if upgrading)
  27   --rethread          regenerate thread IDs (if upgrading, use sparingly)
  28   --prune             prune git storage on discontiguous history
  29   --verbose | -v      increase verbosity (may be repeated)
  30   --help | -?         show this help
  31
  32 BYTES may use `k', `m', and `g' suffixes (e.g. `10m' for 10 megabytes)
  33 See public-inbox-index(1) man page for full documentation.
  34 EOF
  35 my $compact_opt;
  36 my $opt = { quiet => -1, compact => 0, max_size => undef, fsync => 1 };
  37 GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune
  38                 fsync|sync! xapian_only|xapian-only
  39                 indexlevel|index-level|L=s max_size|max-size=s
  40                 batch_size|batch-size=s
  41                 sequential_shard|seq-shard|sequential-shard
  42                 help|?))
  43         or die "bad command-line args\n$usage";
  44 if ($opt->{help}) { print $help; exit 0 };
  45 die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;
  46 if ($opt->{xapian_only} && !$opt->{reindex}) {
  47         die "--xapian-only requires --reindex\n";
  48 }
  49
  50 # require lazily to speed up --help
  51 require PublicInbox::Admin;
  52 PublicInbox::Admin::require_or_die('-index');
  53
  54 if ($opt->{compact}) {
  55         require PublicInbox::Xapcmd;
  56         PublicInbox::Xapcmd::check_compact();
  57         $compact_opt = { -coarse_lock => 1, compact => 1 };
  58         if (defined(my $jobs = $opt->{jobs})) {
  59                 $compact_opt->{jobs} = $jobs;
  60         }
  61 }
  62
  63 my $cfg = PublicInbox::Config->new; # Config is loaded by Admin
  64 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, undef, $cfg);
  65 PublicInbox::Admin::require_or_die('-index');
  66 unless (@ibxs) { print STDERR "Usage: $usage\n"; exit 1 }
  67
  68 my $max_size = $opt->{max_size} // $cfg->{lc('publicInbox.indexMaxSize')};
  69 if (defined $max_size) {
  70         PublicInbox::Admin::parse_unsigned(\$max_size) or
  71                 die "`publicInbox.indexMaxSize=$max_size' not parsed\n";
  72         $opt->{max_size} = $max_size;
  73 }
  74
  75 my $bs = $opt->{batch_size} // $cfg->{lc('publicInbox.indexBatchSize')};
  76 if (defined $bs) {
  77         PublicInbox::Admin::parse_unsigned(\$bs) or
  78                 die "`publicInbox.indexBatchSize=$bs' not parsed\n";
  79         $opt->{batch_size} = $bs;
  80 }
  81
  82 # out-of-the-box builds of Xapian 1.4.x are still limited to 32-bit
  83 # https://getting-started-with-xapian.readthedocs.io/en/latest/concepts/indexing/limitations.html
  84 local $ENV{XAPIAN_FLUSH_THRESHOLD} ||= '4294967295' if defined($bs);
  85
  86 my $s = $opt->{sequential_shard} //
  87                         $cfg->{lc('publicInbox.indexSequentialShard')};
  88 if (defined $s) {
  89         my $v = $cfg->git_bool($s);
  90         defined($v) or
  91                 die "`publicInbox.indexSequentialShard=$s' not boolean\n";
  92         $opt->{sequential_shard} = $v;
  93 }
  94
  95 my $mods = {};
  96 foreach my $ibx (@ibxs) {
  97         # XXX: users can shoot themselves in the foot, with opt->{indexlevel}
  98         $ibx->{indexlevel} //= $opt->{indexlevel} // ($opt->{xapian_only} ?
  99                         'full' : PublicInbox::Admin::detect_indexlevel($ibx));
 100         PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
 101 }
 102
 103 PublicInbox::Admin::require_or_die(keys %$mods);
 104 require PublicInbox::InboxWritable;
 105 PublicInbox::Admin::progress_prepare($opt);
 106 for my $ibx (@ibxs) {
 107         $ibx = PublicInbox::InboxWritable->new($ibx);
 108         if ($opt->{compact} >= 2) {
 109                 PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
 110         }
 111         $ibx->{-no_fsync} = 1 if !$opt->{fsync};
 112
 113         my $ibx_opt = $opt;
 114         if (defined(my $s = $ibx->{lc('indexSequentialShard')})) {
 115                 defined(my $v = $cfg->git_bool($s)) or die <<EOL;
 116 publicInbox.$ibx->{name}.indexSequentialShard not boolean
 117 EOL
 118                 $ibx_opt = { %$opt, sequential_shard => $v };
 119         }
 120         PublicInbox::Admin::index_inbox($ibx, undef, $ibx_opt);
 121         if ($compact_opt) {
 122                 local $compact_opt->{jobs} = 0 if $ibx_opt->{sequential_shard};
 123                 PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
 124         }
 125 }