t/httpd-corner.psgi

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # corner case tests for the generic PSGI server
   4 # Usage: plackup [OPTIONS] /path/to/this/file
   5 use strict;
   6 use warnings;
   7 use Plack::Builder;
   8 require Digest::SHA;
   9 my $app = sub {
  10         my ($env) = @_;
  11         my $path = $env->{PATH_INFO};
  12         my $in = $env->{'psgi.input'};
  13         my $actual = -s $in;
  14         my $code = 500;
  15         my $h = [ 'Content-Type' => 'text/plain' ];
  16         my $body = [];
  17         if ($path eq '/sha1') {
  18                 my $sha1 = Digest::SHA->new('SHA-1');
  19                 my $buf;
  20                 while (1) {
  21                         my $r = $in->read($buf, 4096);
  22                         die "read err: $!" unless defined $r;
  23                         last if $r == 0;
  24                         $sha1->add($buf);
  25                 }
  26                 $code = 200;
  27                 push @$body, $sha1->hexdigest;
  28         } elsif (my $fifo = $env->{HTTP_X_CHECK_FIFO}) {
  29                 if ($path eq '/slow-header') {
  30                         return sub {
  31                                 open my $f, '<', $fifo or
  32                                                 die "open $fifo: $!\n";
  33                                 my @r = <$f>;
  34                                 $_[0]->([200, $h, \@r ]);
  35                         };
  36                 } elsif ($path eq '/slow-body') {
  37                         return sub {
  38                                 my $fh = $_[0]->([200, $h]);
  39                                 open my $f, '<', $fifo or
  40                                                 die "open $fifo: $!\n";
  41                                 while (defined(my $l = <$f>)) {
  42                                         $fh->write($l);
  43                                 }
  44                                 $fh->close;
  45                         };
  46                 }
  47         }
  48
  49         [ $code, $h, $body ]
  50 };
  51
  52 builder {
  53         enable 'ContentLength';
  54         enable 'Head';
  55         $app;
  56 }