t/imapd.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # end-to-end IMAP tests, see unit tests in t/imap.t, too
   5 use strict;
   6 use Test::More;
   7 use Time::HiRes ();
   8 use PublicInbox::TestCommon;
   9 use PublicInbox::Config;
  10 use PublicInbox::Spawn qw(which);
  11 require_mods(qw(DBD::SQLite Mail::IMAPClient Mail::IMAPClient::BodyStructure));
  12 my $imap_client = 'Mail::IMAPClient';
  13 my $can_compress = $imap_client->can('compress');
  14 if ($can_compress) { # hope this gets fixed upstream, soon
  15         require PublicInbox::IMAPClient;
  16         $imap_client = 'PublicInbox::IMAPClient';
  17 }
  18
  19 require_ok 'PublicInbox::IMAP';
  20 my $first_range = '1-'.PublicInbox::IMAP::UID_BLOCK();
  21
  22 my $level = '-Lbasic';
  23 SKIP: {
  24         require_mods('Search::Xapian', 1);
  25         $level = '-Lmedium';
  26 };
  27
  28 my @V = (1);
  29 push(@V, 2) if require_git('2.6', 1);
  30
  31 my ($tmpdir, $for_destroy) = tmpdir();
  32 my $home = "$tmpdir/home";
  33 local $ENV{HOME} = $home;
  34
  35 for my $V (@V) {
  36         my $addr = "i$V\@example.com";
  37         my $name = "i$V";
  38         my $url = "http://example.com/i$V";
  39         my $inboxdir = "$tmpdir/$name";
  40         my $folder = "inbox.i$V";
  41         my $cmd = ['-init', "-V$V", $level, $name, $inboxdir, $url, $addr];
  42         run_script($cmd) or BAIL_OUT("init $name");
  43         xsys(qw(git config), "--file=$ENV{HOME}/.public-inbox/config",
  44                         "publicinbox.$name.newsgroup", $folder) == 0 or
  45                         BAIL_OUT("setting newsgroup $V");
  46         if ($V == 1) {
  47                 xsys(qw(git config), "--file=$ENV{HOME}/.public-inbox/config",
  48                         'publicinboxmda.spamcheck', 'none') == 0 or
  49                         BAIL_OUT("config: $?");
  50         }
  51         open(my $fh, '<', 't/utf8.eml') or BAIL_OUT("open t/utf8.eml: $!");
  52         my $env = { ORIGINAL_RECIPIENT => $addr };
  53         run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or
  54                 BAIL_OUT('-mda delivery');
  55         if ($V == 1) {
  56                 run_script(['-index', $inboxdir]) or BAIL_OUT("index $?");
  57         }
  58 }
  59 my $sock = tcp_server();
  60 my $err = "$tmpdir/stderr.log";
  61 my $out = "$tmpdir/stdout.log";
  62 my $cmd = [ '-imapd', '-W0', "--stdout=$out", "--stderr=$err" ];
  63 my $td = start_script($cmd, undef, { 3 => $sock }) or BAIL_OUT("-imapd: $?");
  64 my %mic_opt = (
  65         Server => $sock->sockhost,
  66         Port => $sock->sockport,
  67         Uid => 1,
  68 );
  69 my $mic = $imap_client->new(%mic_opt);
  70 my $pre_login_capa = $mic->capability;
  71 is(grep(/\AAUTH=ANONYMOUS\z/, @$pre_login_capa), 1,
  72         'AUTH=ANONYMOUS advertised pre-login');
  73
  74 $mic->User('lorelei');
  75 $mic->Password('Hunter2');
  76 ok($mic->login && $mic->IsAuthenticated, 'LOGIN works');
  77 my $post_login_capa = $mic->capability;
  78 ok(join("\n", @$pre_login_capa) ne join("\n", @$post_login_capa),
  79         'got different capabilities post-login');
  80
  81 $mic_opt{Authmechanism} = 'ANONYMOUS';
  82 $mic_opt{Authcallback} = sub { '' };
  83 $mic = $imap_client->new(%mic_opt);
  84 ok($mic && $mic->login && $mic->IsAuthenticated, 'AUTHENTICATE ANONYMOUS');
  85 my $post_auth_anon_capa = $mic->capability;
  86 is_deeply($post_auth_anon_capa, $post_login_capa,
  87         'auth anon has same capabilities');
  88 my $e;
  89 ok(!$mic->examine('foo') && ($e = $@), 'EXAMINE non-existent');
  90 like($e, qr/\bNO\b/, 'got a NO on EXAMINE for non-existent');
  91 ok(!$mic->select('foo') && ($e = $@), 'EXAMINE non-existent');
  92 like($e, qr/\bNO\b/, 'got a NO on EXAMINE for non-existent');
  93 my $mailbox1 = "inbox.i1.$first_range";
  94 ok($mic->select('inbox.i1'), 'SELECT on parent succeeds');
  95 ok($mic->select($mailbox1), 'SELECT succeeds');
  96 ok($mic->examine($mailbox1), 'EXAMINE succeeds');
  97 my @raw = $mic->status($mailbox1, qw(Messages uidnext uidvalidity));
  98 is(scalar(@raw), 2, 'got status response');
  99 like($raw[0], qr/\A\*\x20STATUS\x20inbox\.i1\.$first_range\x20
 100         \(MESSAGES\x20\d+\x20UIDNEXT\x20\d+\x20UIDVALIDITY\x20\d+\)\r\n/sx);
 101 like($raw[1], qr/\A\S+ OK /, 'finished status response');
 102
 103 @raw = $mic->list;
 104 like($raw[0], qr/^\* LIST \(.*?\) "\." inbox/,
 105         'got an inbox');
 106 like($raw[-1], qr/^\S+ OK /, 'response ended with OK');
 107 is(scalar(@raw), scalar(@V) + 4, 'default LIST response');
 108 @raw = $mic->list('', 'inbox.i1');
 109 is(scalar(@raw), 2, 'limited LIST response');
 110 like($raw[0], qr/^\* LIST \(.*?\) "\." inbox/,
 111                 'got an inbox.i1');
 112 like($raw[-1], qr/^\S+ OK /, 'response ended with OK');
 113
 114 my $ret = $mic->search('all') or BAIL_OUT "SEARCH FAIL $@";
 115 is_deeply($ret, [ 1 ], 'search all works');
 116 $ret = $mic->search('uid 1') or BAIL_OUT "SEARCH FAIL $@";
 117 is_deeply($ret, [ 1 ], 'search UID 1 works');
 118 $ret = $mic->search('uid 1:1') or BAIL_OUT "SEARCH FAIL $@";
 119 is_deeply($ret, [ 1 ], 'search UID 1:1 works');
 120 $ret = $mic->search('uid 1:*') or BAIL_OUT "SEARCH FAIL $@";
 121 is_deeply($ret, [ 1 ], 'search UID 1:* works');
 122
 123 is_deeply(scalar $mic->flags('1'), [], '->flags works');
 124 {
 125         # RFC 3501 section 6.4.8 states:
 126         # Also note that a UID range of 559:* always includes the
 127         # UID of the last message in the mailbox, even if 559 is
 128         # higher than any assigned UID value.
 129         my $exp = $mic->fetch_hash(1, 'UID');
 130         $ret = $mic->fetch_hash('559:*', 'UID');
 131         is_deeply($ret, $exp, 'beginning range too big');
 132         for my $r (qw(559:558 558:559)) {
 133                 $ret = $mic->fetch_hash($r, 'UID');
 134                 is_deeply($ret, {}, "out-of-range UID FETCH $r");
 135         }
 136 }
 137
 138 for my $r ('1:*', '1') {
 139         $ret = $mic->fetch_hash($r, 'RFC822') or BAIL_OUT "FETCH $@";
 140         is_deeply([keys %$ret], [1]);
 141         like($ret->{1}->{RFC822}, qr/\r\n\r\nThis is a test/, 'read full');
 142
 143         # ensure Mail::IMAPClient behaves
 144         my $str = $mic->message_string($r) or BAIL_OUT "->message_string: $@";
 145         is($str, $ret->{1}->{RFC822}, '->message_string works as expected');
 146
 147         my $sz = $mic->fetch_hash($r, 'RFC822.size') or BAIL_OUT "FETCH $@";
 148         is($sz->{1}->{'RFC822.SIZE'}, length($ret->{1}->{RFC822}),
 149                 'RFC822.SIZE');
 150
 151         $ret = $mic->fetch_hash($r, 'RFC822.HEADER') or BAIL_OUT "FETCH $@";
 152         is_deeply([keys %$ret], [1]);
 153         like($ret->{1}->{'RFC822.HEADER'},
 154                 qr/^Message-ID: <testmessage\@example\.com>/ms, 'read header');
 155
 156         $ret = $mic->fetch_hash($r, 'INTERNALDATE') or BAIL_OUT "FETCH $@";
 157         is($ret->{1}->{'INTERNALDATE'}, '01-Jan-1970 00:00:00 +0000',
 158                 'internaldate matches');
 159         ok(!$mic->fetch_hash($r, 'INFERNALDATE'), 'bogus attribute fails');
 160
 161         my $envelope = $mic->get_envelope($r) or BAIL_OUT("get_envelope: $@");
 162         is($envelope->{bcc}, 'NIL', 'empty bcc');
 163         is($envelope->{messageid}, '<testmessage@example.com>', 'messageid');
 164         is(scalar @{$envelope->{to}}, 1, 'one {to} header');
 165         # *sigh* too much to verify...
 166         #use Data::Dumper; diag Dumper($envelope);
 167
 168         $ret = $mic->fetch_hash($r, 'FLAGS') or BAIL_OUT "FETCH $@";
 169         is_deeply($ret->{1}->{FLAGS}, '', 'no flags');
 170
 171         $ret = $mic->fetch_hash($r, 'BODY[1]') or BAIL_OUT "FETCH $@";
 172         like($ret->{1}->{'BODY[1]'}, qr/\AThis is a test message/, 'BODY[1]');
 173
 174         $ret = $mic->fetch_hash($r, 'BODY[1]<1>') or BAIL_OUT "FETCH $@";
 175         like($ret->{1}->{'BODY[1]<1>'}, qr/\Ahis is a test message/,
 176                         'BODY[1]<1>');
 177
 178         $ret = $mic->fetch_hash($r, 'BODY[1]<2.3>') or BAIL_OUT "FETCH $@";
 179         is($ret->{1}->{'BODY[1]<2>'}, "is ", 'BODY[1]<2.3>');
 180         $ret = $mic->bodypart_string($r, 1, 3, 2) or
 181                                         BAIL_OUT "bodypart_string $@";
 182         is($ret, "is ", 'bodypart string');
 183
 184         $ret = $mic->fetch_hash($r, 'BODY[HEADER.FIELDS.NOT (Message-ID)]')
 185                 or BAIL_OUT "FETCH $@";
 186         $ret = $ret->{1}->{'BODY[HEADER.FIELDS.NOT (MESSAGE-ID)]'};
 187         unlike($ret, qr/message-id/i, 'Message-ID excluded');
 188         like($ret, qr/\r\n\r\n\z/s, 'got header end');
 189
 190         $ret = $mic->fetch_hash($r, 'BODY[HEADER.FIELDS (Message-ID)]')
 191                 or BAIL_OUT "FETCH $@";
 192         is($ret->{1}->{'BODY[HEADER.FIELDS (MESSAGE-ID)]'},
 193                 'Message-ID: <testmessage@example.com>'."\r\n\r\n",
 194                 'got only Message-ID');
 195
 196         my $bs = $mic->get_bodystructure($r) or BAIL_OUT("bodystructure: $@");
 197         ok($bs, 'got a bodystructure');
 198         is(lc($bs->bodytype), 'text', '->bodytype');
 199         is(lc($bs->bodyenc), '8bit', '->bodyenc');
 200 }
 201
 202 is_deeply([$mic->has_capability('COMPRESS')], ['DEFLATE'], 'deflate cap');
 203 SKIP: {
 204         skip 'Mail::IMAPClient too old for ->compress', 2 if !$can_compress;
 205         my $c = $imap_client->new(%mic_opt);
 206         ok($c && $c->compress, 'compress enabled');
 207         ok($c->examine($mailbox1), 'EXAMINE succeeds after COMPRESS');
 208         $ret = $c->search('uid 1:*') or BAIL_OUT "SEARCH FAIL $@";
 209         is_deeply($ret, [ 1 ], 'search UID 1:* works after compression');
 210 }
 211
 212 ok($mic->logout, 'logout works');
 213
 214 my $have_inotify = eval { require Linux::Inotify2; 1 };
 215
 216 my $pi_config = PublicInbox::Config->new;
 217 $pi_config->each_inbox(sub {
 218         my ($ibx) = @_;
 219         my $env = { ORIGINAL_RECIPIENT => $ibx->{-primary_address} };
 220         my $name = $ibx->{name};
 221         my $ng = $ibx->{newsgroup};
 222         my $mic = $imap_client->new(%mic_opt);
 223         ok($mic && $mic->login && $mic->IsAuthenticated, "authed $name");
 224         my $mb = "$ng.$first_range";
 225         my $uidnext = $mic->uidnext($mb); # we'll fetch BODYSTRUCTURE on this
 226         ok($uidnext, 'got uidnext for later fetch');
 227         is_deeply([$mic->has_capability('IDLE')], ['IDLE'], "IDLE capa $name");
 228         ok(!$mic->idle, "IDLE fails w/o SELECT/EXAMINE $name");
 229         ok($mic->examine($mb), "EXAMINE $ng succeeds");
 230         ok(my $idle_tag = $mic->idle, "IDLE succeeds on $ng");
 231
 232         open(my $fh, '<', 't/data/message_embed.eml') or BAIL_OUT("open: $!");
 233         run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or
 234                 BAIL_OUT('-mda delivery');
 235         my $t0 = Time::HiRes::time();
 236         ok(my @res = $mic->idle_data(11), "IDLE succeeds on $ng");
 237         is(grep(/\A\* [0-9] EXISTS\b/, @res), 1, 'got EXISTS message');
 238         ok((Time::HiRes::time() - $t0) < 10, 'IDLE client notified');
 239
 240         my (@ino_info, $ino_fdinfo);
 241         SKIP: {
 242                 skip 'no inotify support', 1 unless $have_inotify;
 243                 skip 'missing /proc/$PID/fd', 1 if !-d "/proc/$td->{pid}/fd";
 244                 my @ino = grep {
 245                         readlink($_) =~ /\binotify\b/
 246                 } glob("/proc/$td->{pid}/fd/*");
 247                 is(scalar(@ino), 1, 'only one inotify FD');
 248                 my $ino_fd = (split('/', $ino[0]))[-1];
 249                 $ino_fdinfo = "/proc/$td->{pid}/fdinfo/$ino_fd";
 250                 if (open my $fh, '<', $ino_fdinfo) {
 251                         local $/ = "\n";
 252                         @ino_info = grep(/^inotify wd:/, <$fh>);
 253                         ok(scalar(@ino_info), 'inotify has watches');
 254                 } else {
 255                         skip "$ino_fdinfo missing: $!", 1;
 256                 }
 257         };
 258
 259         # ensure IDLE persists across HUP, w/o extra watches or FDs
 260         $td->kill('HUP') or BAIL_OUT "failed to kill -imapd: $!";
 261         SKIP: {
 262                 skip 'no inotify fdinfo (or support)', 2 if !@ino_info;
 263                 my (@tmp, %prev);
 264                 local $/ = "\n";
 265                 my $end = time + 5;
 266                 until (time > $end) {
 267                         select undef, undef, undef, 0.01;
 268                         open my $fh, '<', $ino_fdinfo or
 269                                                 BAIL_OUT "$ino_fdinfo: $!";
 270                         %prev = map { $_ => 1 } @ino_info;
 271                         @tmp = grep(/^inotify wd:/, <$fh>);
 272                         if (scalar(@tmp) == scalar(@ino_info)) {
 273                                 delete @prev{@tmp};
 274                                 last if scalar(keys(%prev)) == @ino_info;
 275                         }
 276                 }
 277                 is(scalar @tmp, scalar @ino_info,
 278                         'old inotify watches replaced');
 279                 is(scalar keys %prev, scalar @ino_info,
 280                         'no previous watches overlap');
 281         };
 282
 283         open($fh, '<', 't/data/0001.patch') or BAIL_OUT("open: $!");
 284         run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or
 285                 BAIL_OUT('-mda delivery');
 286         $t0 = Time::HiRes::time();
 287         ok(@res = $mic->idle_data(11), "IDLE succeeds on $ng after HUP");
 288         is(grep(/\A\* [0-9] EXISTS\b/, @res), 1, 'got EXISTS message');
 289         ok((Time::HiRes::time() - $t0) < 10, 'IDLE client notified');
 290         ok($mic->done($idle_tag), 'IDLE DONE');
 291         my $bs = $mic->get_bodystructure($uidnext);
 292         ok($bs, 'BODYSTRUCTURE ok for deeply nested');
 293         $ret = $mic->fetch_hash($uidnext, 'BODY') or BAIL_OUT "FETCH $@";
 294         ok($ret->{$uidnext}->{BODY}, 'got something in BODY');
 295
 296         # this matches dovecot behavior
 297         $ret = $mic->fetch_hash($uidnext, 'BODY[1]') or BAIL_OUT "FETCH $@";
 298         is($ret->{$uidnext}->{'BODY[1]'},
 299                 "testing embedded message harder\r\n", 'BODY[1]');
 300         $ret = $mic->fetch_hash($uidnext, 'BODY[2]') or BAIL_OUT "FETCH $@";
 301         like($ret->{$uidnext}->{'BODY[2]'},
 302                 qr/\ADate: Sat, 18 Apr 2020 22:20:20 /, 'BODY[2]');
 303
 304         $ret = $mic->fetch_hash($uidnext, 'BODY[2.1.1]') or BAIL_OUT "FETCH $@";
 305         is($ret->{$uidnext}->{'BODY[2.1.1]'},
 306                 "testing embedded message\r\n", 'BODY[2.1.1]');
 307
 308         $ret = $mic->fetch_hash($uidnext, 'BODY[2.1.2]') or BAIL_OUT "FETCH $@";
 309         like($ret->{$uidnext}->{'BODY[2.1.2]'}, qr/\AFrom: /,
 310                 'BODY[2.1.2] tip matched');
 311         like($ret->{$uidnext}->{'BODY[2.1.2]'},
 312                  # trailing CRLF may vary depending on MIME parser
 313                  qr/done_testing;(?:\r\n){1,2}\z/,
 314                 'BODY[2.1.2] tail matched');
 315
 316         $ret = $mic->fetch_hash("1:$uidnext", 'BODY[2.HEADER]') or
 317                                                 BAIL_OUT "2.HEADER $@";
 318         like($ret->{$uidnext}->{'BODY[2.HEADER]'},
 319                 qr/\ADate: Sat, 18 Apr 2020 22:20:20 /,
 320                 '2.HEADER of message/rfc822');
 321
 322         $ret = $mic->fetch_hash($uidnext, 'BODY[2.MIME]') or
 323                 BAIL_OUT "2.MIME $@";
 324         is($ret->{$uidnext}->{'BODY[2.MIME]'}, <<EOF, 'BODY[2.MIME]');
 325 Content-Type: message/rfc822\r
 326 Content-Disposition: attachment; filename="embed2x\.eml"\r
 327 \r
 328 EOF
 329 }); # each_inbox
 330
 331 # message sequence numbers :<
 332 is($mic->Uid(0), 0, 'disable UID on '.ref($mic));
 333 ok($mic->reconnect, 'reconnected');
 334 $ret = $mic->fetch_hash('1,2:3', 'RFC822') or BAIL_OUT "FETCH $@";
 335 is(scalar keys %$ret, 3, 'got all 3 messages with comma-separated sequence');
 336 $ret = $mic->fetch_hash('1:*', 'RFC822') or BAIL_OUT "FETCH $@";
 337 is(scalar keys %$ret, 3, 'got all 3 messages');
 338 {
 339         my $rdr = { 0 => \($ret->{1}->{RFC822}) };
 340         my $env = { HOME => $ENV{HOME} };
 341         my @cmd = qw(-learn rm --all);
 342         run_script(\@cmd, $env, $rdr) or BAIL_OUT('-learn rm');
 343 }
 344 my $r2 = $mic->fetch_hash('1:*', 'BODY.PEEK[]') or BAIL_OUT "FETCH $@";
 345 is(scalar keys %$r2, 3, 'still got all 3 messages');
 346 like($r2->{1}->{'BODY[]'}, qr/dummy message #1/, 'got dummy message 1');
 347 is($r2->{2}->{'BODY[]'}, $ret->{2}->{RFC822}, 'message 2 unchanged');
 348 is($r2->{3}->{'BODY[]'}, $ret->{3}->{RFC822}, 'message 3 unchanged');
 349 $r2 = $mic->fetch_hash(2, 'BODY.PEEK[HEADER.FIELDS (message-id)]')
 350                         or BAIL_OUT "FETCH $@";
 351 is($r2->{2}->{'BODY[HEADER.FIELDS (MESSAGE-ID)]'},
 352         'Message-ID: <20200418222508.GA13918@dcvr>'."\r\n\r\n",
 353         'BODY.PEEK[HEADER.FIELDS ...] drops .PEEK');
 354 ok($mic->close, 'CLOSE works');
 355 ok(!$mic->close, 'CLOSE not idempotent');
 356 ok($mic->logout, 'logged out');
 357
 358 $td->kill;
 359 $td->join;
 360 is($?, 0, 'no error in exited process');
 361 open my $fh, '<', $err or BAIL_OUT("open $err failed: $!");
 362 my $eout = do { local $/; <$fh> };
 363 unlike($eout, qr/wide/i, 'no Wide character warnings');
 364
 365 done_testing;