scripts/import_vger_from_mbox

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use warnings;
   6 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   7 use Date::Parse qw/str2time/;
   8 use Email::MIME;
   9 $Email::MIME::ContentType::STRICT_PARAMS = 0; # user input is imperfect
  10 use PublicInbox::V2Writable;
  11 my $usage = "usage: $0 NAME EMAIL DIR <MBOX\n";
  12 my $dry_run;
  13 my %opts = ( 'n|dry-run' => \$dry_run );
  14 GetOptions(%opts) or die $usage;
  15 my $name = shift or die $usage; # git
  16 my $email = shift or die $usage; # git@vger.kernel.org
  17 my $mainrepo = shift or die $usage; # /path/to/v2/repo
  18 my $v2ibx = {
  19         mainrepo => $mainrepo,
  20         name => $name,
  21         -primary_address => $email,
  22 };
  23 my $im = $dry_run ? undef : PublicInbox::V2Writable->new($v2ibx, 1);
  24 binmode STDIN;
  25 my $msg = '';
  26 use PublicInbox::Filter::Vger;
  27 my $vger = PublicInbox::Filter::Vger->new;
  28
  29 sub do_add ($$) {
  30         my ($im, $msg) = @_;
  31         $$msg =~ s/(\r?\n)+\z/$1/s;
  32         $msg = Email::MIME->new($$msg);
  33         $msg = $vger->scrub($msg);
  34         return unless $im;
  35         $im->add($msg) or
  36                 warn "duplicate: ",
  37                         $msg->header_obj->header_raw('Message-ID'), "\n";
  38 }
  39
  40 # asctime: From example@example.com Fri Jun 23 02:56:55 2000
  41 my $from_strict = qr/^From \S+ +\S+ \S+ +\S+ [^:]+:[^:]+:[^:]+ [^:]+/;
  42 my $prev = undef;
  43 while (defined(my $l = <STDIN>)) {
  44         if ($l =~ /$from_strict/o) {
  45                 if (!defined($prev) || $prev =~ /^\r?$/) {
  46                         do_add($im, \$msg) if $msg;
  47                         $msg = '';
  48                         $prev = $l;
  49                         next;
  50                 }
  51                 warn "W[$.] $l\n";
  52         }
  53         $prev = $l;
  54         $msg .= $l;
  55 }
  56 do_add($im, \$msg) if $msg;
  57 $im->done if $im;