script/public-inbox-index

   1 #!perl -w
   2 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a public-inbox.
   5 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   6 # highly recommended: eatmydata public-inbox-index INBOX_DIR
   7
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 my $help = <<EOF; # the following should fit w/o scrolling in 80x24 term:
  12 usage: public-inbox-index [options] INBOX_DIR
  13
  14   Create and update per-inbox search indices
  15
  16 options:
  17
  18   --no-fsync          speed up indexing, risk corruption on power outage
  19   -L LEVEL            `basic', `medium', or `full' (default: full)
  20   -E EIDX             update EIDX (e.g. `all')
  21   --all               index all configured inboxes
  22   --compact | -c      run public-inbox-compact(1) after indexing
  23   --sequential-shard  index Xapian shards sequentially for slow storage
  24   --jobs=NUM          set or disable parallelization (NUM=0)
  25   --batch-size=BYTES  flush changes to OS after a given number of bytes
  26   --max-size=BYTES    do not index messages larger than the given size
  27   --reindex           index previously indexed data (if upgrading)
  28   --rethread          regenerate thread IDs (if upgrading, use sparingly)
  29   --prune             prune git storage on discontiguous history
  30   --verbose | -v      increase verbosity (may be repeated)
  31
  32 BYTES may use `k', `m', and `g' suffixes (e.g. `10m' for 10 megabytes)
  33 See public-inbox-index(1) man page for full documentation.
  34 EOF
  35 my $opt = { quiet => -1, compact => 0, max_size => undef, fsync => 1 };
  36 GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune
  37                 fsync|sync! xapian_only|xapian-only
  38                 indexlevel|index-level|L=s max_size|max-size=s
  39                 batch_size|batch-size=s
  40                 sequential_shard|seq-shard|sequential-shard
  41                 skip-docdata all help|h))
  42         or die $help;
  43 if ($opt->{help}) { print $help; exit 0 };
  44 die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;
  45 if ($opt->{xapian_only} && !$opt->{reindex}) {
  46         die "--xapian-only requires --reindex\n";
  47 }
  48
  49 # require lazily to speed up --help
  50 require PublicInbox::Admin;
  51 PublicInbox::Admin::require_or_die('-index');
  52
  53 my $cfg = PublicInbox::Config->new; # Config is loaded by Admin
  54 $opt->{-use_cwd} = 1;
  55 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, $opt, $cfg);
  56 PublicInbox::Admin::require_or_die('-index');
  57 unless (@ibxs) { print STDERR $help; exit 1 }
  58
  59 my $mods = {};
  60 foreach my $ibx (@ibxs) {
  61         # detect_indexlevel may also set $ibx->{-skip_docdata}
  62         my $detected = PublicInbox::Admin::detect_indexlevel($ibx);
  63         # XXX: users can shoot themselves in the foot, with opt->{indexlevel}
  64         $ibx->{indexlevel} //= $opt->{indexlevel} // ($opt->{xapian_only} ?
  65                         'full' : $detected);
  66         PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
  67 }
  68
  69 # "Search::Xapian" includes SWIG "Xapian", too:
  70 $opt->{compact} = 0 if !$mods->{'Search::Xapian'};
  71
  72 PublicInbox::Admin::require_or_die(keys %$mods);
  73 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
  74 local %ENV = (%ENV, %$env) if $env;
  75 require PublicInbox::InboxWritable;
  76 PublicInbox::Xapcmd::check_compact() if $opt->{compact};
  77 PublicInbox::Admin::progress_prepare($opt);
  78 for my $ibx (@ibxs) {
  79         $ibx = PublicInbox::InboxWritable->new($ibx);
  80         if ($opt->{compact} >= 2) {
  81                 PublicInbox::Xapcmd::run($ibx, 'compact', $opt->{compact_opt});
  82         }
  83         $ibx->{-no_fsync} = 1 if !$opt->{fsync};
  84         $ibx->{-skip_docdata} //= $opt->{'skip-docdata'};
  85
  86         my $ibx_opt = $opt;
  87         if (defined(my $s = $ibx->{lc('indexSequentialShard')})) {
  88                 defined(my $v = $cfg->git_bool($s)) or die <<EOL;
  89 publicInbox.$ibx->{name}.indexSequentialShard not boolean
  90 EOL
  91                 $ibx_opt = { %$opt, sequential_shard => $v };
  92         }
  93         PublicInbox::Admin::index_inbox($ibx, undef, $ibx_opt);
  94         last if $ibx_opt->{quit};
  95         if (my $copt = $opt->{compact_opt}) {
  96                 local $copt->{jobs} = 0 if $ibx_opt->{sequential_shard};
  97                 PublicInbox::Xapcmd::run($ibx, 'compact', $copt);
  98         }
  99 }