script/public-inbox-index

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Basic tool to create a Xapian search index for a public-inbox.
   5 # Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
   6 # highly recommended: eatmydata public-inbox-index INBOX_DIR
   7
   8 use strict;
   9 use warnings;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 my $usage = "public-inbox-index INBOX_DIR";
  12 use PublicInbox::Admin;
  13 PublicInbox::Admin::require_or_die('-index');
  14 use PublicInbox::Xapcmd;
  15
  16 my $compact_opt;
  17 my $opt = { quiet => -1, compact => 0, maxsize => undef, sync => 1 };
  18 GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune sync!
  19                 indexlevel|L=s maxsize|max-size=s batchsize|batch-size=s))
  20         or die "bad command-line args\n$usage";
  21 die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;
  22
  23 if ($opt->{compact}) {
  24         require PublicInbox::Xapcmd;
  25         PublicInbox::Xapcmd::check_compact();
  26         $compact_opt = { -coarse_lock => 1, compact => 1 };
  27         if (defined(my $jobs = $opt->{jobs})) {
  28                 $compact_opt->{jobs} = $jobs;
  29         }
  30 }
  31
  32 my $cfg = PublicInbox::Config->new;
  33 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, undef, $cfg);
  34 PublicInbox::Admin::require_or_die('-index');
  35 unless (@ibxs) { print STDERR "Usage: $usage\n"; exit 1 }
  36
  37 my $max_size = $opt->{maxsize} // $cfg->{lc('publicInbox.indexMaxSize')};
  38 if (defined $max_size) {
  39         PublicInbox::Admin::parse_unsigned(\$max_size) or
  40                 die "`publicInbox.indexMaxSize=$max_size' not parsed\n";
  41 }
  42
  43 if (my $bs = $opt->{batchsize} // $cfg->{lc('publicInbox.indexBatchSize')}) {
  44         PublicInbox::Admin::parse_unsigned(\$bs) or
  45                 die "`publicInbox.indexBatchSize=$bs' not parsed\n";
  46         $PublicInbox::SearchIdx::BATCH_BYTES = $bs;
  47 }
  48
  49 my $mods = {};
  50 foreach my $ibx (@ibxs) {
  51         # XXX: users can shoot themselves in the foot, with opt->{indexlevel}
  52         $ibx->{indexlevel} //= $opt->{indexlevel} //
  53                         PublicInbox::Admin::detect_indexlevel($ibx);
  54         $ibx->{index_max_size} = $max_size;
  55         PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
  56 }
  57
  58 PublicInbox::Admin::require_or_die(keys %$mods);
  59 PublicInbox::Admin::progress_prepare($opt);
  60 for my $ibx (@ibxs) {
  61         $ibx = PublicInbox::InboxWritable->new($ibx);
  62         if ($opt->{compact} >= 2) {
  63                 PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
  64         }
  65         $ibx->{-no_sync} = 1 if !$opt->{sync};
  66         PublicInbox::Admin::index_inbox($ibx, undef, $opt);
  67         PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt) if $compact_opt;
  68 }