t/address.t

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use_ok 'PublicInbox::Address';
   7
   8 sub test_pkg {
   9         my ($pkg) = @_;
  10         my $emails = \&{"${pkg}::emails"};
  11         my $names = \&{"${pkg}::names"};
  12
  13         is_deeply([qw(e@example.com e@example.org)],
  14                 [$emails->('User <e@example.com>, e@example.org')],
  15                 'address extraction works as expected');
  16
  17         is_deeply(['user@example.com'],
  18                 [$emails->('<user@example.com (Comment)>')],
  19                 'comment after domain accepted before >');
  20
  21         my @names = $names->(
  22                 'User <e@e>, e@e, "John A. Doe" <j@d>, <x@x>, <y@x> (xyz), '.
  23                 'U Ser <u@x> (do not use)');
  24         is_deeply(\@names, ['User', 'e', 'John A. Doe', 'x', 'xyz', 'U Ser'],
  25                 'name extraction works as expected');
  26
  27         @names = $names->('"user@example.com" <user@example.com>');
  28         is_deeply(['user'], \@names,
  29                 'address-as-name extraction works as expected');
  30
  31         {
  32                 my $backwards = 'u@example.com (John Q. Public)';
  33                 @names = $names->($backwards);
  34                 is_deeply(\@names, ['John Q. Public'], 'backwards name OK');
  35                 my @emails = $emails->($backwards);
  36                 is_deeply(\@emails, ['u@example.com'], 'backwards emails OK');
  37         }
  38
  39         @names = $names->('"Quote Unneeded" <user@example.com>');
  40         is_deeply(['Quote Unneeded'], \@names, 'extra quotes dropped');
  41
  42         my @emails = $emails->('Local User <user>');
  43         is_deeply([], \@emails , 'no address for local address');
  44         @names = $emails->('Local User <user>');
  45         is_deeply([], \@names, 'no address, no name');
  46 }
  47
  48 test_pkg('PublicInbox::Address');
  49
  50 SKIP: {
  51         if ($INC{'PublicInbox/AddressPP.pm'}) {
  52                 skip 'Email::Address::XS missing', 8;
  53         }
  54         use_ok 'PublicInbox::AddressPP';
  55         test_pkg('PublicInbox::AddressPP');
  56 }
  57
  58 done_testing;