script/public-inbox-mda

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2013-2019 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Mail delivery agent for public-inbox, run from your MTA upon mail delivery
   6 use strict;
   7 use warnings;
   8 my $usage = 'public-inbox-mda [OPTIONS] < rfc2822_message';
   9 my $precheck = grep(/\A--no-precheck\z/, @ARGV) ? 0 : 1;
  10 my ($ems, $emm);
  11
  12 sub do_exit {
  13         my ($code) = shift;
  14         $emm = $ems = undef; # trigger DESTROY
  15         exit $code;
  16 }
  17
  18 use Email::Simple;
  19 use PublicInbox::MIME;
  20 use PublicInbox::MDA;
  21 use PublicInbox::Config;
  22 use PublicInbox::Emergency;
  23 use PublicInbox::Filter::Base;
  24 use PublicInbox::InboxWritable;
  25 use PublicInbox::Spamcheck;
  26
  27 # n.b: hopefully we can setup the emergency path without bailing due to
  28 # user error, we really want to setup the emergency destination ASAP
  29 # in case there's bugs in our code or user error.
  30 my $emergency = $ENV{PI_EMERGENCY} || "$ENV{HOME}/.public-inbox/emergency/";
  31 $ems = PublicInbox::Emergency->new($emergency);
  32 my $str = eval { local $/; <STDIN> };
  33 $str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  34 $ems->prepare(\$str);
  35 my $simple = Email::Simple->new(\$str);
  36 my $config = PublicInbox::Config->new;
  37 my $key = 'publicinboxmda.spamcheck';
  38 my $default = 'PublicInbox::Spamcheck::Spamc';
  39 my $spamc = PublicInbox::Spamcheck::get($config, $key, $default);
  40 my $dst;
  41 my $recipient = $ENV{ORIGINAL_RECIPIENT};
  42 if (defined $recipient) {
  43         $dst = $config->lookup($recipient); # first check
  44 }
  45 if (!defined $dst) {
  46         my $list_id = $simple->header('List-Id');
  47         if (defined $list_id && $list_id =~ /<[ \t]*(.+)?[ \t]*>/) {
  48                 $dst = $config->lookup_list_id($1);
  49         }
  50         if (!defined $dst && !defined $recipient) {
  51                 die "ORIGINAL_RECIPIENT not defined in ENV\n";
  52         }
  53         defined $dst or do_exit(67); # EX_NOUSER 5.1.1 user unknown
  54 }
  55 $dst->{mainrepo} or do_exit(67);
  56 $dst = PublicInbox::InboxWritable->new($dst);
  57
  58 # pre-check, MDA has stricter rules than an importer might;
  59 if ($precheck && !PublicInbox::MDA->precheck($simple, $dst->{address})) {
  60         do_exit(0);
  61 }
  62 $simple = undef;
  63 my $spam_ok;
  64 if ($spamc) {
  65         $str = '';
  66         $spam_ok = $spamc->spamcheck($ems->fh, \$str);
  67         # update the emergency dump with the new message:
  68         $emm = PublicInbox::Emergency->new($emergency);
  69         $emm->prepare(\$str);
  70         $ems = $ems->abort;
  71 } else { # no spam checking configured:
  72         $spam_ok = 1;
  73         $emm = $ems;
  74         my $fh = $emm->fh;
  75         read($fh, $str, -s $fh);
  76 }
  77
  78 my $mime = PublicInbox::MIME->new(\$str);
  79 do_exit(0) unless $spam_ok;
  80
  81 my $fcfg = $dst->{filter} || '';
  82 # -mda defaults to the strict base filter
  83 if ($fcfg eq '') {
  84         $dst->{filter} = 'PublicInbox::Filter::Base';
  85 } elsif ($fcfg eq 'scrub') { # legacy alias, undocumented, remove?
  86         $dst->{filter} = 'PublicInbox::Filter::Mirror';
  87 }
  88 my $filter = $dst->filter;
  89 my $ret = $filter->delivery($mime);
  90 if (ref($ret) && $ret->isa('Email::MIME')) { # filter altered message
  91         $mime = $ret;
  92 } elsif ($ret == PublicInbox::Filter::Base::IGNORE) {
  93         do_exit(0); # chuck it to emergency
  94 } elsif ($ret == PublicInbox::Filter::Base::REJECT) {
  95         $! = 65; # EX_DATAERR 5.6.0 data format error
  96         die $filter->err, "\n";
  97 } # else { accept
  98 $filter = undef;
  99
 100 PublicInbox::MDA->set_list_headers($mime, $dst);
 101 my $im = $dst->importer(0);
 102 if (defined $im->add($mime)) {
 103         $emm = $emm->abort;
 104 } else {
 105         # this message is similar to what ssoma-mda shows:
 106         print STDERR "CONFLICT: Message-ID: ",
 107                         $mime->header_obj->header_raw('Message-ID'),
 108                         " exists\n";
 109 }
 110
 111 $im->done;
 112 do_exit(0);