scripts/import_vger_from_mbox

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use warnings;
   6 use Email::MIME;
   7 $Email::MIME::ContentType::STRICT_PARAMS = 0; # user input is imperfect
   8 use PublicInbox::Git;
   9 use PublicInbox::Import;
  10 my $usage = "usage: $0 NAME EMAIL <MBOX\n";
  11 chomp(my $git_dir = `git rev-parse --git-dir`);
  12 my $git = PublicInbox::Git->new($git_dir);
  13 my $name = shift or die $usage; # git
  14 my $email = shift or die $usage; # git@vger.kernel.org
  15 my $im = PublicInbox::Import->new($git, $name, $email);
  16 binmode STDIN;
  17 my $msg = '';
  18 use PublicInbox::Filter::Vger;
  19 my $vger = PublicInbox::Filter::Vger->new;
  20 sub do_add ($$) {
  21         my ($im, $msg) = @_;
  22         $$msg =~ s/(\r?\n)+\z/$1/s;
  23         $msg = Email::MIME->new($$msg);
  24         $msg = $vger->scrub($msg);
  25         $im->add($msg) or
  26                 warn "duplicate: ",
  27                         $msg->header_obj->header_raw('Message-ID'), "\n";
  28 }
  29
  30 # asctime: From example@example.com Fri Jun 23 02:56:55 2000
  31 my $from_strict = qr/^From \S+ \S+ \S+ +\S+ [^:]+:[^:]+:[^:]+ [^:]+/;
  32 my $prev = undef;
  33 while (defined(my $l = <STDIN>)) {
  34         if ($l =~ /$from_strict/o) {
  35                 if (!defined($prev) || $prev =~ /^\r?$/) {
  36                         do_add($im, \$msg) if $msg;
  37                         $msg = '';
  38                         $prev = $l;
  39                         next;
  40                 }
  41                 warn "W[$.] $l\n";
  42         }
  43         $prev = $l;
  44         $msg .= $l;
  45 }
  46 do_add($im, \$msg) if $msg;
  47 $im->done;