script/public-inbox-learn

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2014-2019 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Used for training spam (via SpamAssassin) and removing messages from a
   6 # public-inbox
   7 my $usage = "$0 <spam|ham|rm> </path/to/message";
   8 use strict;
   9 use warnings;
  10 use PublicInbox::Config;
  11 use PublicInbox::InboxWritable;
  12 use PublicInbox::MIME;
  13 use PublicInbox::Address;
  14 use PublicInbox::Spamcheck::Spamc;
  15 my $train = shift or die "usage: $usage\n";
  16 if ($train !~ /\A(?:ham|spam|rm)\z/) {
  17         die "`$train' not recognized.\nusage: $usage\n";
  18 }
  19
  20 my $spamc = PublicInbox::Spamcheck::Spamc->new;
  21 my $pi_config = PublicInbox::Config->new;
  22 my $err;
  23 my $mime = PublicInbox::MIME->new(eval {
  24         local $/;
  25         my $data = scalar <STDIN>;
  26         $data =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  27
  28         if ($train ne 'rm') {
  29                 eval {
  30                         if ($train eq 'ham') {
  31                                 $spamc->hamlearn(\$data);
  32                         } elsif ($train eq 'spam') {
  33                                 $spamc->spamlearn(\$data);
  34                         }
  35                         die "spamc failed with: $?\n" if $?;
  36                 };
  37                 $err = $@;
  38         }
  39         $data
  40 });
  41
  42 # spam is removed from all known inboxes since it is often Bcc:-ed
  43 if ($train eq 'spam') {
  44         $pi_config->each_inbox(sub {
  45                 my ($ibx) = @_;
  46                 $ibx = PublicInbox::InboxWritable->new($ibx);
  47                 my $im = $ibx->importer(0);
  48                 $im->remove($mime, 'spam');
  49                 $im->done;
  50         });
  51 } else {
  52         require PublicInbox::MDA if $train eq "ham";
  53
  54         # get all recipients
  55         my %dests; # address => <PublicInbox::Inbox|0(false)>
  56         for ($mime->header('Cc'), $mime->header('To')) {
  57                 foreach my $addr (PublicInbox::Address::emails($_)) {
  58                         $addr = lc($addr);
  59                         $dests{$addr} //= $pi_config->lookup($addr) // 0;
  60                 }
  61         }
  62
  63         # n.b. message may be cross-posted to multiple public-inboxes
  64         while (my ($addr, $dst) = each %dests) {
  65                 next unless ref($dst);
  66                 # We do not touch GIT_COMMITTER_* env here so we can track
  67                 # who trained the message.
  68                 $dst->{name} = $ENV{GIT_COMMITTER_NAME} || $dst->{name};
  69                 $dst->{-primary_address} = $ENV{GIT_COMMITTER_EMAIL} || $addr;
  70                 $dst = PublicInbox::InboxWritable->new($dst);
  71                 my $im = $dst->importer(0);
  72
  73                 if ($train eq "rm") {
  74                         # This needs to be idempotent, as my inotify trainer
  75                         # may train for each cross-posted message, and this
  76                         # script already learns for every list in
  77                         # ~/.public-inbox/config
  78                         $im->remove($mime, $train);
  79                 } elsif ($train eq "ham") {
  80                         # no checking for spam here, we assume the message has
  81                         # been reviewed by a human at this point:
  82                         PublicInbox::MDA->set_list_headers($mime, $dst);
  83
  84                         # Ham messages are trained when they're marked into
  85                         # a SEEN state, so this is idempotent:
  86                         $im->add($mime);
  87                 }
  88                 $im->done;
  89         }
  90 }
  91
  92 if ($err) {
  93         warn $err;
  94         exit 1;
  95 }