t/edit.t

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # edit frontend behavior test (t/replace.t for backend)
   4 use strict;
   5 use warnings;
   6 use Test::More;
   7 use File::Temp qw/tempdir/;
   8 require './t/common.perl';
   9 require_git(2.6);
  10 require PublicInbox::Inbox;
  11 require PublicInbox::InboxWritable;
  12 require PublicInbox::Config;
  13 use PublicInbox::MID qw(mid_clean);
  14
  15 my @mods = qw(IPC::Run DBI DBD::SQLite);
  16 foreach my $mod (@mods) {
  17         eval "require $mod";
  18         plan skip_all => "missing $mod for $0" if $@;
  19 };
  20 IPC::Run->import(qw(run));
  21
  22 my $cmd_pfx = 'blib/script/public-inbox';
  23 my $tmpdir = tempdir('pi-edit-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  24 my $inboxdir = "$tmpdir/v2";
  25 my $ibx = PublicInbox::Inbox->new({
  26         inboxdir => $inboxdir,
  27         name => 'test-v2edit',
  28         version => 2,
  29         -primary_address => 'test@example.com',
  30         indexlevel => 'basic',
  31 });
  32 $ibx = PublicInbox::InboxWritable->new($ibx, {nproc=>1});
  33 my $cfgfile = "$tmpdir/config";
  34 local $ENV{PI_CONFIG} = $cfgfile;
  35 my $file = 't/data/0001.patch';
  36 open my $fh, '<', $file or die "open: $!";
  37 my $raw = do { local $/; <$fh> };
  38 my $im = $ibx->importer(0);
  39 my $mime = PublicInbox::MIME->new($raw);
  40 my $mid = mid_clean($mime->header('Message-Id'));
  41 ok($im->add($mime), 'add message to be edited');
  42 $im->done;
  43 my ($in, $out, $err, $cmd, $cur, $t);
  44 my $git = PublicInbox::Git->new("$ibx->{inboxdir}/git/0.git");
  45
  46 $t = '-F FILE'; {
  47         $in = $out = $err = '';
  48         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 's/boolean prefix/bool pfx/'";
  49         $cmd = [ "$cmd_pfx-edit", "-F$file", $inboxdir ];
  50         ok(run($cmd, \$in, \$out, \$err), "$t edit OK");
  51         $cur = PublicInbox::MIME->new($ibx->msg_by_mid($mid));
  52         like($cur->header('Subject'), qr/bool pfx/, "$t message edited");
  53         like($out, qr/[a-f0-9]{40}/, "$t shows commit on success");
  54 }
  55
  56 $t = '-m MESSAGE_ID'; {
  57         $in = $out = $err = '';
  58         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 's/bool pfx/boolean prefix/'";
  59         $cmd = [ "$cmd_pfx-edit", "-m$mid", $inboxdir ];
  60         ok(run($cmd, \$in, \$out, \$err), "$t edit OK");
  61         $cur = PublicInbox::MIME->new($ibx->msg_by_mid($mid));
  62         like($cur->header('Subject'), qr/boolean prefix/, "$t message edited");
  63         like($out, qr/[a-f0-9]{40}/, "$t shows commit on success");
  64 }
  65
  66 $t = 'no-op -m MESSAGE_ID'; {
  67         $in = $out = $err = '';
  68         my $before = $git->qx(qw(rev-parse HEAD));
  69         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 's/bool pfx/boolean prefix/'";
  70         $cmd = [ "$cmd_pfx-edit", "-m$mid", $inboxdir ];
  71         ok(run($cmd, \$in, \$out, \$err), "$t succeeds");
  72         my $prev = $cur;
  73         $cur = PublicInbox::MIME->new($ibx->msg_by_mid($mid));
  74         is_deeply($cur, $prev, "$t makes no change");
  75         like($cur->header('Subject'), qr/boolean prefix/,
  76                 "$t does not change message");
  77         like($out, qr/NONE/, 'noop shows NONE');
  78         my $after = $git->qx(qw(rev-parse HEAD));
  79         is($after, $before, 'git head unchanged');
  80 }
  81
  82 $t = 'no-op -m MESSAGE_ID w/Status: header'; { # because mutt does it
  83         $in = $out = $err = '';
  84         my $before = $git->qx(qw(rev-parse HEAD));
  85         local $ENV{MAIL_EDITOR} =
  86                         "$^X -i -p -e 's/^Subject:.*/Status: RO\\n\$&/'";
  87         $cmd = [ "$cmd_pfx-edit", "-m$mid", $inboxdir ];
  88         ok(run($cmd, \$in, \$out, \$err), "$t succeeds");
  89         my $prev = $cur;
  90         $cur = PublicInbox::MIME->new($ibx->msg_by_mid($mid));
  91         is_deeply($cur, $prev, "$t makes no change");
  92         like($cur->header('Subject'), qr/boolean prefix/,
  93                 "$t does not change message");
  94         is($cur->header('Status'), undef, 'Status header not added');
  95         like($out, qr/NONE/, 'noop shows NONE');
  96         my $after = $git->qx(qw(rev-parse HEAD));
  97         is($after, $before, 'git head unchanged');
  98 }
  99
 100 $t = '-m MESSAGE_ID can change Received: headers'; {
 101         $in = $out = $err = '';
 102         local $ENV{MAIL_EDITOR} =
 103                         "$^X -i -p -e 's/^Subject:.*/Received: x\\n\$&/'";
 104         $cmd = [ "$cmd_pfx-edit", "-m$mid", $inboxdir ];
 105         ok(run($cmd, \$in, \$out, \$err), "$t succeeds");
 106         $cur = PublicInbox::MIME->new($ibx->msg_by_mid($mid));
 107         like($cur->header('Subject'), qr/boolean prefix/,
 108                 "$t does not change Subject");
 109         is($cur->header('Received'), 'x', 'added Received header');
 110 }
 111
 112 $t = '-m miss'; {
 113         $in = $out = $err = '';
 114         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 's/boolean/FAIL/'";
 115         $cmd = [ "$cmd_pfx-edit", "-m$mid-miss", $inboxdir ];
 116         ok(!run($cmd, \$in, \$out, \$err), "$t fails on invalid MID");
 117         like($err, qr/No message found/, "$t shows error");
 118 }
 119
 120 $t = 'non-interactive editor failure'; {
 121         $in = $out = $err = '';
 122         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 'END { exit 1 }'";
 123         $cmd = [ "$cmd_pfx-edit", "-m$mid", $inboxdir ];
 124         ok(!run($cmd, \$in, \$out, \$err), "$t detected");
 125         like($err, qr/END \{ exit 1 \}' failed:/, "$t shows error");
 126 }
 127
 128 $t = 'mailEditor set in config'; {
 129         $in = $out = $err = '';
 130         my $rc = system(qw(git config), "--file=$cfgfile",
 131                         'publicinbox.maileditor',
 132                         "$^X -i -p -e 's/boolean prefix/bool pfx/'");
 133         is($rc, 0, 'set publicinbox.mailEditor');
 134         local $ENV{MAIL_EDITOR};
 135         local $ENV{GIT_EDITOR} = 'echo should not run';
 136         $cmd = [ "$cmd_pfx-edit", "-m$mid", $inboxdir ];
 137         ok(run($cmd, \$in, \$out, \$err), "$t edited message");
 138         $cur = PublicInbox::MIME->new($ibx->msg_by_mid($mid));
 139         like($cur->header('Subject'), qr/bool pfx/, "$t message edited");
 140         unlike($out, qr/should not run/, 'did not run GIT_EDITOR');
 141 }
 142
 143 $t = '--raw and mbox escaping'; {
 144         $in = $out = $err = '';
 145         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 's/^\$/\\nFrom not mbox\\n/'";
 146         $cmd = [ "$cmd_pfx-edit", "-m$mid", '--raw', $inboxdir ];
 147         ok(run($cmd, \$in, \$out, \$err), "$t succeeds");
 148         $cur = PublicInbox::MIME->new($ibx->msg_by_mid($mid));
 149         like($cur->body, qr/^From not mbox/sm, 'put "From " line into body');
 150
 151         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 's/^>From not/\$& an/'";
 152         $cmd = [ "$cmd_pfx-edit", "-m$mid", $inboxdir ];
 153         ok(run($cmd, \$in, \$out, \$err), "$t succeeds with mbox escaping");
 154         $cur = PublicInbox::MIME->new($ibx->msg_by_mid($mid));
 155         like($cur->body, qr/^From not an mbox/sm,
 156                 'changed "From " line unescaped');
 157
 158         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 's/^From not an mbox\\n//s'";
 159         $cmd = [ "$cmd_pfx-edit", "-m$mid", '--raw', $inboxdir ];
 160         ok(run($cmd, \$in, \$out, \$err), "$t succeeds again");
 161         $cur = PublicInbox::MIME->new($ibx->msg_by_mid($mid));
 162         unlike($cur->body, qr/^From not an mbox/sm, "$t restored body");
 163 }
 164
 165 $t = 'reuse Message-ID'; {
 166         my @warn;
 167         local $SIG{__WARN__} = sub { push @warn, @_ };
 168         ok($im->add($mime), "$t and re-add");
 169         $im->done;
 170         like($warn[0], qr/reused for mismatched content/, "$t got warning");
 171 }
 172
 173 $t = 'edit ambiguous Message-ID with -m'; {
 174         $in = $out = $err = '';
 175         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 's/bool pfx/boolean prefix/'";
 176         $cmd = [ "$cmd_pfx-edit", "-m$mid", $inboxdir ];
 177         ok(!run($cmd, \$in, \$out, \$err), "$t fails w/o --force");
 178         like($err, qr/Multiple messages with different content found matching/,
 179                 "$t shows matches");
 180         like($err, qr/GIT_DIR=.*git show/is, "$t shows git commands");
 181 }
 182
 183 $t .= ' and --force'; {
 184         $in = $out = $err = '';
 185         local $ENV{MAIL_EDITOR} = "$^X -i -p -e 's/^Subject:.*/Subject:x/i'";
 186         $cmd = [ "$cmd_pfx-edit", "-m$mid", '--force', $inboxdir ];
 187         ok(run($cmd, \$in, \$out, \$err), "$t succeeds");
 188         like($err, qr/Will edit all of them/, "$t notes all will be edited");
 189         my @dump = $git->qx(qw(cat-file --batch --batch-all-objects));
 190         chomp @dump;
 191         is_deeply([grep(/^Subject:/i, @dump)], [qw(Subject:x Subject:x)],
 192                 "$t edited both messages");
 193 }
 194
 195 done_testing();