t/httpd.t

   1 #!perl -w
   2 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use PublicInbox::TestCommon;
   7 use PublicInbox::Eml;
   8 use Socket qw(IPPROTO_TCP SOL_SOCKET);
   9 require_mods(qw(Plack::Util Plack::Builder HTTP::Date HTTP::Status));
  10
  11 # FIXME: too much setup
  12 my ($tmpdir, $for_destroy) = tmpdir();
  13 my $home = "$tmpdir/pi-home";
  14 my $err = "$tmpdir/stderr.log";
  15 my $out = "$tmpdir/stdout.log";
  16 my $inboxdir = "$tmpdir/i.git";
  17 my $group = 'test-httpd';
  18 my $addr = $group . '@example.com';
  19 my $sock = tcp_server();
  20 my $td;
  21 {
  22         create_inbox 'test', tmpdir => $inboxdir, sub {
  23                 my ($im, $ibx) = @_;
  24                 $im->add(PublicInbox::Eml->new(<<EOF)) or BAIL_OUT;
  25 From: Me <me\@example.com>
  26 To: You <you\@example.com>
  27 Cc: $addr
  28 Message-Id: <nntp\@example.com>
  29 Subject: hihi
  30 Date: Thu, 01 Jan 1970 06:06:06 +0000
  31
  32 nntp
  33 EOF
  34         };
  35         local $ENV{HOME} = $home;
  36         my $cmd = [ '-init', $group, $inboxdir, 'http://example.com/', $addr ];
  37         ok(run_script($cmd), 'init ran properly');
  38         $cmd = [ '-httpd', '-W0', "--stdout=$out", "--stderr=$err" ];
  39         $td = start_script($cmd, undef, { 3 => $sock });
  40         my $http_pfx = 'http://'.tcp_host_port($sock);
  41         {
  42                 my $bad = tcp_connect($sock);
  43                 print $bad "GETT / HTTP/1.0\r\n\r\n" or die;
  44                 like(<$bad>, qr!\AHTTP/1\.[01] 405\b!, 'got 405 on bad req');
  45         }
  46         my $conn = tcp_connect($sock);
  47         ok($conn->write("GET / HTTP/1.0\r\n\r\n"), 'wrote data to socket');
  48         {
  49                 my $buf;
  50                 ok($conn->read($buf, 4096), 'read some bytes');
  51                 like($buf, qr!\AHTTP/1\.[01] 404\b!, 'got 404 response');
  52                 is($conn->read($buf, 1), 0, "EOF");
  53         }
  54
  55         is(xsys(qw(git clone -q --mirror),
  56                         "$http_pfx/$group", "$tmpdir/clone.git"),
  57                 0, 'smart clone successful');
  58
  59         # ensure dumb cloning works, too:
  60         is(xsys('git', "--git-dir=$inboxdir",
  61                 qw(config http.uploadpack false)),
  62                 0, 'disable http.uploadpack');
  63         is(xsys(qw(git clone -q --mirror),
  64                         "$http_pfx/$group", "$tmpdir/dumb.git"),
  65                 0, 'clone successful');
  66
  67         ok($td->kill, 'killed httpd');
  68         $td->join;
  69
  70         is(xsys('git', "--git-dir=$tmpdir/clone.git",
  71                   qw(fsck --no-verbose)), 0,
  72                 'fsck on cloned directory successful');
  73 }
  74
  75 SKIP: {
  76         skip 'TCP_DEFER_ACCEPT is Linux-only', 1 if $^O ne 'linux';
  77         my $var = eval { Socket::TCP_DEFER_ACCEPT() } // 9;
  78         defined(my $x = getsockopt($sock, IPPROTO_TCP, $var)) or die;
  79         ok(unpack('i', $x) > 0, 'TCP_DEFER_ACCEPT set');
  80 };
  81 SKIP: {
  82         skip 'SO_ACCEPTFILTER is FreeBSD-only', 1 if $^O ne 'freebsd';
  83         if (system('kldstat -m accf_http >/dev/null') != 0) {
  84                 skip 'accf_http not loaded: kldload accf_http', 1;
  85         }
  86         require PublicInbox::Daemon;
  87         my $var = PublicInbox::Daemon::SO_ACCEPTFILTER();
  88         my $x = getsockopt($sock, SOL_SOCKET, $var);
  89         like($x, qr/\Ahttpready\0+\z/, 'got httpready accf for HTTP');
  90 };
  91
  92 done_testing;