t/common.perl

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
   5 use POSIX qw(dup2);
   6 use strict;
   7 use warnings;
   8 use IO::Socket::INET;
   9
  10 sub stream_to_string {
  11         my ($res) = @_;
  12         my $body = $res->[2];
  13         my $str = '';
  14         while (defined(my $chunk = $body->getline)) {
  15                 $str .= $chunk;
  16         }
  17         $body->close;
  18         $str;
  19 }
  20
  21 sub tcp_server () {
  22         IO::Socket::INET->new(
  23                 LocalAddr => '127.0.0.1',
  24                 ReuseAddr => 1,
  25                 Proto => 'tcp',
  26                 Type => Socket::SOCK_STREAM(),
  27                 Listen => 1024,
  28                 Blocking => 0,
  29         )
  30 }
  31
  32 sub unix_server ($) {
  33         my $s = IO::Socket::UNIX->new(
  34                 Listen => 1024,
  35                 Type => Socket::SOCK_STREAM(),
  36                 Local => $_[0],
  37         );
  38         $s->blocking(0);
  39         $s;
  40 }
  41
  42 sub tcp_connect {
  43         my ($dest, %opt) = @_;
  44         my $s = IO::Socket::INET->new(
  45                 Proto => 'tcp',
  46                 Type => Socket::SOCK_STREAM(),
  47                 PeerAddr => $dest->sockhost . ':' . $dest->sockport,
  48                 %opt,
  49         );
  50         $s->autoflush(1);
  51         $s;
  52 }
  53
  54 sub spawn_listener {
  55         my ($env, $cmd, $socks) = @_;
  56         my $pid = fork;
  57         defined $pid or die "fork failed: $!\n";
  58         if ($pid == 0) {
  59                 # pretend to be systemd (cf. sd_listen_fds(3))
  60                 my $fd = 3; # 3 == SD_LISTEN_FDS_START
  61                 foreach my $s (@$socks) {
  62                         my $fl = fcntl($s, F_GETFD, 0);
  63                         if (($fl & FD_CLOEXEC) != FD_CLOEXEC) {
  64                                 warn "got FD:".fileno($s)." w/o CLOEXEC\n";
  65                         }
  66                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
  67                         dup2(fileno($s), $fd++) or die "dup2 failed: $!\n";
  68                 }
  69                 $ENV{LISTEN_PID} = $$;
  70                 $ENV{LISTEN_FDS} = scalar @$socks;
  71                 %ENV = (%ENV, %$env) if $env;
  72                 exec @$cmd;
  73                 die "FAIL: ",join(' ', @$cmd), ": $!\n";
  74         }
  75         $pid;
  76 }
  77
  78 sub require_git ($;$) {
  79         my ($req, $maybe) = @_;
  80         my ($req_maj, $req_min) = split(/\./, $req);
  81         my ($cur_maj, $cur_min) = (`git --version` =~ /version (\d+)\.(\d+)/);
  82
  83         my $req_int = ($req_maj << 24) | ($req_min << 16);
  84         my $cur_int = ($cur_maj << 24) | ($cur_min << 16);
  85         if ($cur_int < $req_int) {
  86                 return 0 if $maybe;
  87                 plan skip_all => "git $req+ required, have $cur_maj.$cur_min";
  88         }
  89         1;
  90 }
  91
  92 1;