t/imap_searchqp.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use Test::More;
   6 use Time::Local qw(timegm);
   7 use PublicInbox::TestCommon;
   8 require_mods(qw(Parse::RecDescent));
   9 use_ok 'PublicInbox::IMAPsearchqp';
  10 use_ok 'PublicInbox::IMAP';
  11
  12 my $imap = bless {}, 'PublicInbox::IMAP';
  13 my $q;
  14 my $parse = sub { PublicInbox::IMAPsearchqp::parse($imap, $_[0]) };
  15
  16 $q = $parse->(qq{OR HEADER TO Brian (OR FROM Ryan (OR TO Joe CC Scott))});
  17 is($q->{sql}, undef, 'not using SQLite for complex query');
  18 is($q->{xap}, '(t:"brian" OR (f:"ryan" OR (t:"joe" OR c:"scott")))',
  19         'complex query matches Xapian query string');
  20
  21 $q = $parse->(qq{HEADER CC b SENTSINCE 2-Oct-1993});
  22 is($q->{xap}, 'c:"b" d:19931002..', 'compound query');
  23
  24 $q = $parse->(qq{HEADER CC B (SENTBEFORE 2-Oct-1993)});
  25 is($q->{xap}, 'c:"b" d:..19931002', 'compound query w/ parens');
  26
  27 { # limit recursion, stack and CPU cycles ain't free
  28         my $n = 10;
  29         my $s = ('('x$n ). 'To a' . ( ')'x$n );
  30         $q = $parse->($s);
  31         is($q->{xap}, 't:"a"', 'nesting works');
  32         ++$n;
  33         $s = ('('x$n ). 'To a' . ( ')'x$n );
  34         my $err = $parse->($s);
  35         like($err, qr/\ABAD /, 'reject deep nesting');
  36 }
  37
  38 # IMAP has at least 6 ways of interpreting a date
  39 {
  40         my $t0 = timegm(0, 0, 0, 2, 10 - 1, 1993);
  41         my $t1 = $t0 + 86399; # no leap (day|second) support
  42         my $s;
  43
  44         $q = $parse->($s = qq{SENTBEFORE 2-Oct-1993});
  45         is_deeply($q->{sql}, \" AND ds <= $t0", 'SENTBEFORE SQL');
  46         $q = $parse->("FROM z $s");
  47         is($q->{xap}, 'f:"z" d:..19931002', 'SENTBEFORE Xapian');
  48
  49         $q = $parse->($s = qq{SENTSINCE 2-Oct-1993});
  50         is_deeply($q->{sql}, \" AND ds >= $t0", 'SENTSINCE SQL');
  51         $q = $parse->("FROM z $s");
  52         is($q->{xap}, 'f:"z" d:19931002..', 'SENTSINCE Xapian');
  53
  54         $q = $parse->($s = qq{SENTON 2-Oct-1993});
  55         is_deeply($q->{sql}, \" AND ds >= $t0 AND ds <= $t1", 'SENTON SQL');
  56         $q = $parse->("FROM z $s");
  57         is($q->{xap}, 'f:"z" dt:19931002000000..19931002235959',
  58                 'SENTON Xapian');
  59
  60         $q = $parse->($s = qq{BEFORE 2-Oct-1993});
  61         is_deeply($q->{sql}, \" AND ts <= $t0", 'BEFORE SQL');
  62         $q = $parse->("FROM z $s");
  63         is($q->{xap}, qq{f:"z" ts:..$t0}, 'BEFORE Xapian');
  64
  65         $q = $parse->($s = qq{SINCE 2-Oct-1993});
  66         is_deeply($q->{sql}, \" AND ts >= $t0", 'SINCE SQL');
  67         $q = $parse->("FROM z $s");
  68         is($q->{xap}, qq{f:"z" ts:$t0..}, 'SINCE Xapian');
  69
  70         $q = $parse->($s = qq{ON 2-Oct-1993});
  71         is_deeply($q->{sql}, \" AND ts >= $t0 AND ts <= $t1", 'ON SQL');
  72         $q = $parse->("FROM z $s");
  73         is($q->{xap}, qq{f:"z" ts:$t0..$t1}, 'ON Xapian');
  74 }
  75
  76 {
  77         $imap->{uo2m} = pack('S*', (1..50000));
  78         $imap->{uid_base} = 50000;
  79         my $err = $parse->(qq{9:});
  80         my $s;
  81
  82         like($err, qr/\ABAD /, 'bad MSN range');
  83         $err = $parse->(qq{UID 9:});
  84         like($err, qr/\ABAD /, 'bad UID range');
  85         $err = $parse->(qq{FROM x UID 9:});
  86         like($err, qr/\ABAD /, 'bad UID range with Xapian');
  87         $err = $parse->(qq{FROM x 9:});
  88         like($err, qr/\ABAD /, 'bad UID range with Xapian');
  89
  90         $q = $parse->($s = qq{UID 50009:50099});
  91         is_deeply($q->{sql}, \' AND (num >= 50009 AND num <= 50099)',
  92                 'SQL generated for UID range');
  93         $q = $parse->("CC x $s");
  94         is($q->{xap}, qq{c:"x" uid:50009..50099},
  95                 'Xapian generated for UID range');
  96
  97         $q = $parse->($s = qq{9:99});
  98         is_deeply($q->{sql}, \' AND (num >= 50009 AND num <= 50099)',
  99                 'SQL generated for MSN range');
 100         $q = $parse->("CC x $s");
 101         is($q->{xap}, qq{c:"x" uid:50009..50099},
 102                 'Xapian generated for MSN range');
 103 }
 104
 105 done_testing;