t/common.perl

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
   5 use POSIX qw(dup2);
   6 use strict;
   7 use warnings;
   8
   9 sub stream_to_string {
  10         my ($res) = @_;
  11         my $body = $res->[2];
  12         my $str = '';
  13         while (defined(my $chunk = $body->getline)) {
  14                 $str .= $chunk;
  15         }
  16         $body->close;
  17         $str;
  18 }
  19
  20 sub spawn_listener {
  21         my ($env, $cmd, $socks) = @_;
  22         my $pid = fork;
  23         defined $pid or die "fork failed: $!\n";
  24         if ($pid == 0) {
  25                 # pretend to be systemd (cf. sd_listen_fds(3))
  26                 my $fd = 3; # 3 == SD_LISTEN_FDS_START
  27                 foreach my $s (@$socks) {
  28                         my $fl = fcntl($s, F_GETFD, 0);
  29                         if (($fl & FD_CLOEXEC) != FD_CLOEXEC) {
  30                                 warn "got FD:".fileno($s)." w/o CLOEXEC\n";
  31                         }
  32                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
  33                         dup2(fileno($s), $fd++) or die "dup2 failed: $!\n";
  34                 }
  35                 $ENV{LISTEN_PID} = $$;
  36                 $ENV{LISTEN_FDS} = scalar @$socks;
  37                 %ENV = (%ENV, %$env) if $env;
  38                 exec @$cmd;
  39                 die "FAIL: ",join(' ', @$cmd), ": $!\n";
  40         }
  41         $pid;
  42 }
  43
  44 sub require_git ($;$) {
  45         my ($req, $maybe) = @_;
  46         my ($req_maj, $req_min) = split(/\./, $req);
  47         my ($cur_maj, $cur_min) = (`git --version` =~ /version (\d+)\.(\d+)/);
  48
  49         my $req_int = ($req_maj << 24) | ($req_min << 16);
  50         my $cur_int = ($cur_maj << 24) | ($cur_min << 16);
  51         if ($cur_int < $req_int) {
  52                 return 0 if $maybe;
  53                 plan skip_all => "git $req+ required, have $cur_maj.$cur_min";
  54         }
  55         1;
  56 }
  57
  58 1;