t/cgi.t

   1 # Copyright (C) 2014-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # FIXME: this test is too slow and most non-CGI-requirements
   4 # should be moved over to things which use test_psgi
   5 use strict;
   6 use warnings;
   7 use Test::More;
   8 use Email::MIME;
   9 use File::Temp qw/tempdir/;
  10 require './t/common.perl';
  11 my $tmpdir = tempdir('pi-cgi-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  12 my $home = "$tmpdir/pi-home";
  13 my $pi_home = "$home/.public-inbox";
  14 my $pi_config = "$pi_home/config";
  15 my $maindir = "$tmpdir/main.git";
  16 my $addr = 'test-public@example.com';
  17 my $cfgpfx = "publicinbox.test";
  18
  19 {
  20         is(1, mkdir($home, 0755), "setup ~/ for testing");
  21         is(1, mkdir($pi_home, 0755), "setup ~/.public-inbox");
  22         is(0, system(qw(git init -q --bare), $maindir), "git init (main)");
  23
  24         open my $fh, '>', "$maindir/description" or die "open: $!\n";
  25         print $fh "test for public-inbox\n";
  26         close $fh or die "close: $!\n";
  27         my %cfg = (
  28                 "$cfgpfx.address" => $addr,
  29                 "$cfgpfx.inboxdir" => $maindir,
  30                 "$cfgpfx.indexlevel" => 'basic',
  31         );
  32         while (my ($k,$v) = each %cfg) {
  33                 is(0, system(qw(git config --file), $pi_config, $k, $v),
  34                         "setup $k");
  35         }
  36 }
  37
  38 use_ok 'PublicInbox::Git';
  39 use_ok 'PublicInbox::Import';
  40 use_ok 'PublicInbox::Inbox';
  41 use_ok 'PublicInbox::InboxWritable';
  42 use_ok 'PublicInbox::Config';
  43 my $cfg = PublicInbox::Config->new($pi_config);
  44 my $ibx = $cfg->lookup_name('test');
  45 my $im = PublicInbox::InboxWritable->new($ibx)->importer;
  46
  47 {
  48         local $ENV{HOME} = $home;
  49
  50         # inject some messages:
  51         my $mime = Email::MIME->new(<<EOF);
  52 From: Me <me\@example.com>
  53 To: You <you\@example.com>
  54 Cc: $addr
  55 Message-Id: <blah\@example.com>
  56 Subject: hihi
  57 Date: Thu, 01 Jan 1970 00:00:00 +0000
  58
  59 zzzzzz
  60 EOF
  61         $im->add($mime);
  62
  63         # deliver a reply, too
  64         my $reply = Email::MIME->new(<<EOF);
  65 From: You <you\@example.com>
  66 To: Me <me\@example.com>
  67 Cc: $addr
  68 In-Reply-To: <blah\@example.com>
  69 Message-Id: <blahblah\@example.com>
  70 Subject: Re: hihi
  71 Date: Thu, 01 Jan 1970 00:00:01 +0000
  72
  73 Me wrote:
  74 > zzzzzz
  75
  76 what?
  77 EOF
  78         $im->add($reply);
  79
  80         my $slashy_mid = 'slashy/asdf@example.com';
  81         my $slashy = Email::MIME->new(<<EOF);
  82 From: You <you\@example.com>
  83 To: Me <me\@example.com>
  84 Cc: $addr
  85 Message-Id: <$slashy_mid>
  86 Subject: Re: hihi
  87 Date: Thu, 01 Jan 1970 00:00:01 +0000
  88
  89 slashy
  90 EOF
  91         $im->add($slashy);
  92         $im->done;
  93
  94         my $res = cgi_run("/test/slashy/asdf\@example.com/raw");
  95         like($res->{body}, qr/Message-Id: <\Q$slashy_mid\E>/,
  96                 "slashy mid raw hit");
  97 }
  98
  99 # retrieve thread as an mbox
 100 {
 101         local $ENV{HOME} = $home;
 102         my $path = "/test/blahblah\@example.com/t.mbox.gz";
 103         my $res = cgi_run($path);
 104         like($res->{head}, qr/^Status: 501 /, "search not-yet-enabled");
 105         my $indexed;
 106         eval {
 107                 require DBD::SQLite;
 108                 require PublicInbox::SearchIdx;
 109                 my $s = PublicInbox::SearchIdx->new($ibx, 1);
 110                 $s->index_sync;
 111                 $indexed = 1;
 112         };
 113         if ($indexed) {
 114                 $res = cgi_run($path);
 115                 like($res->{head}, qr/^Status: 200 /, "search returned mbox");
 116                 eval {
 117                         require IO::Uncompress::Gunzip;
 118                         my $in = $res->{body};
 119                         my $out;
 120                         IO::Uncompress::Gunzip::gunzip(\$in => \$out);
 121                         like($out, qr/^From /m, "From lines in mbox");
 122                 };
 123         } else {
 124                 like($res->{head}, qr/^Status: 501 /, "search not available");
 125                 SKIP: { skip 'DBD::SQLite not available', 2 };
 126         }
 127
 128         my $have_xml_feed = eval { require XML::Feed; 1 } if $indexed;
 129         if ($have_xml_feed) {
 130                 $path = "/test/blahblah\@example.com/t.atom";
 131                 $res = cgi_run($path);
 132                 like($res->{head}, qr/^Status: 200 /, "atom returned 200");
 133                 like($res->{head}, qr!^Content-Type: application/atom\+xml!m,
 134                         "search returned atom");
 135                 my $p = XML::Feed->parse(\($res->{body}));
 136                 is($p->format, "Atom", "parsed atom feed");
 137                 is(scalar $p->entries, 3, "parsed three entries");
 138         } else {
 139                 SKIP: { skip 'DBD::SQLite or XML::Feed missing', 2 };
 140         }
 141 }
 142
 143 done_testing();
 144
 145 sub cgi_run {
 146         my %env = (
 147                 PATH_INFO => $_[0],
 148                 QUERY_STRING => $_[1] || "",
 149                 SCRIPT_NAME => '',
 150                 REQUEST_URI => $_[0] . ($_[1] ? "?$_[1]" : ''),
 151                 REQUEST_METHOD => $_[2] || "GET",
 152                 GATEWAY_INTERFACE => 'CGI/1.1',
 153                 HTTP_ACCEPT => '*/*',
 154                 HTTP_HOST => 'test.example.com',
 155         );
 156         my ($in, $out, $err) = ("", "", "");
 157         my $rdr = { 0 => \$in, 1 => \$out, 2 => \$err };
 158         run_script(['.cgi'], \%env, $rdr);
 159         die "unexpected error: \$?=$?" if $?;
 160         my ($head, $body) = split(/\r\n\r\n/, $out, 2);
 161         { head => $head, body => $body, err => $err }
 162 }