t/httpd.t

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::TestCommon;
   7 use Socket qw(IPPROTO_TCP SOL_SOCKET);
   8 require_mods(qw(Plack::Util Plack::Builder HTTP::Date HTTP::Status));
   9
  10 # FIXME: too much setup
  11 my ($tmpdir, $for_destroy) = tmpdir();
  12 my $home = "$tmpdir/pi-home";
  13 my $err = "$tmpdir/stderr.log";
  14 my $out = "$tmpdir/stdout.log";
  15 my $maindir = "$tmpdir/main.git";
  16 my $group = 'test-httpd';
  17 my $addr = $group . '@example.com';
  18 my $cfgpfx = "publicinbox.$group";
  19 my $sock = tcp_server();
  20 my $td;
  21 use_ok 'PublicInbox::Git';
  22 use_ok 'PublicInbox::Import';
  23 use_ok 'Email::MIME';
  24 {
  25         local $ENV{HOME} = $home;
  26         my $cmd = [ '-init', $group, $maindir, 'http://example.com/', $addr ];
  27         ok(run_script($cmd), 'init ran properly');
  28
  29         # ensure successful message delivery
  30         {
  31                 my $mime = Email::MIME->new(<<EOF);
  32 From: Me <me\@example.com>
  33 To: You <you\@example.com>
  34 Cc: $addr
  35 Message-Id: <nntp\@example.com>
  36 Subject: hihi
  37 Date: Thu, 01 Jan 1970 06:06:06 +0000
  38
  39 nntp
  40 EOF
  41
  42                 my $git = PublicInbox::Git->new($maindir);
  43                 my $im = PublicInbox::Import->new($git, 'test', $addr);
  44                 $im->add($mime);
  45                 $im->done($mime);
  46         }
  47         ok($sock, 'sock created');
  48         $cmd = [ '-httpd', '-W0', "--stdout=$out", "--stderr=$err" ];
  49         $td = start_script($cmd, undef, { 3 => $sock });
  50         my $host = $sock->sockhost;
  51         my $port = $sock->sockport;
  52         {
  53                 my $bad = tcp_connect($sock);
  54                 print $bad "GETT / HTTP/1.0\r\n\r\n" or die;
  55                 like(<$bad>, qr!\AHTTP/1\.[01] 405\b!, 'got 405 on bad req');
  56         }
  57         my $conn = tcp_connect($sock);
  58         ok($conn, 'connected');
  59         ok($conn->write("GET / HTTP/1.0\r\n\r\n"), 'wrote data to socket');
  60         {
  61                 my $buf;
  62                 ok($conn->read($buf, 4096), 'read some bytes');
  63                 like($buf, qr!\AHTTP/1\.[01] 404\b!, 'got 404 response');
  64                 is($conn->read($buf, 1), 0, "EOF");
  65         }
  66
  67         is(system(qw(git clone -q --mirror),
  68                         "http://$host:$port/$group", "$tmpdir/clone.git"),
  69                 0, 'smart clone successful');
  70
  71         # ensure dumb cloning works, too:
  72         is(system('git', "--git-dir=$maindir",
  73                 qw(config http.uploadpack false)),
  74                 0, 'disable http.uploadpack');
  75         is(system(qw(git clone -q --mirror),
  76                         "http://$host:$port/$group", "$tmpdir/dumb.git"),
  77                 0, 'clone successful');
  78
  79         ok($td->kill, 'killed httpd');
  80         $td->join;
  81
  82         is(system('git', "--git-dir=$tmpdir/clone.git",
  83                   qw(fsck --no-verbose)), 0,
  84                 'fsck on cloned directory successful');
  85 }
  86
  87 SKIP: {
  88         skip 'TCP_DEFER_ACCEPT is Linux-only', 1 if $^O ne 'linux';
  89         my $var = eval { Socket::TCP_DEFER_ACCEPT() } // 9;
  90         defined(my $x = getsockopt($sock, IPPROTO_TCP, $var)) or die;
  91         ok(unpack('i', $x) > 0, 'TCP_DEFER_ACCEPT set');
  92 };
  93 SKIP: {
  94         skip 'SO_ACCEPTFILTER is FreeBSD-only', 1 if $^O ne 'freebsd';
  95         if (system('kldstat -m accf_http >/dev/null') != 0) {
  96                 skip 'accf_http not loaded: kldload accf_http', 1;
  97         }
  98         require PublicInbox::Daemon;
  99         my $var = PublicInbox::Daemon::SO_ACCEPTFILTER();
 100         my $x = getsockopt($sock, SOL_SOCKET, $var);
 101         like($x, qr/\Ahttpready\0+\z/, 'got httpready accf for HTTP');
 102 };
 103
 104 done_testing();
 105
 106 1;