script/public-inbox-mda

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2013-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Mail delivery agent for public-inbox, run from your MTA upon mail delivery
   6 use strict;
   7 use warnings;
   8 my $usage = 'public-inbox-mda [OPTIONS] < rfc2822_message';
   9 my $precheck = grep(/\A--no-precheck\z/, @ARGV) ? 0 : 1;
  10 my ($ems, $emm);
  11
  12 my $do_exit = sub {
  13         my ($code) = shift;
  14         $emm = $ems = undef; # trigger DESTROY
  15         exit $code;
  16 };
  17
  18 use Email::Simple;
  19 use PublicInbox::MIME;
  20 use PublicInbox::MDA;
  21 use PublicInbox::Config;
  22 use PublicInbox::Emergency;
  23 use PublicInbox::Filter::Base;
  24 use PublicInbox::InboxWritable;
  25 use PublicInbox::Spamcheck;
  26
  27 # n.b: hopefully we can setup the emergency path without bailing due to
  28 # user error, we really want to setup the emergency destination ASAP
  29 # in case there's bugs in our code or user error.
  30 my $emergency = $ENV{PI_EMERGENCY} || "$ENV{HOME}/.public-inbox/emergency/";
  31 $ems = PublicInbox::Emergency->new($emergency);
  32 my $str = eval { local $/; <STDIN> };
  33 $str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
  34 $ems->prepare(\$str);
  35 my $simple = Email::Simple->new(\$str);
  36 my $config = PublicInbox::Config->new;
  37 my $key = 'publicinboxmda.spamcheck';
  38 my $default = 'PublicInbox::Spamcheck::Spamc';
  39 my $spamc = PublicInbox::Spamcheck::get($config, $key, $default);
  40 my $dests = [];
  41 my $recipient = $ENV{ORIGINAL_RECIPIENT};
  42 if (defined $recipient) {
  43         my $ibx = $config->lookup($recipient); # first check
  44         push @$dests, $ibx if $ibx;
  45 }
  46 if (!scalar(@$dests)) {
  47         $dests = PublicInbox::MDA->inboxes_for_list_id($config, $simple);
  48         if (!scalar(@$dests) && !defined($recipient)) {
  49                 die "ORIGINAL_RECIPIENT not defined in ENV\n";
  50         }
  51         scalar(@$dests) or $do_exit->(67); # EX_NOUSER 5.1.1 user unknown
  52 }
  53
  54 my $err;
  55 @$dests = grep {
  56         my $ibx = PublicInbox::InboxWritable->new($_);
  57         eval { $ibx->assert_usable_dir };
  58         if ($@) {
  59                 warn $@;
  60                 $err = 1;
  61                 0;
  62         # pre-check, MDA has stricter rules than an importer might;
  63         } elsif ($precheck) {
  64                 !!PublicInbox::MDA->precheck($simple, $ibx->{address});
  65         } else {
  66                 1;
  67         }
  68 } @$dests;
  69
  70 $do_exit->(67) if $err && scalar(@$dests) == 0;
  71
  72 $simple = undef;
  73 my $spam_ok;
  74 if ($spamc) {
  75         $str = '';
  76         $spam_ok = $spamc->spamcheck($ems->fh, \$str);
  77         # update the emergency dump with the new message:
  78         $emm = PublicInbox::Emergency->new($emergency);
  79         $emm->prepare(\$str);
  80         $ems = $ems->abort;
  81 } else { # no spam checking configured:
  82         $spam_ok = 1;
  83         $emm = $ems;
  84         my $fh = $emm->fh;
  85         read($fh, $str, -s $fh);
  86 }
  87 $do_exit->(0) unless $spam_ok;
  88
  89 # -mda defaults to the strict base filter which we won't use anywhere else
  90 sub mda_filter_adjust ($) {
  91         my ($ibx) = @_;
  92         my $fcfg = $ibx->{filter} || '';
  93         if ($fcfg eq '') {
  94                 $ibx->{filter} = 'PublicInbox::Filter::Base';
  95         } elsif ($fcfg eq 'scrub') { # legacy alias, undocumented, remove?
  96                 $ibx->{filter} = 'PublicInbox::Filter::Mirror';
  97         }
  98 }
  99
 100 my @rejects;
 101 for my $ibx (@$dests) {
 102         mda_filter_adjust($ibx);
 103         my $filter = $ibx->filter;
 104         my $mime = PublicInbox::MIME->new($str);
 105         my $ret = $filter->delivery($mime);
 106         if (ref($ret) && $ret->isa('Email::MIME')) { # filter altered message
 107                 $mime = $ret;
 108         } elsif ($ret == PublicInbox::Filter::Base::IGNORE) {
 109                 next; # nothing, keep looping
 110         } elsif ($ret == PublicInbox::Filter::Base::REJECT) {
 111                 push @rejects, $filter->err;
 112                 next;
 113         }
 114
 115         PublicInbox::MDA->set_list_headers($mime, $ibx);
 116         my $im = $ibx->importer(0);
 117         if (defined $im->add($mime)) {
 118                 # ->abort is idempotent, no emergency if a single
 119                 # destination succeeds
 120                 $emm->abort;
 121         } else { # v1-only
 122                 my $mid = $mime->header_obj->header_raw('Message-ID');
 123                 # this message is similar to what ssoma-mda shows:
 124                 print STDERR "CONFLICT: Message-ID: $mid exists\n";
 125         }
 126         $im->done;
 127 }
 128
 129 if (scalar(@rejects) && scalar(@rejects) == scalar(@$dests)) {
 130         $! = 65; # EX_DATAERR 5.6.0 data format error
 131         die join("\n", @rejects, '');
 132 }
 133
 134 $do_exit->(0);