t/cgi.t

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # FIXME: this test is too slow and most non-CGI-requirements
   4 # should be moved over to things which use test_psgi
   5 use strict;
   6 use warnings;
   7 use Test::More;
   8 use Email::MIME;
   9 use File::Temp qw/tempdir/;
  10 use Cwd;
  11 eval { require IPC::Run };
  12 plan skip_all => "missing IPC::Run for t/cgi.t" if $@;
  13
  14 use constant CGI => "blib/script/public-inbox.cgi";
  15 my $index = "blib/script/public-inbox-index";
  16 my $tmpdir = tempdir('pi-cgi-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  17 my $home = "$tmpdir/pi-home";
  18 my $pi_home = "$home/.public-inbox";
  19 my $pi_config = "$pi_home/config";
  20 my $maindir = "$tmpdir/main.git";
  21 my $addr = 'test-public@example.com';
  22 my $cfgpfx = "publicinbox.test";
  23
  24 {
  25         is(1, mkdir($home, 0755), "setup ~/ for testing");
  26         is(1, mkdir($pi_home, 0755), "setup ~/.public-inbox");
  27         is(0, system(qw(git init -q --bare), $maindir), "git init (main)");
  28
  29         open my $fh, '>', "$maindir/description" or die "open: $!\n";
  30         print $fh "test for public-inbox\n";
  31         close $fh or die "close: $!\n";
  32         my %cfg = (
  33                 "$cfgpfx.address" => $addr,
  34                 "$cfgpfx.mainrepo" => $maindir,
  35         );
  36         while (my ($k,$v) = each %cfg) {
  37                 is(0, system(qw(git config --file), $pi_config, $k, $v),
  38                         "setup $k");
  39         }
  40 }
  41
  42 use_ok 'PublicInbox::Git';
  43 use_ok 'PublicInbox::Import';
  44 use_ok 'Email::MIME';
  45 my $git = PublicInbox::Git->new($maindir);
  46 my $im = PublicInbox::Import->new($git, 'test', $addr);
  47
  48 {
  49         local $ENV{HOME} = $home;
  50
  51         # inject some messages:
  52         my $mime = Email::MIME->new(<<EOF);
  53 From: Me <me\@example.com>
  54 To: You <you\@example.com>
  55 Cc: $addr
  56 Message-Id: <blah\@example.com>
  57 Subject: hihi
  58 Date: Thu, 01 Jan 1970 00:00:00 +0000
  59
  60 zzzzzz
  61 EOF
  62         $im->add($mime);
  63
  64         # deliver a reply, too
  65         my $reply = Email::MIME->new(<<EOF);
  66 From: You <you\@example.com>
  67 To: Me <me\@example.com>
  68 Cc: $addr
  69 In-Reply-To: <blah\@example.com>
  70 Message-Id: <blahblah\@example.com>
  71 Subject: Re: hihi
  72 Date: Thu, 01 Jan 1970 00:00:01 +0000
  73
  74 Me wrote:
  75 > zzzzzz
  76
  77 what?
  78 EOF
  79         $im->add($reply);
  80         $im->done;
  81 }
  82
  83 # message-id pages
  84 {
  85         local $ENV{HOME} = $home;
  86         my $slashy_mid = 'slashy/asdf@example.com';
  87         my $reply = Email::MIME->new(<<EOF);
  88 From: You <you\@example.com>
  89 To: Me <me\@example.com>
  90 Cc: $addr
  91 Message-Id: <$slashy_mid>
  92 Subject: Re: hihi
  93 Date: Thu, 01 Jan 1970 00:00:01 +0000
  94
  95 slashy
  96 EOF
  97         $im->add($reply);
  98         $im->done;
  99
 100         my $res = cgi_run("/test/slashy/asdf\@example.com/raw");
 101         like($res->{body}, qr/Message-Id: <\Q$slashy_mid\E>/,
 102                 "slashy mid raw hit");
 103
 104         $res = cgi_run("/test/blahblah\@example.com/raw");
 105         like($res->{body}, qr/Message-Id: <blahblah\@example\.com>/,
 106                 "mid raw hit");
 107
 108         $res = cgi_run("/test/blahblah\@example.com/");
 109         like($res->{body}, qr/\A<html>/, "mid html hit");
 110         like($res->{head}, qr/Status: 200 OK/, "200 response");
 111
 112         $res = cgi_run("/test/blahblah\@example.com/f/");
 113         like($res->{head}, qr/Status: 301 Moved/, "301 response");
 114         like($res->{head},
 115                 qr!^Location: http://[^/]+/test/blahblah\@example\.com/\r\n!ms,
 116                 '301 redirect location');
 117
 118         $res = cgi_run("/test/new.html");
 119         like($res->{body}, qr/slashy%2Fasdf\@example\.com/,
 120                 "slashy URL generated correctly");
 121 }
 122
 123 # retrieve thread as an mbox
 124 {
 125         local $ENV{HOME} = $home;
 126         my $path = "/test/blahblah\@example.com/t.mbox.gz";
 127         my $res = cgi_run($path);
 128         like($res->{head}, qr/^Status: 501 /, "search not-yet-enabled");
 129         my $indexed = system($index, $maindir) == 0;
 130         if ($indexed) {
 131                 $res = cgi_run($path);
 132                 like($res->{head}, qr/^Status: 200 /, "search returned mbox");
 133                 eval {
 134                         require IO::Uncompress::Gunzip;
 135                         my $in = $res->{body};
 136                         my $out;
 137                         IO::Uncompress::Gunzip::gunzip(\$in => \$out);
 138                         like($out, qr/^From /m, "From lines in mbox");
 139                 };
 140         } else {
 141                 like($res->{head}, qr/^Status: 501 /, "search not available");
 142         }
 143
 144         my $have_xml_feed = eval { require XML::Feed; 1 } if $indexed;
 145         if ($have_xml_feed) {
 146                 $path = "/test/blahblah\@example.com/t.atom";
 147                 $res = cgi_run($path);
 148                 like($res->{head}, qr/^Status: 200 /, "atom returned 200");
 149                 like($res->{head}, qr!^Content-Type: application/atom\+xml!m,
 150                         "search returned atom");
 151                 my $p = XML::Feed->parse(\($res->{body}));
 152                 is($p->format, "Atom", "parsed atom feed");
 153                 is(scalar $p->entries, 3, "parsed three entries");
 154         }
 155 }
 156
 157 done_testing();
 158
 159 sub run_with_env {
 160         my ($env, @args) = @_;
 161         IPC::Run::run(@args, init => sub { %ENV = (%ENV, %$env) });
 162 }
 163
 164 sub cgi_run {
 165         my %env = (
 166                 PATH_INFO => $_[0],
 167                 QUERY_STRING => $_[1] || "",
 168                 SCRIPT_NAME => '',
 169                 REQUEST_URI => $_[0] . ($_[1] ? "?$_[1]" : ''),
 170                 REQUEST_METHOD => $_[2] || "GET",
 171                 GATEWAY_INTERFACE => 'CGI/1.1',
 172                 HTTP_ACCEPT => '*/*',
 173                 HTTP_HOST => 'test.example.com',
 174         );
 175         my ($in, $out, $err) = ("", "", "");
 176         my $rc = run_with_env(\%env, [CGI], \$in, \$out, \$err);
 177         my ($head, $body) = split(/\r\n\r\n/, $out, 2);
 178         { head => $head, body => $body, rc => $rc, err => $err }
 179 }