t/imap_searchqp.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use Test::More;
   6 use Time::Local qw(timegm);
   7 use PublicInbox::TestCommon;
   8 require_mods(qw(Parse::RecDescent));
   9 use_ok 'PublicInbox::IMAPsearchqp';
  10 use_ok 'PublicInbox::IMAP';
  11
  12 my $imap = bless {}, 'PublicInbox::IMAP';
  13 my $q;
  14 my $parse = sub { PublicInbox::IMAPsearchqp::parse($imap, $_[0]) };
  15
  16 $q = $parse->(qq{OR HEADER TO Brian (OR FROM Ryan (OR TO Joe CC Scott))});
  17 is($q->{sql}, undef, 'not using SQLite for complex query');
  18 is($q->{xap}, '(t:"brian" OR (f:"ryan" OR (t:"joe" OR c:"scott")))',
  19         'complex query matches Xapian query string');
  20
  21 $q = $parse->(qq{HEADER CC b SENTSINCE 2-Oct-1993});
  22 is($q->{xap}, 'c:"b" d:19931002..', 'compound query');
  23
  24 $q = $parse->(qq{CHARSET UTF-8 From b});
  25 is($q->{xap}, 'f:"b"', 'charset handled');
  26 $q = $parse->(qq{CHARSET WTF-8 From b});
  27 like($q, qr/\ANO \[/, 'bad charset rejected');
  28 {
  29         # TODO: squelch errors by default? clients could flood logs
  30         open my $fh, '>:scalar', \(my $buf) or die;
  31         local *STDERR = $fh;
  32         $q = $parse->(qq{CHARSET});
  33 }
  34 like($q, qr/\ABAD /, 'bad charset rejected');
  35
  36 $q = $parse->(qq{HEADER CC B (SENTBEFORE 2-Oct-1993)});
  37 is($q->{xap}, 'c:"b" d:..19931002', 'compound query w/ parens');
  38
  39 { # limit recursion, stack and CPU cycles ain't free
  40         my $n = 10;
  41         my $s = ('('x$n ). 'To a' . ( ')'x$n );
  42         $q = $parse->($s);
  43         is($q->{xap}, 't:"a"', 'nesting works');
  44         ++$n;
  45         $s = ('('x$n ). 'To a' . ( ')'x$n );
  46         my $err = $parse->($s);
  47         like($err, qr/\ABAD /, 'reject deep nesting');
  48 }
  49
  50 # IMAP has at least 6 ways of interpreting a date
  51 {
  52         my $t0 = timegm(0, 0, 0, 2, 10 - 1, 1993);
  53         my $t1 = $t0 + 86399; # no leap (day|second) support
  54         my $s;
  55
  56         $q = $parse->($s = qq{SENTBEFORE 2-Oct-1993});
  57         is_deeply($q->{sql}, \" AND ds <= $t0", 'SENTBEFORE SQL');
  58         $q = $parse->("FROM z $s");
  59         is($q->{xap}, 'f:"z" d:..19931002', 'SENTBEFORE Xapian');
  60
  61         $q = $parse->($s = qq{SENTSINCE 2-Oct-1993});
  62         is_deeply($q->{sql}, \" AND ds >= $t0", 'SENTSINCE SQL');
  63         $q = $parse->("FROM z $s");
  64         is($q->{xap}, 'f:"z" d:19931002..', 'SENTSINCE Xapian');
  65
  66         $q = $parse->($s = qq{SENTON 2-Oct-1993});
  67         is_deeply($q->{sql}, \" AND ds >= $t0 AND ds <= $t1", 'SENTON SQL');
  68         $q = $parse->("FROM z $s");
  69         is($q->{xap}, 'f:"z" dt:19931002000000..19931002235959',
  70                 'SENTON Xapian');
  71
  72         $q = $parse->($s = qq{BEFORE 2-Oct-1993});
  73         is_deeply($q->{sql}, \" AND ts <= $t0", 'BEFORE SQL');
  74         $q = $parse->("FROM z $s");
  75         is($q->{xap}, qq{f:"z" ts:..$t0}, 'BEFORE Xapian');
  76
  77         $q = $parse->($s = qq{SINCE 2-Oct-1993});
  78         is_deeply($q->{sql}, \" AND ts >= $t0", 'SINCE SQL');
  79         $q = $parse->("FROM z $s");
  80         is($q->{xap}, qq{f:"z" ts:$t0..}, 'SINCE Xapian');
  81
  82         $q = $parse->($s = qq{ON 2-Oct-1993});
  83         is_deeply($q->{sql}, \" AND ts >= $t0 AND ts <= $t1", 'ON SQL');
  84         $q = $parse->("FROM z $s");
  85         is($q->{xap}, qq{f:"z" ts:$t0..$t1}, 'ON Xapian');
  86 }
  87
  88 {
  89         $imap->{uo2m} = pack('S*', (1..50000));
  90         $imap->{uid_base} = 50000;
  91         my $err = $parse->(qq{9:});
  92         my $s;
  93
  94         like($err, qr/\ABAD /, 'bad MSN range');
  95         $err = $parse->(qq{UID 9:});
  96         like($err, qr/\ABAD /, 'bad UID range');
  97         $err = $parse->(qq{FROM x UID 9:});
  98         like($err, qr/\ABAD /, 'bad UID range with Xapian');
  99         $err = $parse->(qq{FROM x 9:});
 100         like($err, qr/\ABAD /, 'bad UID range with Xapian');
 101
 102         $q = $parse->($s = qq{UID 50009:50099});
 103         is_deeply($q->{sql}, \' AND (num >= 50009 AND num <= 50099)',
 104                 'SQL generated for UID range');
 105         $q = $parse->("CC x $s");
 106         is($q->{xap}, qq{c:"x" uid:50009..50099},
 107                 'Xapian generated for UID range');
 108
 109         $q = $parse->($s = qq{9:99});
 110         is_deeply($q->{sql}, \' AND (num >= 50009 AND num <= 50099)',
 111                 'SQL generated for MSN range');
 112         $q = $parse->("CC x $s");
 113         is($q->{xap}, qq{c:"x" uid:50009..50099},
 114                 'Xapian generated for MSN range');
 115 }
 116
 117 done_testing;