t/imapd.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # end-to-end IMAP tests, see unit tests in t/imap.t, too
   5 use strict;
   6 use Test::More;
   7 use Time::HiRes ();
   8 use PublicInbox::TestCommon;
   9 use PublicInbox::Config;
  10 use PublicInbox::Spawn qw(which);
  11 require_mods(qw(DBD::SQLite Mail::IMAPClient Mail::IMAPClient::BodyStructure
  12         Email::Address::XS||Mail::Address));
  13 my $imap_client = 'Mail::IMAPClient';
  14 my $can_compress = $imap_client->can('compress');
  15 if ($can_compress) { # hope this gets fixed upstream, soon
  16         require PublicInbox::IMAPClient;
  17         $imap_client = 'PublicInbox::IMAPClient';
  18 }
  19
  20 require_ok 'PublicInbox::IMAP';
  21 my $first_range = '0';
  22
  23 my $level = 'basic';
  24 SKIP: {
  25         require_mods('Search::Xapian', 1);
  26         $level = 'medium';
  27 };
  28
  29 my @V = (1);
  30 push(@V, 2) if require_git('2.6', 1);
  31
  32 my ($tmpdir, $for_destroy) = tmpdir();
  33 my $home = "$tmpdir/home";
  34 local $ENV{HOME} = $home;
  35
  36 for my $V (@V) {
  37         my $addr = "i$V\@example.com";
  38         my $name = "i$V";
  39         my $url = "http://example.com/i$V";
  40         my $inboxdir = "$tmpdir/$name";
  41         my $folder = "inbox.i$V";
  42         my $cmd = ['-init', "-V$V", "-L$level", $name, $inboxdir, $url, $addr];
  43         run_script($cmd) or BAIL_OUT("init $name");
  44         xsys(qw(git config), "--file=$ENV{HOME}/.public-inbox/config",
  45                         "publicinbox.$name.newsgroup", $folder) == 0 or
  46                         BAIL_OUT("setting newsgroup $V");
  47         if ($V == 1) {
  48                 xsys(qw(git config), "--file=$ENV{HOME}/.public-inbox/config",
  49                         'publicinboxmda.spamcheck', 'none') == 0 or
  50                         BAIL_OUT("config: $?");
  51         }
  52         open(my $fh, '<', 't/utf8.eml') or BAIL_OUT("open t/utf8.eml: $!");
  53         my $env = { ORIGINAL_RECIPIENT => $addr };
  54         run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or
  55                 BAIL_OUT('-mda delivery');
  56         if ($V == 1) {
  57                 run_script(['-index', $inboxdir]) or BAIL_OUT("index $?");
  58         }
  59 }
  60 my $sock = tcp_server();
  61 my $err = "$tmpdir/stderr.log";
  62 my $out = "$tmpdir/stdout.log";
  63 my $cmd = [ '-imapd', '-W0', "--stdout=$out", "--stderr=$err" ];
  64 my $td = start_script($cmd, undef, { 3 => $sock }) or BAIL_OUT("-imapd: $?");
  65 my %mic_opt = (
  66         Server => $sock->sockhost,
  67         Port => $sock->sockport,
  68         Uid => 1,
  69 );
  70 my $mic = $imap_client->new(%mic_opt);
  71 my $pre_login_capa = $mic->capability;
  72 is(grep(/\AAUTH=ANONYMOUS\z/, @$pre_login_capa), 1,
  73         'AUTH=ANONYMOUS advertised pre-login');
  74
  75 $mic->User('lorelei');
  76 $mic->Password('Hunter2');
  77 ok($mic->login && $mic->IsAuthenticated, 'LOGIN works');
  78 my $post_login_capa = $mic->capability;
  79 ok(join("\n", @$pre_login_capa) ne join("\n", @$post_login_capa),
  80         'got different capabilities post-login');
  81
  82 $mic_opt{Authmechanism} = 'ANONYMOUS';
  83 $mic_opt{Authcallback} = sub { '' };
  84 $mic = $imap_client->new(%mic_opt);
  85 ok($mic && $mic->login && $mic->IsAuthenticated, 'AUTHENTICATE ANONYMOUS');
  86 my $post_auth_anon_capa = $mic->capability;
  87 is_deeply($post_auth_anon_capa, $post_login_capa,
  88         'auth anon has same capabilities');
  89 my $e;
  90 ok(!$mic->examine('foo') && ($e = $@), 'EXAMINE non-existent');
  91 like($e, qr/\bNO\b/, 'got a NO on EXAMINE for non-existent');
  92 ok(!$mic->select('foo') && ($e = $@), 'EXAMINE non-existent');
  93 like($e, qr/\bNO\b/, 'got a NO on EXAMINE for non-existent');
  94 my $mailbox1 = "inbox.i1.$first_range";
  95 ok($mic->select('inbox.i1'), 'SELECT on parent succeeds');
  96 ok($mic->select($mailbox1), 'SELECT succeeds');
  97 ok($mic->examine($mailbox1), 'EXAMINE succeeds');
  98 my @raw = $mic->status($mailbox1, qw(Messages uidnext uidvalidity));
  99 is(scalar(@raw), 2, 'got status response');
 100 like($raw[0], qr/\A\*\x20STATUS\x20inbox\.i1\.$first_range\x20
 101         \(MESSAGES\x20\d+\x20UIDNEXT\x20\d+\x20UIDVALIDITY\x20\d+\)\r\n/sx);
 102 like($raw[1], qr/\A\S+ OK /, 'finished status response');
 103
 104 my @orig_list = @raw = $mic->list;
 105 like($raw[0], qr/^\* LIST \(.*?\) "\." INBOX/,
 106         'got an inbox');
 107 like($raw[-1], qr/^\S+ OK /, 'response ended with OK');
 108 is(scalar(@raw), scalar(@V) + 4, 'default LIST response');
 109 @raw = $mic->list('', 'inbox.i1');
 110 is(scalar(@raw), 2, 'limited LIST response');
 111 like($raw[0], qr/^\* LIST \(.*?\) "\." INBOX/,
 112                 'got an inbox.i1');
 113 like($raw[-1], qr/^\S+ OK /, 'response ended with OK');
 114
 115 my $ret = $mic->search('all') or BAIL_OUT "SEARCH FAIL $@";
 116 is_deeply($ret, [ 1 ], 'search all works');
 117 $ret = $mic->search('uid 1') or BAIL_OUT "SEARCH FAIL $@";
 118 is_deeply($ret, [ 1 ], 'search UID 1 works');
 119 $ret = $mic->search('uid 1:1') or BAIL_OUT "SEARCH FAIL $@";
 120 is_deeply($ret, [ 1 ], 'search UID 1:1 works');
 121 $ret = $mic->search('uid 1:*') or BAIL_OUT "SEARCH FAIL $@";
 122 is_deeply($ret, [ 1 ], 'search UID 1:* works');
 123
 124 SKIP: {
 125         skip 'Xapian missing', 6 if $level eq 'basic';
 126         my $x = $mic->search(qw(smaller 99999));
 127         is_deeply($x, [1], 'SMALLER works with Xapian (hit)');
 128         $x = $mic->search(qw(smaller 9));
 129         is_deeply($x, [], 'SMALLER works with Xapian (miss)');
 130
 131         $x = $mic->search(qw(larger 99999));
 132         is_deeply($x, [], 'LARGER works with Xapian (miss)');
 133         $x = $mic->search(qw(larger 9));
 134         is_deeply($x, [1], 'LARGER works with Xapian (hit)');
 135
 136         $x = $mic->search(qw(HEADER Message-ID testmessage@example.com));
 137         is_deeply($x, [1], 'HEADER Message-ID works');
 138         $x = $mic->search(qw(HEADER Message-ID miss));
 139         is_deeply($x, [], 'HEADER Message-ID can miss');
 140 }
 141
 142 is_deeply(scalar $mic->flags('1'), [], '->flags works');
 143 {
 144         # RFC 3501 section 6.4.8 states:
 145         # Also note that a UID range of 559:* always includes the
 146         # UID of the last message in the mailbox, even if 559 is
 147         # higher than any assigned UID value.
 148         my $exp = $mic->fetch_hash(1, 'UID');
 149         $ret = $mic->fetch_hash('559:*', 'UID');
 150         is_deeply($ret, $exp, 'beginning range too big');
 151         for my $r (qw(559:558 558:559)) {
 152                 $ret = $mic->fetch_hash($r, 'UID');
 153                 is_deeply($ret, {}, "out-of-range UID FETCH $r");
 154         }
 155 }
 156
 157 for my $r ('1:*', '1') {
 158         $ret = $mic->fetch_hash($r, 'RFC822') or BAIL_OUT "FETCH $@";
 159         is_deeply([keys %$ret], [1]);
 160         like($ret->{1}->{RFC822}, qr/\r\n\r\nThis is a test/, 'read full');
 161
 162         # ensure Mail::IMAPClient behaves
 163         my $str = $mic->message_string($r) or BAIL_OUT "->message_string: $@";
 164         is($str, $ret->{1}->{RFC822}, '->message_string works as expected');
 165
 166         my $sz = $mic->fetch_hash($r, 'RFC822.size') or BAIL_OUT "FETCH $@";
 167         is($sz->{1}->{'RFC822.SIZE'}, length($ret->{1}->{RFC822}),
 168                 'RFC822.SIZE');
 169
 170         $ret = $mic->fetch_hash($r, 'RFC822.HEADER') or BAIL_OUT "FETCH $@";
 171         is_deeply([keys %$ret], [1]);
 172         like($ret->{1}->{'RFC822.HEADER'},
 173                 qr/^Message-ID: <testmessage\@example\.com>/ms, 'read header');
 174
 175         $ret = $mic->fetch_hash($r, 'INTERNALDATE') or BAIL_OUT "FETCH $@";
 176         is($ret->{1}->{'INTERNALDATE'}, '01-Jan-1970 00:00:00 +0000',
 177                 'internaldate matches');
 178         ok(!$mic->fetch_hash($r, 'INFERNALDATE'), 'bogus attribute fails');
 179
 180         my $envelope = $mic->get_envelope($r) or BAIL_OUT("get_envelope: $@");
 181         is($envelope->{bcc}, 'NIL', 'empty bcc');
 182         is($envelope->{messageid}, '<testmessage@example.com>', 'messageid');
 183         is(scalar @{$envelope->{to}}, 1, 'one {to} header');
 184         # *sigh* too much to verify...
 185         #use Data::Dumper; diag Dumper($envelope);
 186
 187         $ret = $mic->fetch_hash($r, 'FLAGS') or BAIL_OUT "FETCH $@";
 188         is_deeply($ret->{1}->{FLAGS}, '', 'no flags');
 189
 190         $ret = $mic->fetch_hash($r, 'BODY[1]') or BAIL_OUT "FETCH $@";
 191         like($ret->{1}->{'BODY[1]'}, qr/\AThis is a test message/, 'BODY[1]');
 192
 193         $ret = $mic->fetch_hash($r, 'BODY[1]<1>') or BAIL_OUT "FETCH $@";
 194         like($ret->{1}->{'BODY[1]<1>'}, qr/\Ahis is a test message/,
 195                         'BODY[1]<1>');
 196
 197         $ret = $mic->fetch_hash($r, 'BODY[1]<2.3>') or BAIL_OUT "FETCH $@";
 198         is($ret->{1}->{'BODY[1]<2>'}, "is ", 'BODY[1]<2.3>');
 199         $ret = $mic->bodypart_string($r, 1, 3, 2) or
 200                                         BAIL_OUT "bodypart_string $@";
 201         is($ret, "is ", 'bodypart string');
 202
 203         $ret = $mic->fetch_hash($r, 'BODY[HEADER.FIELDS.NOT (Message-ID)]')
 204                 or BAIL_OUT "FETCH $@";
 205         $ret = $ret->{1}->{'BODY[HEADER.FIELDS.NOT (MESSAGE-ID)]'};
 206         unlike($ret, qr/message-id/i, 'Message-ID excluded');
 207         like($ret, qr/\r\n\r\n\z/s, 'got header end');
 208
 209         $ret = $mic->fetch_hash($r, 'BODY[HEADER.FIELDS (Message-ID)]')
 210                 or BAIL_OUT "FETCH $@";
 211         is($ret->{1}->{'BODY[HEADER.FIELDS (MESSAGE-ID)]'},
 212                 'Message-ID: <testmessage@example.com>'."\r\n\r\n",
 213                 'got only Message-ID');
 214
 215         my $bs = $mic->get_bodystructure($r) or BAIL_OUT("bodystructure: $@");
 216         ok($bs, 'got a bodystructure');
 217         is(lc($bs->bodytype), 'text', '->bodytype');
 218         is(lc($bs->bodyenc), '8bit', '->bodyenc');
 219 }
 220
 221 is_deeply([$mic->has_capability('COMPRESS')], ['DEFLATE'], 'deflate cap');
 222 SKIP: {
 223         skip 'Mail::IMAPClient too old for ->compress', 2 if !$can_compress;
 224         my $c = $imap_client->new(%mic_opt);
 225         ok($c && $c->compress, 'compress enabled');
 226         ok($c->examine($mailbox1), 'EXAMINE succeeds after COMPRESS');
 227         $ret = $c->search('uid 1:*') or BAIL_OUT "SEARCH FAIL $@";
 228         is_deeply($ret, [ 1 ], 'search UID 1:* works after compression');
 229 }
 230
 231 ok($mic->logout, 'logout works');
 232
 233 my $have_inotify = eval { require Linux::Inotify2; 1 };
 234
 235 my $pi_config = PublicInbox::Config->new;
 236 $pi_config->each_inbox(sub {
 237         my ($ibx) = @_;
 238         my $env = { ORIGINAL_RECIPIENT => $ibx->{-primary_address} };
 239         my $name = $ibx->{name};
 240         my $ng = $ibx->{newsgroup};
 241         my $mic = $imap_client->new(%mic_opt);
 242         ok($mic && $mic->login && $mic->IsAuthenticated, "authed $name");
 243         my $mb = "$ng.$first_range";
 244         my $uidnext = $mic->uidnext($mb); # we'll fetch BODYSTRUCTURE on this
 245         ok($uidnext, 'got uidnext for later fetch');
 246         is_deeply([$mic->has_capability('IDLE')], ['IDLE'], "IDLE capa $name");
 247         ok(!$mic->idle, "IDLE fails w/o SELECT/EXAMINE $name");
 248         ok($mic->examine($mb), "EXAMINE $ng succeeds");
 249         ok(my $idle_tag = $mic->idle, "IDLE succeeds on $ng");
 250
 251         open(my $fh, '<', 't/data/message_embed.eml') or BAIL_OUT("open: $!");
 252         run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or
 253                 BAIL_OUT('-mda delivery');
 254         my $t0 = Time::HiRes::time();
 255         ok(my @res = $mic->idle_data(11), "IDLE succeeds on $ng");
 256         is(grep(/\A\* [0-9] EXISTS\b/, @res), 1, 'got EXISTS message');
 257         ok((Time::HiRes::time() - $t0) < 10, 'IDLE client notified');
 258
 259         my (@ino_info, $ino_fdinfo);
 260         SKIP: {
 261                 skip 'no inotify support', 1 unless $have_inotify;
 262                 skip 'missing /proc/$PID/fd', 1 if !-d "/proc/$td->{pid}/fd";
 263                 my @ino = grep {
 264                         readlink($_) =~ /\binotify\b/
 265                 } glob("/proc/$td->{pid}/fd/*");
 266                 is(scalar(@ino), 1, 'only one inotify FD');
 267                 my $ino_fd = (split('/', $ino[0]))[-1];
 268                 $ino_fdinfo = "/proc/$td->{pid}/fdinfo/$ino_fd";
 269                 if (open my $fh, '<', $ino_fdinfo) {
 270                         local $/ = "\n";
 271                         @ino_info = grep(/^inotify wd:/, <$fh>);
 272                         ok(scalar(@ino_info), 'inotify has watches');
 273                 } else {
 274                         skip "$ino_fdinfo missing: $!", 1;
 275                 }
 276         };
 277
 278         # ensure IDLE persists across HUP, w/o extra watches or FDs
 279         $td->kill('HUP') or BAIL_OUT "failed to kill -imapd: $!";
 280         SKIP: {
 281                 skip 'no inotify fdinfo (or support)', 2 if !@ino_info;
 282                 my (@tmp, %prev);
 283                 local $/ = "\n";
 284                 my $end = time + 5;
 285                 until (time > $end) {
 286                         select undef, undef, undef, 0.01;
 287                         open my $fh, '<', $ino_fdinfo or
 288                                                 BAIL_OUT "$ino_fdinfo: $!";
 289                         %prev = map { $_ => 1 } @ino_info;
 290                         @tmp = grep(/^inotify wd:/, <$fh>);
 291                         if (scalar(@tmp) == scalar(@ino_info)) {
 292                                 delete @prev{@tmp};
 293                                 last if scalar(keys(%prev)) == @ino_info;
 294                         }
 295                 }
 296                 is(scalar @tmp, scalar @ino_info,
 297                         'old inotify watches replaced');
 298                 is(scalar keys %prev, scalar @ino_info,
 299                         'no previous watches overlap');
 300         };
 301
 302         open($fh, '<', 't/data/0001.patch') or BAIL_OUT("open: $!");
 303         run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or
 304                 BAIL_OUT('-mda delivery');
 305         $t0 = Time::HiRes::time();
 306         ok(@res = $mic->idle_data(11), "IDLE succeeds on $ng after HUP");
 307         is(grep(/\A\* [0-9] EXISTS\b/, @res), 1, 'got EXISTS message');
 308         ok((Time::HiRes::time() - $t0) < 10, 'IDLE client notified');
 309         ok($mic->done($idle_tag), 'IDLE DONE');
 310         my $bs = $mic->get_bodystructure($uidnext);
 311         ok($bs, 'BODYSTRUCTURE ok for deeply nested');
 312         $ret = $mic->fetch_hash($uidnext, 'BODY') or BAIL_OUT "FETCH $@";
 313         ok($ret->{$uidnext}->{BODY}, 'got something in BODY');
 314
 315         # this matches dovecot behavior
 316         $ret = $mic->fetch_hash($uidnext, 'BODY[1]') or BAIL_OUT "FETCH $@";
 317         is($ret->{$uidnext}->{'BODY[1]'},
 318                 "testing embedded message harder\r\n", 'BODY[1]');
 319         $ret = $mic->fetch_hash($uidnext, 'BODY[2]') or BAIL_OUT "FETCH $@";
 320         like($ret->{$uidnext}->{'BODY[2]'},
 321                 qr/\ADate: Sat, 18 Apr 2020 22:20:20 /, 'BODY[2]');
 322
 323         $ret = $mic->fetch_hash($uidnext, 'BODY[2.1.1]') or BAIL_OUT "FETCH $@";
 324         is($ret->{$uidnext}->{'BODY[2.1.1]'},
 325                 "testing embedded message\r\n", 'BODY[2.1.1]');
 326
 327         $ret = $mic->fetch_hash($uidnext, 'BODY[2.1.2]') or BAIL_OUT "FETCH $@";
 328         like($ret->{$uidnext}->{'BODY[2.1.2]'}, qr/\AFrom: /,
 329                 'BODY[2.1.2] tip matched');
 330         like($ret->{$uidnext}->{'BODY[2.1.2]'},
 331                  # trailing CRLF may vary depending on MIME parser
 332                  qr/done_testing;(?:\r\n){1,2}\z/,
 333                 'BODY[2.1.2] tail matched');
 334
 335         $ret = $mic->fetch_hash("1:$uidnext", 'BODY[2.HEADER]') or
 336                                                 BAIL_OUT "2.HEADER $@";
 337         like($ret->{$uidnext}->{'BODY[2.HEADER]'},
 338                 qr/\ADate: Sat, 18 Apr 2020 22:20:20 /,
 339                 '2.HEADER of message/rfc822');
 340
 341         $ret = $mic->fetch_hash($uidnext, 'BODY[2.MIME]') or
 342                 BAIL_OUT "2.MIME $@";
 343         is($ret->{$uidnext}->{'BODY[2.MIME]'}, <<EOF, 'BODY[2.MIME]');
 344 Content-Type: message/rfc822\r
 345 Content-Disposition: attachment; filename="embed2x\.eml"\r
 346 \r
 347 EOF
 348
 349         my @hits = $mic->search('SENTON' => '18-Apr-2020');
 350         is_deeply(\@hits, [ $uidnext ], 'search with date condition works');
 351         ok($mic->examine($ng), 'EXAMINE on dummy');
 352         @hits = $mic->search('SENTSINCE' => '18-Apr-2020');
 353         is_deeply(\@hits, [], 'search on dummy with condition works');
 354 }); # each_inbox
 355
 356 # message sequence numbers :<
 357 is($mic->Uid(0), 0, 'disable UID on '.ref($mic));
 358 ok($mic->reconnect, 'reconnected');
 359 $ret = $mic->fetch_hash('1,2:3', 'RFC822') or BAIL_OUT "FETCH $@";
 360 is(scalar keys %$ret, 3, 'got all 3 messages with comma-separated sequence');
 361 $ret = $mic->fetch_hash('1:*', 'RFC822') or BAIL_OUT "FETCH $@";
 362 is(scalar keys %$ret, 3, 'got all 3 messages');
 363
 364 {
 365         my @new_list = $mic->list;
 366         # tag differs in [-1]
 367         like($orig_list[-1], qr/\A\S+ OK List done\r\n/, 'orig LIST');
 368         like($new_list[-1], qr/\A\S+ OK List done\r\n/, 'new LIST');
 369         pop @new_list;
 370         pop @orig_list;
 371         # TODO: not sure if sort order matters, imapd_refresh_finalize
 372         # doesn't sort, hopefully clients don't care...
 373         @new_list = sort @new_list;
 374         @orig_list = sort @orig_list;
 375         is_deeply(\@new_list, \@orig_list, 'LIST identical');
 376 }
 377 ok($mic->close, 'CLOSE works');
 378 ok(!$mic->close, 'CLOSE not idempotent');
 379 ok($mic->logout, 'logged out');
 380
 381 {
 382         my $c = tcp_connect($sock);
 383         $c->autoflush(1);
 384         like(<$c>, qr/\* OK/, 'got a greeting');
 385         print $c "\r\n";
 386         like(<$c>, qr/\A\* BAD Error in IMAP command/, 'empty line');
 387         print $c "tagonly\r\n";
 388         like(<$c>, qr/\Atagonly BAD Error in IMAP command/, 'tag-only line');
 389 }
 390
 391 $td->kill;
 392 $td->join;
 393 is($?, 0, 'no error in exited process');
 394 open my $fh, '<', $err or BAIL_OUT("open $err failed: $!");
 395 my $eout = do { local $/; <$fh> };
 396 unlike($eout, qr/wide/i, 'no Wide character warnings');
 397 unlike($eout, qr/uninitialized/i, 'no uninitialized warnings');
 398
 399 done_testing;