t/cgi.t

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # FIXME: this test is too slow and most non-CGI-requirements
   4 # should be moved over to things which use test_psgi
   5 use strict;
   6 use warnings;
   7 use Test::More;
   8 use Email::MIME;
   9 use File::Temp qw/tempdir/;
  10 eval { require IPC::Run };
  11 plan skip_all => "missing IPC::Run for t/cgi.t" if $@;
  12
  13 use constant CGI => "blib/script/public-inbox.cgi";
  14 my $tmpdir = tempdir('pi-cgi-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  15 my $home = "$tmpdir/pi-home";
  16 my $pi_home = "$home/.public-inbox";
  17 my $pi_config = "$pi_home/config";
  18 my $maindir = "$tmpdir/main.git";
  19 my $addr = 'test-public@example.com';
  20 my $cfgpfx = "publicinbox.test";
  21
  22 {
  23         is(1, mkdir($home, 0755), "setup ~/ for testing");
  24         is(1, mkdir($pi_home, 0755), "setup ~/.public-inbox");
  25         is(0, system(qw(git init -q --bare), $maindir), "git init (main)");
  26
  27         open my $fh, '>', "$maindir/description" or die "open: $!\n";
  28         print $fh "test for public-inbox\n";
  29         close $fh or die "close: $!\n";
  30         my %cfg = (
  31                 "$cfgpfx.address" => $addr,
  32                 "$cfgpfx.mainrepo" => $maindir,
  33         );
  34         while (my ($k,$v) = each %cfg) {
  35                 is(0, system(qw(git config --file), $pi_config, $k, $v),
  36                         "setup $k");
  37         }
  38 }
  39
  40 use_ok 'PublicInbox::Git';
  41 use_ok 'PublicInbox::Import';
  42 use_ok 'Email::MIME';
  43 my $git = PublicInbox::Git->new($maindir);
  44 my $im = PublicInbox::Import->new($git, 'test', $addr);
  45
  46 {
  47         local $ENV{HOME} = $home;
  48
  49         # inject some messages:
  50         my $mime = Email::MIME->new(<<EOF);
  51 From: Me <me\@example.com>
  52 To: You <you\@example.com>
  53 Cc: $addr
  54 Message-Id: <blah\@example.com>
  55 Subject: hihi
  56 Date: Thu, 01 Jan 1970 00:00:00 +0000
  57
  58 zzzzzz
  59 EOF
  60         $im->add($mime);
  61
  62         # deliver a reply, too
  63         my $reply = Email::MIME->new(<<EOF);
  64 From: You <you\@example.com>
  65 To: Me <me\@example.com>
  66 Cc: $addr
  67 In-Reply-To: <blah\@example.com>
  68 Message-Id: <blahblah\@example.com>
  69 Subject: Re: hihi
  70 Date: Thu, 01 Jan 1970 00:00:01 +0000
  71
  72 Me wrote:
  73 > zzzzzz
  74
  75 what?
  76 EOF
  77         $im->add($reply);
  78
  79         my $slashy_mid = 'slashy/asdf@example.com';
  80         my $slashy = Email::MIME->new(<<EOF);
  81 From: You <you\@example.com>
  82 To: Me <me\@example.com>
  83 Cc: $addr
  84 Message-Id: <$slashy_mid>
  85 Subject: Re: hihi
  86 Date: Thu, 01 Jan 1970 00:00:01 +0000
  87
  88 slashy
  89 EOF
  90         $im->add($slashy);
  91         $im->done;
  92
  93         my $res = cgi_run("/test/slashy/asdf\@example.com/raw");
  94         like($res->{body}, qr/Message-Id: <\Q$slashy_mid\E>/,
  95                 "slashy mid raw hit");
  96 }
  97
  98 # retrieve thread as an mbox
  99 {
 100         local $ENV{HOME} = $home;
 101         my $path = "/test/blahblah\@example.com/t.mbox.gz";
 102         my $res = cgi_run($path);
 103         like($res->{head}, qr/^Status: 501 /, "search not-yet-enabled");
 104         my $indexed;
 105         eval {
 106                 require PublicInbox::SearchIdx;
 107                 my $s = PublicInbox::SearchIdx->new($maindir, 1);
 108                 $s->index_sync;
 109                 $indexed = 1;
 110         };
 111         if ($indexed) {
 112                 $res = cgi_run($path);
 113                 like($res->{head}, qr/^Status: 200 /, "search returned mbox");
 114                 eval {
 115                         require IO::Uncompress::Gunzip;
 116                         my $in = $res->{body};
 117                         my $out;
 118                         IO::Uncompress::Gunzip::gunzip(\$in => \$out);
 119                         like($out, qr/^From /m, "From lines in mbox");
 120                 };
 121         } else {
 122                 like($res->{head}, qr/^Status: 501 /, "search not available");
 123         }
 124
 125         my $have_xml_feed = eval { require XML::Feed; 1 } if $indexed;
 126         if ($have_xml_feed) {
 127                 $path = "/test/blahblah\@example.com/t.atom";
 128                 $res = cgi_run($path);
 129                 like($res->{head}, qr/^Status: 200 /, "atom returned 200");
 130                 like($res->{head}, qr!^Content-Type: application/atom\+xml!m,
 131                         "search returned atom");
 132                 my $p = XML::Feed->parse(\($res->{body}));
 133                 is($p->format, "Atom", "parsed atom feed");
 134                 is(scalar $p->entries, 3, "parsed three entries");
 135         }
 136 }
 137
 138 done_testing();
 139
 140 sub run_with_env {
 141         my ($env, @args) = @_;
 142         IPC::Run::run(@args, init => sub { %ENV = (%ENV, %$env) });
 143 }
 144
 145 sub cgi_run {
 146         my %env = (
 147                 PATH_INFO => $_[0],
 148                 QUERY_STRING => $_[1] || "",
 149                 SCRIPT_NAME => '',
 150                 REQUEST_URI => $_[0] . ($_[1] ? "?$_[1]" : ''),
 151                 REQUEST_METHOD => $_[2] || "GET",
 152                 GATEWAY_INTERFACE => 'CGI/1.1',
 153                 HTTP_ACCEPT => '*/*',
 154                 HTTP_HOST => 'test.example.com',
 155         );
 156         my ($in, $out, $err) = ("", "", "");
 157         my $rc = run_with_env(\%env, [CGI], \$in, \$out, \$err);
 158         my ($head, $body) = split(/\r\n\r\n/, $out, 2);
 159         { head => $head, body => $body, rc => $rc, err => $err }
 160 }