t/imap_searchqp.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use Test::More;
   6 use Time::Local qw(timegm);
   7 use PublicInbox::TestCommon;
   8 require_mods(qw(DBD::SQLite Email::Address::XS||Mail::Address
   9         Parse::RecDescent));
  10 use_ok 'PublicInbox::IMAPsearchqp';
  11 use_ok 'PublicInbox::IMAP';
  12
  13 my $imap = bless {}, 'PublicInbox::IMAP';
  14 my $q;
  15 my $parse = sub { PublicInbox::IMAPsearchqp::parse($imap, $_[0]) };
  16
  17 $q = $parse->(qq{OR HEADER TO Brian (OR FROM Ryan (OR TO Joe CC Scott))});
  18 is($q->{sql}, undef, 'not using SQLite for complex query');
  19 is($q->{xap}, '(t:"brian" OR (f:"ryan" OR (t:"joe" OR c:"scott")))',
  20         'complex query matches Xapian query string');
  21
  22 $q = $parse->(qq{HEADER CC b SENTSINCE 2-Oct-1993});
  23 is($q->{xap}, 'c:"b" d:19931002..', 'compound query');
  24
  25 $q = $parse->(qq{CHARSET UTF-8 From b});
  26 is($q->{xap}, 'f:"b"', 'charset handled');
  27 $q = $parse->(qq{CHARSET WTF-8 From b});
  28 like($q, qr/\ANO \[/, 'bad charset rejected');
  29 {
  30         # TODO: squelch errors by default? clients could flood logs
  31         open my $fh, '>:scalar', \(my $buf) or die;
  32         local *STDERR = $fh;
  33         $q = $parse->(qq{CHARSET});
  34 }
  35 like($q, qr/\ABAD /, 'bad charset rejected');
  36
  37 $q = $parse->(qq{HEADER CC B (SENTBEFORE 2-Oct-1993)});
  38 is($q->{xap}, 'c:"b" d:..19931002', 'compound query w/ parens');
  39
  40 { # limit recursion, stack and CPU cycles ain't free
  41         my $n = 10;
  42         my $s = ('('x$n ). 'To a' . ( ')'x$n );
  43         $q = $parse->($s);
  44         is($q->{xap}, 't:"a"', 'nesting works');
  45         ++$n;
  46         $s = ('('x$n ). 'To a' . ( ')'x$n );
  47         my $err = $parse->($s);
  48         like($err, qr/\ABAD /, 'reject deep nesting');
  49 }
  50
  51 # IMAP has at least 6 ways of interpreting a date
  52 {
  53         my $t0 = timegm(0, 0, 0, 2, 10 - 1, 1993);
  54         my $t1 = $t0 + 86399; # no leap (day|second) support
  55         my $s;
  56
  57         $q = $parse->($s = qq{SENTBEFORE 2-Oct-1993});
  58         is_deeply($q->{sql}, \" AND ds <= $t0", 'SENTBEFORE SQL');
  59         $q = $parse->("FROM z $s");
  60         is($q->{xap}, 'f:"z" d:..19931002', 'SENTBEFORE Xapian');
  61
  62         $q = $parse->($s = qq{SENTSINCE 2-Oct-1993});
  63         is_deeply($q->{sql}, \" AND ds >= $t0", 'SENTSINCE SQL');
  64         $q = $parse->("FROM z $s");
  65         is($q->{xap}, 'f:"z" d:19931002..', 'SENTSINCE Xapian');
  66
  67         $q = $parse->($s = qq{SENTON 2-Oct-1993});
  68         is_deeply($q->{sql}, \" AND ds >= $t0 AND ds <= $t1", 'SENTON SQL');
  69         $q = $parse->("FROM z $s");
  70         is($q->{xap}, 'f:"z" dt:19931002000000..19931002235959',
  71                 'SENTON Xapian');
  72
  73         $q = $parse->($s = qq{BEFORE 2-Oct-1993});
  74         is_deeply($q->{sql}, \" AND ts <= $t0", 'BEFORE SQL');
  75         $q = $parse->("FROM z $s");
  76         is($q->{xap}, qq{f:"z" ts:..$t0}, 'BEFORE Xapian');
  77
  78         $q = $parse->($s = qq{SINCE 2-Oct-1993});
  79         is_deeply($q->{sql}, \" AND ts >= $t0", 'SINCE SQL');
  80         $q = $parse->("FROM z $s");
  81         is($q->{xap}, qq{f:"z" ts:$t0..}, 'SINCE Xapian');
  82
  83         $q = $parse->($s = qq{ON 2-Oct-1993});
  84         is_deeply($q->{sql}, \" AND ts >= $t0 AND ts <= $t1", 'ON SQL');
  85         $q = $parse->("FROM z $s");
  86         is($q->{xap}, qq{f:"z" ts:$t0..$t1}, 'ON Xapian');
  87 }
  88
  89 {
  90         $imap->{uo2m} = pack('S*', (1..50000));
  91         $imap->{uid_base} = 50000;
  92         my $err = $parse->(qq{9:});
  93         my $s;
  94
  95         like($err, qr/\ABAD /, 'bad MSN range');
  96         $err = $parse->(qq{UID 9:});
  97         like($err, qr/\ABAD /, 'bad UID range');
  98         $err = $parse->(qq{FROM x UID 9:});
  99         like($err, qr/\ABAD /, 'bad UID range with Xapian');
 100         $err = $parse->(qq{FROM x 9:});
 101         like($err, qr/\ABAD /, 'bad UID range with Xapian');
 102
 103         $q = $parse->($s = qq{UID 50009:50099});
 104         is_deeply($q->{sql}, \' AND (num >= 50009 AND num <= 50099)',
 105                 'SQL generated for UID range');
 106         $q = $parse->("CC x $s");
 107         is($q->{xap}, qq{c:"x" uid:50009..50099},
 108                 'Xapian generated for UID range');
 109
 110         $q = $parse->($s = qq{9:99});
 111         is_deeply($q->{sql}, \' AND (num >= 50009 AND num <= 50099)',
 112                 'SQL generated for MSN range');
 113         $q = $parse->("CC x $s");
 114         is($q->{xap}, qq{c:"x" uid:50009..50099},
 115                 'Xapian generated for MSN range');
 116 }
 117
 118 done_testing;