t/check-www-inbox.perl

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Parallel WWW checker
   5 my $usage = "$0 [-j JOBS] [-s SLOW_THRESHOLD] URL_OF_INBOX\n";
   6 use strict;
   7 use warnings;
   8 use File::Temp qw(tempfile);
   9 use GDBM_File;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Socket;
  12 use LWP::ConnCache;
  13 use POSIX qw(:sys_wait_h);
  14 use Time::HiRes qw(gettimeofday tv_interval);
  15 use WWW::Mechanize;
  16 use Data::Dumper;
  17 my $nproc = 4;
  18 my $slow = 0.5;
  19 my %opts = (
  20         '-j|jobs=i' => \$nproc,
  21         '-s|slow-threshold=f' => \$slow,
  22 );
  23 GetOptions(%opts) or die "bad command-line args\n$usage";
  24 my $root_url = shift or die $usage;
  25
  26 chomp(my $xmlstarlet = `which xmlstarlet 2>/dev/null`);
  27 my $atom_check = eval {
  28         require IPC::Run;
  29         my $cmd = [ qw(xmlstarlet val -e -) ];
  30         sub {
  31                 my ($in, $out, $err) = @_;
  32                 IPC::Run::run($cmd, $in, $out, $err);
  33         }
  34 } if $xmlstarlet;
  35
  36 my %workers;
  37 $SIG{TERM} = sub { exit 0 };
  38 $SIG{CHLD} = sub {
  39         while (1) {
  40                 my $pid = waitpid(-1, WNOHANG);
  41                 return if !defined $pid || $pid <= 0;
  42                 my $p = delete $workers{$pid} || '(unknown)';
  43                 warn("$pid [$p] exited with $?\n") if $?;
  44         }
  45 };
  46
  47 my @todo = IO::Socket->socketpair(AF_UNIX, SOCK_SEQPACKET, 0);
  48 die "socketpair failed: $!" unless $todo[1];
  49 my @done = IO::Socket->socketpair(AF_UNIX, SOCK_SEQPACKET, 0);
  50 die "socketpair failed: $!" unless $done[1];
  51 $| = 1;
  52
  53 foreach my $p (1..$nproc) {
  54         my $pid = fork;
  55         die "fork failed: $!\n" unless defined $pid;
  56         if ($pid) {
  57                 $workers{$pid} = $p;
  58         } else {
  59                 $todo[1]->close;
  60                 $done[0]->close;
  61                 worker_loop($todo[0], $done[1]);
  62         }
  63 }
  64
  65 my ($fh, $tmp) = tempfile('www-check-XXXXXXXX',
  66                         SUFFIX => '.gdbm', UNLINK => 1, TMPDIR => 1);
  67 my $gdbm = tie my %seen, 'GDBM_File', $tmp, &GDBM_WRCREAT, 0600;
  68 defined $gdbm or die "gdbm open failed: $!\n";
  69 $todo[0]->close;
  70 $done[1]->close;
  71
  72 my ($rvec, $wvec);
  73 $todo[1]->blocking(0);
  74 $done[0]->blocking(0);
  75 $seen{$root_url} = 1;
  76 my $ndone = 0;
  77 my $nsent = 1;
  78 my @queue = ($root_url);
  79 my $timeout = $slow * 4;
  80 while (keys %workers) { # reacts to SIGCHLD
  81         $wvec = $rvec = '';
  82         my $u;
  83         vec($rvec, fileno($done[0]), 1) = 1;
  84         if (@queue) {
  85                 vec($wvec, fileno($todo[1]), 1) = 1;
  86         } elsif ($ndone == $nsent) {
  87                 kill 'TERM', keys %workers;
  88                 exit;
  89         }
  90         if (!select($rvec, $wvec, undef, $timeout)) {
  91                 while (my ($k, $v) = each %seen) {
  92                         next if $v == 2;
  93                         print "WAIT ($ndone/$nsent) <$k>\n";
  94                 }
  95         }
  96         while ($u = shift @queue) {
  97                 my $s = $todo[1]->send($u, MSG_EOR);
  98                 if ($!{EAGAIN}) {
  99                         unshift @queue, $u;
 100                         last;
 101                 }
 102         }
 103         my $r;
 104         do {
 105                 $r = $done[0]->recv($u, 65535, 0);
 106         } while (!defined $r && $!{EINTR});
 107         next unless $u;
 108         if ($u =~ s/\ADONE\t//) {
 109                 $ndone++;
 110                 $seen{$u} = 2;
 111         } else {
 112                 next if $seen{$u};
 113                 $seen{$u} = 1;
 114                 $nsent++;
 115                 push @queue, $u;
 116         }
 117 }
 118
 119 sub worker_loop {
 120         my ($todo_rd, $done_wr) = @_;
 121         my $m = WWW::Mechanize->new(autocheck => 0);
 122         my $cc = LWP::ConnCache->new;
 123         $m->conn_cache($cc);
 124         while (1) {
 125                 $todo_rd->recv(my $u, 65535, 0);
 126                 next unless $u;
 127
 128                 my $t = [ gettimeofday ];
 129                 my $r = $m->get($u);
 130                 $t = tv_interval($t);
 131                 printf "SLOW %0.06f % 5d %s\n", $t, $$, $u if $t > $slow;
 132                 my @links;
 133                 if ($r->is_success) {
 134                         my %links = map {
 135                                 (split('#', $_->URI->abs->as_string))[0] => 1;
 136                         } grep {
 137                                 $_->tag && $_->url !~ /:/
 138                         } $m->links;
 139                         @links = keys %links;
 140                 } elsif ($r->code != 300) {
 141                         warn "W: ".$r->code . " $u\n"
 142                 }
 143
 144                 my $s;
 145                 # blocking
 146                 foreach my $l (@links, "DONE\t$u") {
 147                         next if $l eq '';
 148                         do {
 149                                 $s = $done_wr->send($l, MSG_EOR);
 150                         } while (!defined $s && $!{EINTR});
 151                         die "$$ send $!\n" unless defined $s;
 152                         my $n = length($l);
 153                         die "$$ send truncated $s < $n\n" if $s != $n;
 154                 }
 155
 156                 # make sure the HTML source doesn't screw up terminals
 157                 # when people curl the source (not remotely an expert
 158                 # on languages or encodings, here).
 159                 my $ct = $r->header('Content-Type') || '';
 160                 warn "no Content-Type: $u\n" if $ct eq '';
 161
 162                 if ($atom_check && $ct =~ m!\bapplication/atom\+xml\b!) {
 163                         my $raw = $r->decoded_content;
 164                         my ($out, $err) = ('', '');
 165                         $atom_check->(\$raw, \$out, \$err) and
 166                                 warn "Atom ($?) - $u - <1:$out> <2:$err>\n";
 167                 }
 168
 169                 next if $ct !~ m!\btext/html\b!;
 170                 my $dc = $r->decoded_content;
 171                 if ($dc =~ /([\x00-\x08\x0d-\x1f\x7f-\x{99999999}]+)/s) {
 172                         my $o = $1;
 173                         my $c = Dumper($o);
 174                         warn "bad: $u $c\n";
 175                 }
 176         }
 177 }