t/feed.t

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use Email::MIME;
   7 use PublicInbox::Feed;
   8 use PublicInbox::Git;
   9 use PublicInbox::Import;
  10 use PublicInbox::Config;
  11 use PublicInbox::Inbox;
  12 use File::Temp qw/tempdir/;
  13 my $have_xml_feed = eval { require XML::Feed; 1 };
  14 require 't/common.perl';
  15
  16 sub string_feed {
  17         stream_to_string(PublicInbox::Feed::generate($_[0]));
  18 }
  19
  20 # ensure we are compatible with existing ssoma installations which
  21 # do not use fast-import.  We can probably remove this in 2018
  22 my %SSOMA;
  23 sub rand_use ($) {
  24         return 0 if $ENV{FAST};
  25         eval { require IPC::Run };
  26         return 0 if $@;
  27         my $cmd = $_[0];
  28         my $x = $SSOMA{$cmd};
  29         unless ($x) {
  30                 $x = -1;
  31                 foreach my $p (split(':', $ENV{PATH})) {
  32                         -x "$p/$cmd" or next;
  33                         $x = 1;
  34                         last;
  35                 }
  36                 $SSOMA{$cmd} = $x;
  37         }
  38         return if $x < 0;
  39         ($x > 0 && (int(rand(10)) % 2) == 1);
  40 }
  41
  42 my $tmpdir = tempdir('pi-feed-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  43 my $git_dir = "$tmpdir/gittest";
  44 my $ibx = PublicInbox::Inbox->new({
  45         address => 'test@example',
  46         name => 'testbox',
  47         mainrepo => $git_dir,
  48         url => 'http://example.com/test',
  49 });
  50 my $git = $ibx->git;
  51 my $im = PublicInbox::Import->new($git, $ibx->{name}, 'test@example');
  52
  53 {
  54         is(0, system(qw(git init -q --bare), $git_dir), "git init");
  55         local $ENV{GIT_DIR} = $git_dir;
  56
  57         foreach my $i (1..6) {
  58                 my $mime = Email::MIME->new(<<EOF);
  59 From: ME <me\@example.com>
  60 To: U <u\@example.com>
  61 Message-Id: <$i\@example.com>
  62 Subject: zzz #$i
  63 Date: Thu, 01 Jan 1970 00:00:00 +0000
  64
  65 > This is a long multi line quote so it should not be allowed to
  66 > show up in its entirty in the Atom feed.  drop me
  67 > I quote to much
  68 > I quote to much
  69 > I quote to much
  70 > I quote to much
  71 > I quote to much
  72 > I quote to much
  73 > I quote to much
  74 > I quote to much
  75 > I quote to much
  76 > I quote to much
  77 > I quote to much
  78 > I quote to much
  79 > I quote to much
  80
  81 msg $i
  82
  83 > inline me here
  84 > this is a short quote
  85
  86 keep me
  87 EOF
  88                 if (rand_use('ssoma-mda')) {
  89                         $im->done;
  90                         my $str = $mime->as_string;
  91                         IPC::Run::run(['ssoma-mda', $git_dir], \$str) or
  92                                 die "mda failed: $?\n";
  93                 } else {
  94                         like($im->add($mime), qr/\A:\d+/, 'added');
  95                 }
  96         }
  97         $im->done;
  98 }
  99
 100 # spam check
 101 {
 102         # check initial feed
 103         {
 104                 my $feed = string_feed({
 105                         -inbox => $ibx,
 106                         max => 3
 107                 });
 108                 SKIP: {
 109                         skip 'XML::Feed missing', 2 unless $have_xml_feed;
 110                         my $p = XML::Feed->parse(\$feed);
 111                         is($p->format, "Atom", "parsed atom feed");
 112                         is(scalar $p->entries, 3, "parsed three entries");
 113                         is($p->id, 'mailto:test@example',
 114                                 "id is set to default");
 115                 }
 116
 117                 like($feed, qr/drop me/, "long quoted text kept");
 118                 like($feed, qr/inline me here/, "short quoted text kept");
 119                 like($feed, qr/keep me/, "unquoted text saved");
 120         }
 121
 122         # add a new spam message
 123         my $spam;
 124         {
 125                 $spam = Email::MIME->new(<<EOF);
 126 From: SPAMMER <spammer\@example.com>
 127 To: U <u\@example.com>
 128 Message-Id: <this-is-spam\@example.com>
 129 Subject: SPAM!!!!!!!!
 130 Date: Thu, 01 Jan 1970 00:00:00 +0000
 131
 132 EOF
 133                 if (rand_use('ssoma-mda')) {
 134                         my $str = $spam->as_string;
 135                         IPC::Run::run(['ssoma-mda', $git_dir], \$str) or
 136                                 die "mda failed: $?\n";
 137                 } else {
 138                         $im->add($spam);
 139                         $im->done;
 140                 }
 141         }
 142
 143         # check spam shows up
 144         {
 145                 my $spammy_feed = string_feed({
 146                         -inbox => $ibx,
 147                         max => 3
 148                 });
 149                 SKIP: {
 150                         skip 'XML::Feed missing', 2 unless $have_xml_feed;
 151                         my $p = XML::Feed->parse(\$spammy_feed);
 152                         is($p->format, "Atom", "parsed atom feed");
 153                         is(scalar $p->entries, 3, "parsed three entries");
 154                 }
 155                 like($spammy_feed, qr/SPAM/s, "spam showed up :<");
 156         }
 157
 158         # nuke spam
 159         if (rand_use('ssoma-rm')) {
 160                 my $spam_str = $spam->as_string;
 161                 IPC::Run::run(["ssoma-rm", $git_dir], \$spam_str) or
 162                                 die "ssoma-rm failed: $?\n";
 163         } else {
 164                 $im->remove($spam);
 165                 $im->done;
 166         }
 167
 168         # spam no longer shows up
 169         {
 170                 my $feed = string_feed({ -inbox => $ibx, max => 3 });
 171                 SKIP: {
 172                         skip 'XML::Feed missing', 2 unless $have_xml_feed;
 173                         my $p = XML::Feed->parse(\$feed);
 174                         is($p->format, "Atom", "parsed atom feed");
 175                         is(scalar $p->entries, 3, "parsed three entries");
 176                 }
 177                 unlike($feed, qr/SPAM/, "spam gone :>");
 178         }
 179 }
 180
 181 done_testing();