t/httpd.t

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::TestCommon;
   7 use PublicInbox::Eml;
   8 use Socket qw(IPPROTO_TCP SOL_SOCKET);
   9 require_mods(qw(Plack::Util Plack::Builder HTTP::Date HTTP::Status));
  10
  11 # FIXME: too much setup
  12 my ($tmpdir, $for_destroy) = tmpdir();
  13 my $home = "$tmpdir/pi-home";
  14 my $err = "$tmpdir/stderr.log";
  15 my $out = "$tmpdir/stdout.log";
  16 my $maindir = "$tmpdir/main.git";
  17 my $group = 'test-httpd';
  18 my $addr = $group . '@example.com';
  19 my $cfgpfx = "publicinbox.$group";
  20 my $sock = tcp_server();
  21 my $td;
  22 use_ok 'PublicInbox::Git';
  23 use_ok 'PublicInbox::Import';
  24 {
  25         local $ENV{HOME} = $home;
  26         my $cmd = [ '-init', $group, $maindir, 'http://example.com/', $addr ];
  27         ok(run_script($cmd), 'init ran properly');
  28
  29         # ensure successful message delivery
  30         {
  31                 my $mime = PublicInbox::Eml->new(<<EOF);
  32 From: Me <me\@example.com>
  33 To: You <you\@example.com>
  34 Cc: $addr
  35 Message-Id: <nntp\@example.com>
  36 Subject: hihi
  37 Date: Thu, 01 Jan 1970 06:06:06 +0000
  38
  39 nntp
  40 EOF
  41
  42                 my $git = PublicInbox::Git->new($maindir);
  43                 my $im = PublicInbox::Import->new($git, 'test', $addr);
  44                 $im->add($mime);
  45                 $im->done($mime);
  46         }
  47         $cmd = [ '-httpd', '-W0', "--stdout=$out", "--stderr=$err" ];
  48         $td = start_script($cmd, undef, { 3 => $sock });
  49         my $http_pfx = 'http://'.tcp_host_port($sock);
  50         {
  51                 my $bad = tcp_connect($sock);
  52                 print $bad "GETT / HTTP/1.0\r\n\r\n" or die;
  53                 like(<$bad>, qr!\AHTTP/1\.[01] 405\b!, 'got 405 on bad req');
  54         }
  55         my $conn = tcp_connect($sock);
  56         ok($conn, 'connected');
  57         ok($conn->write("GET / HTTP/1.0\r\n\r\n"), 'wrote data to socket');
  58         {
  59                 my $buf;
  60                 ok($conn->read($buf, 4096), 'read some bytes');
  61                 like($buf, qr!\AHTTP/1\.[01] 404\b!, 'got 404 response');
  62                 is($conn->read($buf, 1), 0, "EOF");
  63         }
  64
  65         is(xsys(qw(git clone -q --mirror),
  66                         "$http_pfx/$group", "$tmpdir/clone.git"),
  67                 0, 'smart clone successful');
  68
  69         # ensure dumb cloning works, too:
  70         is(xsys('git', "--git-dir=$maindir",
  71                 qw(config http.uploadpack false)),
  72                 0, 'disable http.uploadpack');
  73         is(xsys(qw(git clone -q --mirror),
  74                         "$http_pfx/$group", "$tmpdir/dumb.git"),
  75                 0, 'clone successful');
  76
  77         ok($td->kill, 'killed httpd');
  78         $td->join;
  79
  80         is(xsys('git', "--git-dir=$tmpdir/clone.git",
  81                   qw(fsck --no-verbose)), 0,
  82                 'fsck on cloned directory successful');
  83 }
  84
  85 SKIP: {
  86         skip 'TCP_DEFER_ACCEPT is Linux-only', 1 if $^O ne 'linux';
  87         my $var = eval { Socket::TCP_DEFER_ACCEPT() } // 9;
  88         defined(my $x = getsockopt($sock, IPPROTO_TCP, $var)) or die;
  89         ok(unpack('i', $x) > 0, 'TCP_DEFER_ACCEPT set');
  90 };
  91 SKIP: {
  92         skip 'SO_ACCEPTFILTER is FreeBSD-only', 1 if $^O ne 'freebsd';
  93         if (system('kldstat -m accf_http >/dev/null') != 0) {
  94                 skip 'accf_http not loaded: kldload accf_http', 1;
  95         }
  96         require PublicInbox::Daemon;
  97         my $var = PublicInbox::Daemon::SO_ACCEPTFILTER();
  98         my $x = getsockopt($sock, SOL_SOCKET, $var);
  99         like($x, qr/\Ahttpready\0+\z/, 'got httpready accf for HTTP');
 100 };
 101
 102 done_testing();
 103
 104 1;