script/public-inbox-index

   1 #!perl -w
   2 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a public-inbox.
   5 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   6 # highly recommended: eatmydata public-inbox-index INBOX_DIR
   7
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 my $help = <<EOF; # the following should fit w/o scrolling in 80x24 term:
  12 usage: public-inbox-index [options] INBOX_DIR
  13
  14   Create and update per-inbox search indices
  15
  16 options:
  17
  18   --no-fsync          speed up indexing, risk corruption on power outage
  19   -L LEVEL            `basic', `medium', or `full' (default: full)
  20   -E EXTINDEX         update extindex (default: `all')
  21   --all               index all configured inboxes
  22   --compact | -c      run public-inbox-compact(1) after indexing
  23   --sequential-shard  index Xapian shards sequentially for slow storage
  24   --jobs=NUM          set or disable parallelization (NUM=0)
  25   --batch-size=BYTES  flush changes to OS after a given number of bytes
  26   --max-size=BYTES    do not index messages larger than the given size
  27   --reindex           index previously indexed data (if upgrading)
  28   --rethread          regenerate thread IDs (if upgrading, use sparingly)
  29   --prune             prune git storage on discontiguous history
  30   --verbose | -v      increase verbosity (may be repeated)
  31
  32 BYTES may use `k', `m', and `g' suffixes (e.g. `10m' for 10 megabytes)
  33 See public-inbox-index(1) man page for full documentation.
  34 EOF
  35 my $opt = {
  36         quiet => -1, compact => 0, max_size => undef, fsync => 1,
  37         'update-extindex' => [], # ":s@" optional arg sets '' if no arg given
  38 };
  39 GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune
  40                 fsync|sync! xapian_only|xapian-only
  41                 indexlevel|index-level|L=s max_size|max-size=s
  42                 batch_size|batch-size=s
  43                 sequential-shard|seq-shard
  44                 no-update-extindex update-extindex|E=s@
  45                 fast-noop|F skip-docdata all C=s@ help|h))
  46         or die $help;
  47 if ($opt->{help}) { print $help; exit 0 };
  48 die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;
  49 if ($opt->{xapian_only} && !$opt->{reindex}) {
  50         die "--xapian-only requires --reindex\n";
  51 }
  52 if ($opt->{reindex} && delete($opt->{'fast-noop'})) {
  53         warn "--fast-noop ignored with --reindex\n";
  54 }
  55
  56 # require lazily to speed up --help
  57 require PublicInbox::Admin;
  58 PublicInbox::Admin::require_or_die('-index');
  59 PublicInbox::Admin::do_chdir(delete $opt->{C});
  60
  61 my $cfg = PublicInbox::Config->new; # Config is loaded by Admin
  62 $opt->{-use_cwd} = 1;
  63 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, $opt, $cfg);
  64 PublicInbox::Admin::require_or_die('-index');
  65 unless (@ibxs) { print STDERR $help; exit 1 }
  66
  67 my (@eidx, %eidx_seen);
  68 my $update_extindex = $opt->{'update-extindex'};
  69 if (!scalar(@$update_extindex) && (my $ALL = $cfg->ALL)) {
  70         # extindex and normal inboxes may have different owners
  71         push(@$update_extindex, 'all') if -w $ALL->{topdir};
  72 }
  73 @$update_extindex = () if $opt->{'no-update-extindex'};
  74 if (scalar @$update_extindex) {
  75         PublicInbox::Admin::require_or_die('-search');
  76         require PublicInbox::ExtSearchIdx;
  77 }
  78 for my $ei_name (@$update_extindex) {
  79         my $es = $cfg->lookup_ei($ei_name);
  80         my $topdir;
  81         if (!$es && -d $ei_name) { # allow dirname or config section name
  82                 $topdir = $ei_name;
  83         } elsif ($es) {
  84                 $topdir = $es->{topdir};
  85         } else {
  86                 die "extindex `$ei_name' not configured or found\n";
  87         }
  88         my $o = { %$opt };
  89         delete $o->{indexlevel} if ($o->{indexlevel}//'') eq 'basic';
  90         $eidx_seen{$topdir} //=
  91                 push(@eidx, PublicInbox::ExtSearchIdx->new($topdir, $o));
  92 }
  93 my $mods = {};
  94 my @eidx_unconfigured;
  95 foreach my $ibx (@ibxs) {
  96         # detect_indexlevel may also set $ibx->{-skip_docdata}
  97         my $detected = PublicInbox::Admin::detect_indexlevel($ibx);
  98         # XXX: users can shoot themselves in the foot, with opt->{indexlevel}
  99         $ibx->{indexlevel} //= $opt->{indexlevel} // ($opt->{xapian_only} ?
 100                         'full' : $detected);
 101         PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
 102         if (@eidx && $ibx->{-unconfigured}) {
 103                 push @eidx_unconfigured, "  $ibx->{inboxdir}\n";
 104         }
 105 }
 106 warn <<EOF if @eidx_unconfigured;
 107 The following inboxes are unconfigured and will not be updated in
 108 @$update_extindex:\n@eidx_unconfigured
 109 EOF
 110
 111 # "Search::Xapian" includes SWIG "Xapian", too:
 112 $opt->{compact} = 0 if !$mods->{'Search::Xapian'};
 113
 114 PublicInbox::Admin::require_or_die(keys %$mods);
 115 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 116 local %ENV = (%ENV, %$env) if $env;
 117 require PublicInbox::InboxWritable;
 118 PublicInbox::Xapcmd::check_compact() if $opt->{compact};
 119 PublicInbox::Admin::progress_prepare($opt);
 120 for my $ibx (@ibxs) {
 121         $ibx = PublicInbox::InboxWritable->new($ibx);
 122         if ($opt->{compact} >= 2) {
 123                 PublicInbox::Xapcmd::run($ibx, 'compact', $opt->{compact_opt});
 124         }
 125         $ibx->{-no_fsync} = 1 if !$opt->{fsync};
 126         $ibx->{-skip_docdata} //= $opt->{'skip-docdata'};
 127
 128         my $ibx_opt = $opt;
 129         if (defined(my $s = $ibx->{lc('indexSequentialShard')})) {
 130                 defined(my $v = $cfg->git_bool($s)) or die <<EOL;
 131 publicInbox.$ibx->{name}.indexSequentialShard not boolean
 132 EOL
 133                 $ibx_opt = { %$opt, 'sequential-shard' => $v };
 134         }
 135         my $nidx = PublicInbox::Admin::index_inbox($ibx, undef, $ibx_opt);
 136         last if $ibx_opt->{quit};
 137         if (my $copt = $opt->{compact_opt}) {
 138                 local $copt->{jobs} = 0 if $ibx_opt->{'sequential-shard'};
 139                 PublicInbox::Xapcmd::run($ibx, 'compact', $copt);
 140         }
 141         last if $ibx_opt->{quit};
 142         next if $ibx->{-unconfigured} || !$nidx;
 143         for my $eidx (@eidx) {
 144                 $eidx->attach_inbox($ibx);
 145         }
 146 }
 147 my $pr = $opt->{-progress};
 148 for my $eidx (@eidx) {
 149         $pr->("indexing $eidx->{topdir} ...\n") if $pr;
 150         $eidx->eidx_sync($opt);
 151         last if $opt->{quit};
 152 }