script/public-inbox-index

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a git repository
   5 # configured for public-inbox.
   6 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   7 # highly recommended: eatmydata public-inbox-index REPO_DIR
   8
   9 use strict;
  10 use warnings;
  11 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  12 use Cwd 'abs_path';
  13 my $usage = "public-inbox-index REPO_DIR";
  14 use PublicInbox::Config;
  15 my $config = eval { PublicInbox::Config->new } || eval {
  16         warn "public-inbox unconfigured for serving, indexing anyways...\n";
  17         {}
  18 };
  19 eval { require PublicInbox::SearchIdx };
  20 if ($@) {
  21         print STDERR "Search::Xapian required for $0\n";
  22         exit 1;
  23 }
  24
  25 my $reindex;
  26 my %opts = ( '--reindex' => \$reindex );
  27 GetOptions(%opts) or die "bad command-line args\n$usage";
  28
  29 my @dirs;
  30
  31 sub resolve_repo_dir {
  32         my ($cd) = @_;
  33         my $prefix = defined $cd ? $cd : './';
  34
  35         my @cmd = qw(git rev-parse --git-dir);
  36         my $cmd = join(' ', @cmd);
  37         my $pid = open my $fh, '-|';
  38         defined $pid or die "forking $cmd failed: $!\n";
  39         if ($pid == 0) {
  40                 if (defined $cd) {
  41                         chdir $cd or die "chdir $cd failed: $!\n";
  42                 }
  43                 exec @cmd;
  44                 die "Failed to exec $cmd: $!\n";
  45         } else {
  46                 my $dir = eval {
  47                         local $/;
  48                         <$fh>;
  49                 };
  50                 close $fh or die "error in $cmd: $!\n";
  51                 chomp $dir;
  52                 return abs_path($cd) if ($dir eq '.' && defined $cd);
  53                 abs_path($dir);
  54         }
  55 }
  56
  57 if (@ARGV) {
  58         @dirs = map { resolve_repo_dir($_) } @ARGV;
  59 } else {
  60         @dirs = (resolve_repo_dir());
  61 }
  62
  63 sub usage { print STDERR "Usage: $usage\n"; exit 1 }
  64 usage() unless @dirs;
  65
  66 foreach my $k (keys %$config) {
  67         $k =~ /\Apublicinbox\.([^\.]+)\.mainrepo\z/ or next;
  68         my $name = $1;
  69         my $v = $config->{$k};
  70         for my $i (0..$#dirs) {
  71                 next if $dirs[$i] ne $v;
  72                 my $ibx = $config->lookup_name($name);
  73                 $dirs[$i] = $ibx if $ibx;
  74         }
  75 }
  76
  77 foreach my $dir (@dirs) {
  78         index_dir($dir);
  79 }
  80
  81 sub index_dir {
  82         my ($git_dir) = @_;
  83         if (!ref $git_dir && ! -d $git_dir) {
  84                 die "$git_dir does not appear to be a git repository\n";
  85         }
  86         my $s = PublicInbox::SearchIdx->new($git_dir, 1);
  87         $s->index_sync({ reindex => $reindex });
  88 }