script/public-inbox-index

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a public-inbox.
   5 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   6 # highly recommended: eatmydata public-inbox-index INBOX_DIR
   7
   8 use strict;
   9 use warnings;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 my $usage = "public-inbox-index INBOX_DIR";
  12 use PublicInbox::Admin;
  13 PublicInbox::Admin::require_or_die('-index');
  14 use PublicInbox::Xapcmd;
  15
  16 my $compact_opt;
  17 my $opt = { quiet => -1, compact => 0, maxsize => undef, fsync => 1 };
  18 GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune
  19                 fsync|sync! xapianonly|xapian-only
  20                 indexlevel|L=s maxsize|max-size=s batchsize|batch-size=s
  21                 sequentialshard|seq-shard|sequential-shard))
  22         or die "bad command-line args\n$usage";
  23 die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;
  24
  25 if ($opt->{compact}) {
  26         require PublicInbox::Xapcmd;
  27         PublicInbox::Xapcmd::check_compact();
  28         $compact_opt = { -coarse_lock => 1, compact => 1 };
  29         if (defined(my $jobs = $opt->{jobs})) {
  30                 $compact_opt->{jobs} = $jobs;
  31         }
  32 }
  33
  34 my $cfg = PublicInbox::Config->new;
  35 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, undef, $cfg);
  36 PublicInbox::Admin::require_or_die('-index');
  37 unless (@ibxs) { print STDERR "Usage: $usage\n"; exit 1 }
  38
  39 my $max_size = $opt->{maxsize} // $cfg->{lc('publicInbox.indexMaxSize')};
  40 if (defined $max_size) {
  41         PublicInbox::Admin::parse_unsigned(\$max_size) or
  42                 die "`publicInbox.indexMaxSize=$max_size' not parsed\n";
  43 }
  44
  45 my $bs = $opt->{batchsize} // $cfg->{lc('publicInbox.indexBatchSize')};
  46 if (defined $bs) {
  47         PublicInbox::Admin::parse_unsigned(\$bs) or
  48                 die "`publicInbox.indexBatchSize=$bs' not parsed\n";
  49 }
  50 local $PublicInbox::SearchIdx::BATCH_BYTES = $bs if defined($bs);
  51
  52 # out-of-the-box builds of Xapian 1.4.x are still limited to 32-bit
  53 # https://getting-started-with-xapian.readthedocs.io/en/latest/concepts/indexing/limitations.html
  54 local $ENV{XAPIAN_FLUSH_THRESHOLD} ||= '4294967295' if defined($bs);
  55
  56 my $s = $opt->{sequentialshard} //
  57                         $cfg->{lc('publicInbox.indexSequentialShard')};
  58 if (defined $s) {
  59         my $v = $cfg->git_bool($s);
  60         defined($v) or
  61                 die "`publicInbox.indexSequentialShard=$s' not boolean\n";
  62         $opt->{sequentialshard} = $v;
  63 }
  64
  65 my $mods = {};
  66 foreach my $ibx (@ibxs) {
  67         # XXX: users can shoot themselves in the foot, with opt->{indexlevel}
  68         $ibx->{indexlevel} //= $opt->{indexlevel} // ($opt->{xapianonly} ?
  69                         'full' : PublicInbox::Admin::detect_indexlevel($ibx));
  70         $ibx->{index_max_size} = $max_size;
  71         PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
  72 }
  73
  74 PublicInbox::Admin::require_or_die(keys %$mods);
  75 PublicInbox::Admin::progress_prepare($opt);
  76 for my $ibx (@ibxs) {
  77         $ibx = PublicInbox::InboxWritable->new($ibx);
  78         if ($opt->{compact} >= 2) {
  79                 PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
  80         }
  81         $ibx->{-no_fsync} = 1 if !$opt->{fsync};
  82
  83         my $ibx_opt = $opt;
  84         if (defined(my $s = $ibx->{indexsequentialshard})) {
  85                 defined(my $v = $cfg->git_bool($s)) or die <<EOL;
  86 publicInbox.$ibx->{name}.indexSequentialShard not boolean
  87 EOL
  88                 $ibx_opt = { %$opt, sequentialshard => $v };
  89         }
  90         PublicInbox::Admin::index_inbox($ibx, undef, $ibx_opt);
  91         if ($compact_opt) {
  92                 local $compact_opt->{jobs} = 0 if $ibx_opt->{sequentialshard};
  93                 PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
  94         }
  95 }