t/common.perl

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
   5 use POSIX qw(dup2);
   6 use strict;
   7 use warnings;
   8
   9 sub stream_to_string {
  10         my ($res) = @_;
  11         my $body = $res->[2];
  12         my $str = '';
  13         while (defined(my $chunk = $body->getline)) {
  14                 $str .= $chunk;
  15         }
  16         $body->close;
  17         $str;
  18 }
  19
  20 sub tcp_server () {
  21         IO::Socket::INET->new(
  22                 LocalAddr => '127.0.0.1',
  23                 ReuseAddr => 1,
  24                 Proto => 'tcp',
  25                 Type => Socket::SOCK_STREAM(),
  26                 Listen => 1024,
  27         )
  28 }
  29
  30 sub unix_server ($) {
  31         IO::Socket::UNIX->new(
  32                 Listen => 1024,
  33                 Type => Socket::SOCK_STREAM(),
  34                 Local => $_[0],
  35         )
  36 }
  37
  38 sub spawn_listener {
  39         my ($env, $cmd, $socks) = @_;
  40         my $pid = fork;
  41         defined $pid or die "fork failed: $!\n";
  42         if ($pid == 0) {
  43                 # pretend to be systemd (cf. sd_listen_fds(3))
  44                 my $fd = 3; # 3 == SD_LISTEN_FDS_START
  45                 foreach my $s (@$socks) {
  46                         my $fl = fcntl($s, F_GETFD, 0);
  47                         if (($fl & FD_CLOEXEC) != FD_CLOEXEC) {
  48                                 warn "got FD:".fileno($s)." w/o CLOEXEC\n";
  49                         }
  50                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
  51                         dup2(fileno($s), $fd++) or die "dup2 failed: $!\n";
  52                 }
  53                 $ENV{LISTEN_PID} = $$;
  54                 $ENV{LISTEN_FDS} = scalar @$socks;
  55                 %ENV = (%ENV, %$env) if $env;
  56                 exec @$cmd;
  57                 die "FAIL: ",join(' ', @$cmd), ": $!\n";
  58         }
  59         $pid;
  60 }
  61
  62 sub require_git ($;$) {
  63         my ($req, $maybe) = @_;
  64         my ($req_maj, $req_min) = split(/\./, $req);
  65         my ($cur_maj, $cur_min) = (`git --version` =~ /version (\d+)\.(\d+)/);
  66
  67         my $req_int = ($req_maj << 24) | ($req_min << 16);
  68         my $cur_int = ($cur_maj << 24) | ($cur_min << 16);
  69         if ($cur_int < $req_int) {
  70                 return 0 if $maybe;
  71                 plan skip_all => "git $req+ required, have $cur_maj.$cur_min";
  72         }
  73         1;
  74 }
  75
  76 1;