script/public-inbox-init

   1 #!perl -w
   2 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   7 use Fcntl qw(:DEFAULT);
   8 my $help = <<EOF; # the following should fit w/o scrolling in 80x24 term:
   9 usage: public-inbox-init NAME INBOX_DIR HTTP_URL ADDRESS [ADDRESS..]
  10
  11   Initialize a public-inbox
  12
  13 required arguments:
  14
  15   NAME                the name of the inbox
  16   INBOX_DIR           pathname the inbox
  17   HTTP_URL            HTTP (or HTTPS) URL
  18   ADDRESS             email address(es), may be specified multiple times
  19
  20 options:
  21
  22   -V2                 use scalable public-inbox-v2-format(5)
  23   -L LEVEL            index level `basic', `medium', or `full' (default: full)
  24   --ng NEWSGROUP      set NNTP newsgroup name
  25   --skip-artnum=NUM   NNTP article numbers to skip
  26   --skip-epoch=NUM    epochs to skip (-V2 only)
  27   -J JOBS             number of indexing jobs (-V2 only), (default: 4)
  28
  29 See public-inbox-init(1) man page for full documentation.
  30 EOF
  31
  32 require PublicInbox::Admin;
  33 PublicInbox::Admin::require_or_die('-base');
  34
  35 my ($version, $indexlevel, $skip_epoch, $skip_artnum, $jobs, $show_help);
  36 my $skip_docdata;
  37 my $ng = '';
  38 my %opts = (
  39         'V|version=i' => \$version,
  40         'L|index-level|indexlevel=s' => \$indexlevel,
  41         'S|skip|skip-epoch=i' => \$skip_epoch,
  42         'skip-artnum=i' => \$skip_artnum,
  43         'j|jobs=i' => \$jobs,
  44         'ng|newsgroup=s' => \$ng,
  45         'skip-docdata' => \$skip_docdata,
  46         'help|h' => \$show_help,
  47 );
  48 my $usage_cb = sub {
  49         print STDERR $help;
  50         exit 1;
  51 };
  52 GetOptions(%opts) or $usage_cb->();
  53 if ($show_help) { print $help; exit 0 };
  54 PublicInbox::Admin::indexlevel_ok_or_die($indexlevel) if defined $indexlevel;
  55 my $name = shift @ARGV or $usage_cb->();
  56 my $inboxdir = shift @ARGV or $usage_cb->();
  57 my $http_url = shift @ARGV or $usage_cb->();
  58 my (@address) = @ARGV;
  59 @address or $usage_cb->();
  60
  61 $ng =~ m![^A-Za-z0-9/_\.\-\~\@\+\=:]! and
  62         die "--newsgroup `$ng' is not valid\n";
  63 ($ng =~ m!\A\.! || $ng =~ m!\.\z!) and
  64         die "--newsgroup `$ng' must not start or end with `.'\n";
  65
  66 require PublicInbox::Config;
  67 my $pi_config = PublicInbox::Config->default_file;
  68 require File::Basename;
  69 my $dir = File::Basename::dirname($pi_config);
  70 require File::Path;
  71 File::Path::mkpath($dir); # will croak on fatal errors
  72
  73 # first, we grab a flock to prevent simultaneous public-inbox-init
  74 # processes from trampling over each other, or exiting with 255 on
  75 # O_EXCL failure below.  This gets unlocked automatically on exit:
  76 require PublicInbox::Lock;
  77 my $lock_obj = { lock_path => "$pi_config.flock" };
  78 PublicInbox::Lock::lock_acquire($lock_obj);
  79
  80 # git-config will operate on this (and rename on success):
  81 require File::Temp;
  82 my $fh = File::Temp->new(TEMPLATE => 'pi-init-XXXXXXXX', DIR => $dir);
  83
  84 # Now, we grab another lock to use git-config(1) locking, so it won't
  85 # wait on the lock, unlike some of our internal flock()-based locks.
  86 # This is to prevent direct git-config(1) usage from clobbering our
  87 # changes.
  88 my $lockfile = "$pi_config.lock";
  89 my $lockfh;
  90 sysopen($lockfh, $lockfile, O_RDWR|O_CREAT|O_EXCL) or do {
  91         warn "could not open config file: $lockfile: $!\n";
  92         exit(255);
  93 };
  94 require PublicInbox::OnDestroy;
  95 my $auto_unlink = PublicInbox::OnDestroy->new($$, sub { unlink $lockfile });
  96 my ($perm, %seen);
  97 if (-e $pi_config) {
  98         open(my $oh, '<', $pi_config) or die "unable to read $pi_config: $!\n";
  99         my @st = stat($oh);
 100         $perm = $st[2];
 101         defined $perm or die "(f)stat failed on $pi_config: $!\n";
 102         chmod($perm & 07777, $fh) or
 103                 die "(f)chmod failed on future $pi_config: $!\n";
 104         defined(my $old = do { local $/; <$oh> }) or die "read $pi_config: $!\n";
 105         print $fh $old or die "failed to write: $!\n";
 106         close $oh or die "failed to close $pi_config: $!\n";
 107
 108         # yes, this conflict checking is racy if multiple instances of this
 109         # script are run by the same $PI_DIR
 110         my $cfg = PublicInbox::Config->new;
 111         my $conflict;
 112         foreach my $addr (@address) {
 113                 my $found = $cfg->lookup($addr);
 114                 if ($found) {
 115                         if ($found->{name} ne $name) {
 116                                 print STDERR
 117                                         "`$addr' already defined for ",
 118                                         "`$found->{name}',\n",
 119                                         "does not match intend `$name'\n";
 120                                 $conflict = 1;
 121                         } else {
 122                                 $seen{lc($addr)} = 1;
 123                         }
 124                 }
 125         }
 126
 127         exit(1) if $conflict;
 128
 129         my $ibx = $cfg->lookup_name($name);
 130         $indexlevel //= $ibx->{indexlevel} if $ibx;
 131 }
 132 my $pi_config_tmp = $fh->filename;
 133 close($fh) or die "failed to close $pi_config_tmp: $!\n";
 134
 135 my $pfx = "publicinbox.$name";
 136 my @x = (qw/git config/, "--file=$pi_config_tmp");
 137
 138 $inboxdir = PublicInbox::Config::rel2abs_collapsed($inboxdir);
 139 die "`\\n' not allowed in `$inboxdir'\n" if index($inboxdir, "\n") >= 0;
 140
 141 if (-f "$inboxdir/inbox.lock") {
 142         if (!defined $version) {
 143                 $version = 2;
 144         } elsif ($version != 2) {
 145                 die "$inboxdir is a -V2 inbox, -V$version specified\n"
 146         }
 147 } elsif (-d "$inboxdir/objects") {
 148         if (!defined $version) {
 149                 $version = 1;
 150         } elsif ($version != 1) {
 151                 die "$inboxdir is a -V1 inbox, -V$version specified\n"
 152         }
 153 }
 154
 155 $version = 1 unless defined $version;
 156
 157 if ($version == 1 && defined $skip_epoch) {
 158         die "--skip-epoch is only supported for -V2 inboxes\n";
 159 }
 160
 161 my $ibx = PublicInbox::Inbox->new({
 162         inboxdir => $inboxdir,
 163         name => $name,
 164         version => $version,
 165         -primary_address => $address[0],
 166         indexlevel => $indexlevel,
 167 });
 168
 169 my $creat_opt = {};
 170 if (defined $jobs) {
 171         die "--jobs is only supported for -V2 inboxes\n" if $version == 1;
 172         die "--jobs=$jobs must be >= 1\n" if $jobs <= 0;
 173         $creat_opt->{nproc} = $jobs;
 174 }
 175
 176 require PublicInbox::InboxWritable;
 177 $ibx = PublicInbox::InboxWritable->new($ibx, $creat_opt);
 178 if ($skip_docdata) {
 179         $ibx->{indexlevel} //= 'full'; # ensure init_inbox writes xdb
 180         $ibx->{indexlevel} eq 'basic' and
 181                 die "--skip-docdata ignored with --indexlevel=basic\n";
 182         $ibx->{-skip_docdata} = $skip_docdata;
 183 }
 184 $ibx->init_inbox(0, $skip_epoch, $skip_artnum);
 185
 186 # needed for git prior to v2.1.0
 187 umask(0077) if defined $perm;
 188
 189 require PublicInbox::Spawn;
 190 PublicInbox::Spawn->import(qw(run_die));
 191
 192 foreach my $addr (@address) {
 193         next if $seen{lc($addr)};
 194         run_die([@x, "--add", "$pfx.address", $addr]);
 195 }
 196 run_die([@x, "$pfx.url", $http_url]);
 197 run_die([@x, "$pfx.inboxdir", $inboxdir]);
 198
 199 if (defined($indexlevel)) {
 200         run_die([@x, "$pfx.indexlevel", $indexlevel]);
 201 }
 202 run_die([@x, "$pfx.newsgroup", $ng]) if $ng ne '';
 203
 204 # needed for git prior to v2.1.0
 205 if (defined $perm) {
 206         chmod($perm & 07777, $pi_config_tmp) or
 207                         die "(f)chmod failed on future $pi_config: $!\n";
 208 }
 209
 210 rename $pi_config_tmp, $pi_config or
 211         die "failed to rename `$pi_config_tmp' to `$pi_config': $!\n";
 212 undef $auto_unlink; # trigger ->DESTROY