t/admin.t

   1 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::TestCommon;
   7 use PublicInbox::Import;
   8 use_ok 'PublicInbox::Admin';
   9 my ($tmpdir, $for_destroy) = tmpdir();
  10 my $git_dir = "$tmpdir/v1";
  11 my $v2_dir = "$tmpdir/v2";
  12 my ($res, $err, $v);
  13
  14 PublicInbox::Import::init_bare($git_dir);
  15 *resolve_inboxdir = do {
  16         no warnings 'once';
  17         *PublicInbox::Admin::resolve_inboxdir;
  18 };
  19
  20 # v1
  21 is(resolve_inboxdir($git_dir), $git_dir, 'top-level GIT_DIR resolved');
  22 is(resolve_inboxdir("$git_dir/objects"), $git_dir, 'GIT_DIR/objects resolved');
  23
  24 ok(chdir($git_dir), 'chdir GIT_DIR works');
  25 is(resolve_inboxdir(), $git_dir, 'resolve_inboxdir works in GIT_DIR');
  26
  27 ok(chdir("$git_dir/objects"), 'chdir GIT_DIR/objects works');
  28 is(resolve_inboxdir(), $git_dir, 'resolve_inboxdir works in GIT_DIR');
  29 $res = resolve_inboxdir(undef, \$v);
  30 is($v, 1, 'version 1 detected');
  31 is($res, $git_dir, 'detects directory along with version');
  32
  33 # $tmpdir could be inside a git working, directory, so we test '/'
  34 SKIP: {
  35         my $no_vcs_dir = '/';
  36         # do people version-control "/"?
  37         skip "$no_vcs_dir is version controlled by git", 4 if -d '/.git';
  38         open my $null, '>', '/dev/null' or die "open /dev/null: $!";
  39         open my $olderr, '>&', \*STDERR or die "dup stderr: $!";
  40
  41         ok(chdir($no_vcs_dir), 'chdir to a non-inbox');
  42         open STDERR, '>&', $null or die "redirect stderr to /dev/null: $!";
  43         $res = eval { resolve_inboxdir() };
  44         open STDERR, '>&', $olderr or die "restore stderr: $!";
  45         is($res, undef, 'fails inside non-version-controlled dir');
  46
  47         ok(chdir($tmpdir), 'back to test-specific $tmpdir');
  48         open STDERR, '>&', $null or die "redirect stderr to /dev/null: $!";
  49         $res = eval { resolve_inboxdir($no_vcs_dir) };
  50         $err = $@;
  51         open STDERR, '>&', $olderr or die "restore stderr: $!";
  52         is($res, undef, 'fails on non-version-controlled dir');
  53         ok($err, '$@ set on failure');
  54 }
  55
  56 # v2
  57 SKIP: {
  58         for my $m (qw(DBD::SQLite)) {
  59                 skip "$m missing", 5 unless eval "require $m";
  60         }
  61         use_ok 'PublicInbox::V2Writable';
  62         use_ok 'PublicInbox::Inbox';
  63         my $ibx = PublicInbox::Inbox->new({
  64                         inboxdir => $v2_dir,
  65                         name => 'test-v2writable',
  66                         version => 2,
  67                         -primary_address => 'test@example.com',
  68                         indexlevel => 'basic',
  69                 });
  70         PublicInbox::V2Writable->new($ibx, 1)->idx_init;
  71
  72         ok(-e "$v2_dir/inbox.lock", 'exists');
  73         is(resolve_inboxdir($v2_dir), $v2_dir,
  74                 'resolve_inboxdir works on v2_dir');
  75         ok(chdir($v2_dir), 'chdir v2_dir OK');
  76         is(resolve_inboxdir(), $v2_dir, 'resolve_inboxdir works inside v2_dir');
  77         $res = resolve_inboxdir(undef, \$v);
  78         is($v, 2, 'version 2 detected');
  79         is($res, $v2_dir, 'detects directory along with version');
  80
  81         # TODO: should work from inside Xapian dirs, and git dirs, here...
  82 }
  83
  84 chdir '/';
  85
  86 my @pairs = (
  87         '1g' => 1024 ** 3,
  88         666 => 666,
  89         '1500K' => 1500 * 1024,
  90         '15m' => 15 * (1024 ** 2),
  91 );
  92
  93 while (@pairs) {
  94         my ($in, $out) = splice(@pairs, 0, 2);
  95         my $orig = $in;
  96         ok(PublicInbox::Admin::parse_unsigned(\$in), "parse_unsigned $orig");
  97         is($in, $out, "got $orig => ($in == $out)");
  98 }
  99
 100 for my $v ('', 'bogus', '1p', '1gig') {
 101         ok(!PublicInbox::Admin::parse_unsigned(\$v),
 102                 "parse_unsigned rejects $v");
 103 }
 104
 105 done_testing();