script/public-inbox-learn

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2014-2019 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Used for training spam (via SpamAssassin) and removing messages from a
   6 # public-inbox
   7 my $usage = "$0 (spam|ham) < /path/to/message";
   8 use strict;
   9 use warnings;
  10 use PublicInbox::Config;
  11 use PublicInbox::InboxWritable;
  12 use PublicInbox::MIME;
  13 use PublicInbox::Address;
  14 use PublicInbox::Spamcheck::Spamc;
  15 my $train = shift or die "usage: $usage\n";
  16 if ($train !~ /\A(?:ham|spam|rm)\z/) {
  17         die "`$train' not recognized.\nusage: $usage\n";
  18 }
  19
  20 my $spamc = PublicInbox::Spamcheck::Spamc->new;
  21 my $pi_config = PublicInbox::Config->new;
  22 my $err;
  23 my $mime = PublicInbox::MIME->new(eval {
  24         local $/;
  25         my $data = scalar <STDIN>;
  26         $data =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  27
  28         if ($train ne 'rm') {
  29                 eval {
  30                         if ($train eq 'ham') {
  31                                 $spamc->hamlearn(\$data);
  32                         } elsif ($train eq 'spam') {
  33                                 $spamc->spamlearn(\$data);
  34                         }
  35                         die "spamc failed with: $?\n" if $?;
  36                 };
  37                 $err = $@;
  38         }
  39         $data
  40 });
  41
  42 # get all recipients
  43 my %dests;
  44 foreach my $h (qw(Cc To)) {
  45         my $val = $mime->header($h) or next;
  46         foreach my $email (PublicInbox::Address::emails($val)) {
  47                 $dests{lc($email)} = 1;
  48         }
  49 }
  50
  51 if ($train eq 'spam') {
  52         $pi_config->each_inbox(sub {
  53                 my ($ibx) = @_;
  54                 $ibx = PublicInbox::InboxWritable->new($ibx);
  55                 my $im = $ibx->importer(0);
  56                 $im->remove($mime, 'spam');
  57                 $im->done;
  58         });
  59 }
  60
  61 require PublicInbox::MDA if $train eq "ham";
  62
  63 # n.b. message may be cross-posted to multiple public-inboxes
  64 foreach my $recipient (keys %dests) {
  65         my $dst = $pi_config->lookup($recipient) or next;
  66         # We do not touch GIT_COMMITTER_* env here so we can track
  67         # who trained the message.
  68         $dst->{name} = $ENV{GIT_COMMITTER_NAME} || $dst->{name};
  69         $dst->{-primary_address} = $ENV{GIT_COMMITTER_EMAIL} || $recipient;
  70         $dst = PublicInbox::InboxWritable->new($dst);
  71         my $im = $dst->importer(0);
  72
  73         if ($train eq "spam" || $train eq "rm") {
  74                 # This needs to be idempotent, as my inotify trainer
  75                 # may train for each cross-posted message, and this
  76                 # script already learns for every list in
  77                 # ~/.public-inbox/config
  78                 $im->remove($mime, $train);
  79         } else { # $train eq "ham"
  80                 # no checking for spam here, we assume the message has
  81                 # been reviewed by a human at this point:
  82                 PublicInbox::MDA->set_list_headers($mime, $dst);
  83
  84                 # Ham messages are trained when they're marked into
  85                 # a SEEN state, so this is idempotent:
  86                 $im->add($mime);
  87         }
  88         $im->done;
  89 }
  90
  91 if ($err) {
  92         warn $err;
  93         exit 1;
  94 }