t/git-http-backend.t

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use File::Temp qw/tempdir/;
   7 use IO::Socket;
   8 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
   9 use Socket qw(SO_KEEPALIVE IPPROTO_TCP TCP_NODELAY);
  10 use POSIX qw(dup2 setsid);
  11 use Cwd qw(getcwd);
  12
  13 my $git_dir = $ENV{GIANT_GIT_DIR};
  14 plan 'skip_all' => 'GIANT_GIT_DIR not defined' unless $git_dir;
  15 foreach my $mod (qw(Danga::Socket BSD::Resource
  16                         Plack::Util Plack::Builder
  17                         HTTP::Date HTTP::Status Net::HTTP)) {
  18         eval "require $mod";
  19         plan skip_all => "$mod missing for git-http-backend.t" if $@;
  20 }
  21 my $psgi = getcwd()."/t/git-http-backend.psgi";
  22 my $tmpdir = tempdir('pi-git-http-backend-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  23 my $err = "$tmpdir/stderr.log";
  24 my $out = "$tmpdir/stdout.log";
  25 my $httpd = 'blib/script/public-inbox-httpd';
  26 my %opts = (
  27         LocalAddr => '127.0.0.1',
  28         ReuseAddr => 1,
  29         Proto => 'tcp',
  30         Type => SOCK_STREAM,
  31         Listen => 1024,
  32 );
  33 my $sock = IO::Socket::INET->new(%opts);
  34 my $host = $sock->sockhost;
  35 my $port = $sock->sockport;
  36 my $pid;
  37 END { kill 'TERM', $pid if defined $pid };
  38
  39 my $get_maxrss = sub {
  40         my $http = Net::HTTP->new(Host => "$host:$port");
  41         ok($http, 'Net::HTTP object created for maxrss');
  42         $http->write_request(GET => '/');
  43         my ($code, $mess, %h) = $http->read_response_headers;
  44         is($code, 200, 'success reading maxrss');
  45         my $n = $http->read_entity_body(my $buf, 256);
  46         ok(defined $n, 'read response body');
  47         like($buf, qr/\A\d+\n\z/, 'got memory response');
  48         ok(int($buf) > 0, 'got non-zero memory response');
  49         int($buf);
  50 };
  51
  52 {
  53         ok($sock, 'sock created');
  54         $pid = fork;
  55         if ($pid == 0) { # pretend to be systemd
  56                 fcntl($sock, F_SETFD, 0);
  57                 dup2(fileno($sock), 3) or die "dup2 failed: $!\n";
  58                 $ENV{LISTEN_PID} = $$;
  59                 $ENV{LISTEN_FDS} = 1;
  60                 exec $httpd, "--stdout=$out", "--stderr=$err", $psgi;
  61                 die "FAIL: $!\n";
  62         }
  63         ok(defined $pid, 'forked httpd process successfully');
  64 }
  65 my $mem_a = $get_maxrss->();
  66
  67 SKIP: {
  68         my $max = 0;
  69         my $pack;
  70         my $glob = "$git_dir/objects/pack/pack-*.pack";
  71         foreach my $f (glob($glob)) {
  72                 my $n = -s $f;
  73                 if ($n > $max) {
  74                         $max = $n;
  75                         $pack = $f;
  76                 }
  77         }
  78         skip "no packs found in $git_dir" unless defined $pack;
  79         if ($pack !~ m!(/objects/pack/pack-[a-f0-9]{40}.pack)\z!) {
  80                 skip "bad pack name: $pack";
  81         }
  82         my $url = $1;
  83         my $http = Net::HTTP->new(Host => "$host:$port");
  84         ok($http, 'Net::HTTP object created');
  85         $http->write_request(GET => $url);
  86         my ($code, $mess, %h) = $http->read_response_headers;
  87         is(200, $code, 'got 200 success for pack');
  88         is($max, $h{'Content-Length'}, 'got expected Content-Length for pack');
  89         foreach my $i (1..3) {
  90                 sleep 1;
  91                 my $diff = $get_maxrss->() - $mem_a;
  92                 note "${diff}K memory increase after $i seconds";
  93                 ok($diff < 1024, 'no bloating caused by slow dumb client');
  94         }
  95 }
  96
  97 {
  98         my $c = fork;
  99         if ($c == 0) {
 100                 setsid();
 101                 exec qw(git clone -q --mirror), "http://$host:$port/",
 102                         "$tmpdir/mirror.git";
 103                 die "Failed start git clone: $!\n";
 104         }
 105         select(undef, undef, undef, 0.1);
 106         foreach my $i (1..10) {
 107                 is(1, kill('STOP', -$c), 'signaled clone STOP');
 108                 sleep 1;
 109                 ok(kill('CONT', -$c), 'continued clone');
 110                 my $diff = $get_maxrss->() - $mem_a;
 111                 note "${diff}K memory increase after $i seconds";
 112                 ok($diff < 2048, 'no bloating caused by slow smart client');
 113         }
 114         ok(kill('CONT', -$c), 'continued clone');
 115         is($c, waitpid($c, 0), 'reaped wayward slow clone');
 116         is($?, 0, 'clone did not error out');
 117         note 'clone done, fsck-ing clone result...';
 118         is(0, system("git", "--git-dir=$tmpdir/mirror.git",
 119                         qw(fsck --no-progress)),
 120                 'fsck did not report corruption');
 121
 122         my $diff = $get_maxrss->() - $mem_a;
 123         note "${diff}K memory increase after smart clone";
 124         ok($diff < 2048, 'no bloating caused by slow smart client');
 125 }
 126
 127 {
 128         ok(kill('TERM', $pid), 'killed httpd');
 129         $pid = undef;
 130         waitpid(-1, 0);
 131 }
 132
 133 done_testing();