t/extsearch.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use Test::More;
   6 use PublicInbox::TestCommon;
   7 use PublicInbox::Config;
   8 use Fcntl qw(:seek);
   9 my $json = PublicInbox::Config::json() or plan skip_all => 'JSON missing';
  10 require_git(2.6);
  11 require_mods(qw(DBD::SQLite Search::Xapian));
  12 use_ok 'PublicInbox::ExtSearch';
  13 use_ok 'PublicInbox::ExtSearchIdx';
  14 my $sock = tcp_server();
  15 my $host_port = $sock->sockhost . ':' . $sock->sockport;
  16 my ($home, $for_destroy) = tmpdir();
  17 local $ENV{HOME} = $home;
  18 mkdir "$home/.public-inbox" or BAIL_OUT $!;
  19 open my $fh, '>', "$home/.public-inbox/config" or BAIL_OUT $!;
  20 print $fh <<EOF or BAIL_OUT $!;
  21 [publicinboxMda]
  22         spamcheck = none
  23 EOF
  24 close $fh or BAIL_OUT $!;
  25 my $v2addr = 'v2test@example.com';
  26 my $v1addr = 'v1test@example.com';
  27 ok(run_script([qw(-init -V2 v2test --newsgroup v2.example), "$home/v2test",
  28         'http://example.com/v2test', $v2addr ]), 'v2test init');
  29 my $env = { ORIGINAL_RECIPIENT => $v2addr };
  30 my $eml = eml_load('t/utf8.eml');
  31
  32 $eml->header_set('List-Id', '<v2.example.com>');
  33 open($fh, '+>', undef) or BAIL_OUT $!;
  34 $fh->autoflush(1);
  35 print $fh $eml->as_string or BAIL_OUT $!;
  36 seek($fh, 0, SEEK_SET) or BAIL_OUT $!;
  37
  38 run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or BAIL_OUT '-mda';
  39
  40 ok(run_script([qw(-init -V1 v1test --newsgroup v1.example), "$home/v1test",
  41         'http://example.com/v1test', $v1addr ]), 'v1test init');
  42
  43 $eml->header_set('List-Id', '<v1.example.com>');
  44 seek($fh, 0, SEEK_SET) or BAIL_OUT $!;
  45 truncate($fh, 0) or BAIL_OUT $!;
  46 print $fh $eml->as_string or BAIL_OUT $!;
  47 seek($fh, 0, SEEK_SET) or BAIL_OUT $!;
  48
  49 $env = { ORIGINAL_RECIPIENT => $v1addr };
  50 run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or BAIL_OUT '-mda';
  51
  52 run_script(['-index', "$home/v1test"]) or BAIL_OUT "index $?";
  53
  54 ok(run_script([qw(-extindex --all), "$home/extindex"]), 'extindex init');
  55
  56
  57 { # TODO: -extindex should write this to config
  58         open $fh, '>>', "$home/.public-inbox/config" or BAIL_OUT $!;
  59         print $fh <<EOF or BAIL_OUT $!;
  60 ; for ->ALL
  61 [extindex "all"]
  62         topdir = $home/extindex
  63 EOF
  64         close $fh or BAIL_OUT $!;
  65
  66         my $pi_cfg = PublicInbox::Config->new;
  67         $pi_cfg->fill_all;
  68         ok($pi_cfg->ALL, '->ALL');
  69         my $ibx = $pi_cfg->{-by_newsgroup}->{'v2.example'};
  70         my $ret = $pi_cfg->ALL->nntp_xref_for($ibx, $ibx->over->get_art(1));
  71         is_deeply($ret, ['v1.example:1'], '->nntp_xref_for');
  72 }
  73
  74 SKIP: {
  75         require_mods(qw(Net::NNTP), 1);
  76         my ($out, $err) = ("$home/nntpd.out.log", "$home/nntpd.err.log");
  77         my $cmd = [ '-nntpd', '-W0', "--stdout=$out", "--stderr=$err" ];
  78         my $td = start_script($cmd, undef, { 3 => $sock });
  79         my $n = Net::NNTP->new($host_port);
  80         my @xp = $n->xpath('<testmessage@example.com>');
  81         is_deeply(\@xp, [ qw(v1.example/1 v2.example/1) ]);
  82         $n->group('v1.example');
  83         my $res = $n->head(1);
  84         @$res = grep(/^Xref: /, @$res);
  85         like($res->[0], qr/ v1\.example:1 v2\.example:1/, 'nntp_xref works');
  86 }
  87
  88 my $es = PublicInbox::ExtSearch->new("$home/extindex");
  89 {
  90         my $smsg = $es->over->get_art(1);
  91         ok($smsg, 'got first article');
  92         is($es->over->get_art(2), undef, 'only one added');
  93         my $xref3 = $es->over->get_xref3(1);
  94         like($xref3->[0], qr/\A\Qv2.example\E:1:/, 'order preserved 1');
  95         like($xref3->[1], qr/\A\Qv1.example\E:1:/, 'order preserved 2');
  96         is(scalar(@$xref3), 2, 'only to entries');
  97 }
  98
  99 {
 100         my ($in, $out, $err);
 101         $in = $out = $err = '';
 102         my $opt = { 0 => \$in, 1 => \$out, 2 => \$err };
 103         my $env = { MAIL_EDITOR => "$^X -i -p -e 's/test message/BEST MSG/'" };
 104         my $cmd = [ qw(-edit -Ft/utf8.eml), "$home/v2test" ];
 105         ok(run_script($cmd, $env, $opt), '-edit');
 106         ok(run_script([qw(-extindex --all), "$home/extindex"], undef, $opt),
 107                 'extindex again');
 108         like($err, qr/discontiguous range/, 'warned about discontiguous range');
 109         my $msg1 = $es->over->get_art(1) or BAIL_OUT 'msg1 missing';
 110         my $msg2 = $es->over->get_art(2) or BAIL_OUT 'msg2 missing';
 111         is($msg1->{mid}, $msg2->{mid}, 'edited message indexed');
 112         isnt($msg1->{blob}, $msg2->{blob}, 'blobs differ');
 113         my $eml2 = $es->smsg_eml($msg2);
 114         like($eml2->body, qr/BEST MSG/, 'edited body in #2');
 115         unlike($eml2->body, qr/test message/, 'old body discarded in #2');
 116         my $eml1 = $es->smsg_eml($msg1);
 117         like($eml1->body, qr/test message/, 'original body in #1');
 118         my $x1 = $es->over->get_xref3(1);
 119         my $x2 = $es->over->get_xref3(2);
 120         is(scalar(@$x1), 1, 'original only has one xref3');
 121         is(scalar(@$x2), 1, 'new message has one xref3');
 122         isnt($x1->[0], $x2->[0], 'xref3 differs');
 123
 124         my $mset = $es->mset('b:"BEST MSG"');
 125         is($mset->size, 1, 'new message found');
 126         $mset = $es->mset('b:"test message"');
 127         is($mset->size, 1, 'old message found');
 128
 129         delete @$es{qw(git over xdb)}; # fork preparation
 130
 131         open my $rmfh, '+>', undef or BAIL_OUT $!;
 132         $rmfh->autoflush(1);
 133         print $rmfh $eml2->as_string or BAIL_OUT $!;
 134         seek($rmfh, 0, SEEK_SET) or BAIL_OUT $!;
 135         $opt->{0} = $rmfh;
 136         ok(run_script([qw(-learn rm --all)], undef, $opt), '-learn rm');
 137
 138         ok(run_script([qw(-extindex --all), "$home/extindex"], undef, undef),
 139                 'extindex after rm');
 140         is($es->over->get_art(2), undef, 'doc #2 gone');
 141         $mset = $es->mset('b:"BEST MSG"');
 142         is($mset->size, 0, 'new message gone');
 143 }
 144
 145 my $misc = $es->misc;
 146 my @it = $misc->mset('')->items;
 147 is(scalar(@it), 2, 'two inboxes');
 148 like($it[0]->get_document->get_data, qr/v2test/, 'docdata matched v2');
 149 like($it[1]->get_document->get_data, qr/v1test/, 'docdata matched v1');
 150
 151 done_testing;