t/imapd.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # end-to-end IMAP tests, see unit tests in t/imap.t, too
   5 use strict;
   6 use Test::More;
   7 use Time::HiRes ();
   8 use PublicInbox::TestCommon;
   9 use PublicInbox::Config;
  10 use PublicInbox::Spawn qw(which);
  11 require_mods(qw(DBD::SQLite Mail::IMAPClient Mail::IMAPClient::BodyStructure
  12         Email::Address::XS||Mail::Address));
  13 my $imap_client = 'Mail::IMAPClient';
  14 my $can_compress = $imap_client->can('compress');
  15 if ($can_compress) { # hope this gets fixed upstream, soon
  16         require PublicInbox::IMAPClient;
  17         $imap_client = 'PublicInbox::IMAPClient';
  18 }
  19
  20 require_ok 'PublicInbox::IMAP';
  21 my $first_range = '0';
  22
  23 my $level = 'basic';
  24 SKIP: {
  25         require_mods('Search::Xapian', 1);
  26         $level = 'medium';
  27 };
  28
  29 my @V = (1);
  30 push(@V, 2) if require_git('2.6', 1);
  31
  32 my ($tmpdir, $for_destroy) = tmpdir();
  33 my $home = "$tmpdir/home";
  34 local $ENV{HOME} = $home;
  35
  36 for my $V (@V) {
  37         my $addr = "i$V\@example.com";
  38         my $name = "i$V";
  39         my $url = "http://example.com/i$V";
  40         my $inboxdir = "$tmpdir/$name";
  41         my $folder = "inbox.i$V";
  42         my $cmd = ['-init', "-V$V", "-L$level", $name, $inboxdir, $url, $addr];
  43         run_script($cmd) or BAIL_OUT("init $name");
  44         xsys(qw(git config), "--file=$ENV{HOME}/.public-inbox/config",
  45                         "publicinbox.$name.newsgroup", $folder) == 0 or
  46                         BAIL_OUT("setting newsgroup $V");
  47         if ($V == 1) {
  48                 xsys(qw(git config), "--file=$ENV{HOME}/.public-inbox/config",
  49                         'publicinboxmda.spamcheck', 'none') == 0 or
  50                         BAIL_OUT("config: $?");
  51         }
  52         open(my $fh, '<', 't/utf8.eml') or BAIL_OUT("open t/utf8.eml: $!");
  53         my $env = { ORIGINAL_RECIPIENT => $addr };
  54         run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or
  55                 BAIL_OUT('-mda delivery');
  56         if ($V == 1) {
  57                 run_script(['-index', $inboxdir]) or BAIL_OUT("index $?");
  58         }
  59 }
  60 my $sock = tcp_server();
  61 my $err = "$tmpdir/stderr.log";
  62 my $out = "$tmpdir/stdout.log";
  63 my $cmd = [ '-imapd', '-W0', "--stdout=$out", "--stderr=$err" ];
  64 my $td = start_script($cmd, undef, { 3 => $sock }) or BAIL_OUT("-imapd: $?");
  65 my %mic_opt = (
  66         Server => $sock->sockhost,
  67         Port => $sock->sockport,
  68         Uid => 1,
  69 );
  70 my $mic = $imap_client->new(%mic_opt);
  71 my $pre_login_capa = $mic->capability;
  72 is(grep(/\AAUTH=ANONYMOUS\z/, @$pre_login_capa), 1,
  73         'AUTH=ANONYMOUS advertised pre-login');
  74
  75 $mic->User('lorelei');
  76 $mic->Password('Hunter2');
  77 ok($mic->login && $mic->IsAuthenticated, 'LOGIN works');
  78 my $post_login_capa = $mic->capability;
  79 ok(join("\n", @$pre_login_capa) ne join("\n", @$post_login_capa),
  80         'got different capabilities post-login');
  81
  82 $mic_opt{Authmechanism} = 'ANONYMOUS';
  83 $mic_opt{Authcallback} = sub { '' };
  84 $mic = $imap_client->new(%mic_opt);
  85 ok($mic && $mic->login && $mic->IsAuthenticated, 'AUTHENTICATE ANONYMOUS');
  86 my $post_auth_anon_capa = $mic->capability;
  87 is_deeply($post_auth_anon_capa, $post_login_capa,
  88         'auth anon has same capabilities');
  89 my $e;
  90 ok(!$mic->examine('foo') && ($e = $@), 'EXAMINE non-existent');
  91 like($e, qr/\bNO\b/, 'got a NO on EXAMINE for non-existent');
  92 ok(!$mic->select('foo') && ($e = $@), 'EXAMINE non-existent');
  93 like($e, qr/\bNO\b/, 'got a NO on EXAMINE for non-existent');
  94 my $mailbox1 = "inbox.i1.$first_range";
  95 ok($mic->select('inbox.i1'), 'SELECT on parent succeeds');
  96 ok($mic->select($mailbox1), 'SELECT succeeds');
  97 ok($mic->examine($mailbox1), 'EXAMINE succeeds');
  98 my @raw = $mic->status($mailbox1, qw(Messages uidnext uidvalidity));
  99 is(scalar(@raw), 2, 'got status response');
 100 like($raw[0], qr/\A\*\x20STATUS\x20inbox\.i1\.$first_range\x20
 101         \(MESSAGES\x20\d+\x20UIDNEXT\x20\d+\x20UIDVALIDITY\x20\d+\)\r\n/sx);
 102 like($raw[1], qr/\A\S+ OK /, 'finished status response');
 103
 104 my @orig_list = @raw = $mic->list;
 105 like($raw[0], qr/^\* LIST \(.*?\) "\." INBOX/,
 106         'got an inbox');
 107 like($raw[-1], qr/^\S+ OK /, 'response ended with OK');
 108 is(scalar(@raw), scalar(@V) + 4, 'default LIST response');
 109 @raw = $mic->list('', 'inbox.i1');
 110 is(scalar(@raw), 2, 'limited LIST response');
 111 like($raw[0], qr/^\* LIST \(.*?\) "\." INBOX/,
 112                 'got an inbox.i1');
 113 like($raw[-1], qr/^\S+ OK /, 'response ended with OK');
 114
 115 my $ret = $mic->search('all') or BAIL_OUT "SEARCH FAIL $@";
 116 is_deeply($ret, [ 1 ], 'search all works');
 117 $ret = $mic->search('uid 1') or BAIL_OUT "SEARCH FAIL $@";
 118 is_deeply($ret, [ 1 ], 'search UID 1 works');
 119 $ret = $mic->search('uid 1:1') or BAIL_OUT "SEARCH FAIL $@";
 120 is_deeply($ret, [ 1 ], 'search UID 1:1 works');
 121 $ret = $mic->search('uid 1:*') or BAIL_OUT "SEARCH FAIL $@";
 122 is_deeply($ret, [ 1 ], 'search UID 1:* works');
 123
 124 SKIP: {
 125         skip 'Xapian missing', 6 if $level eq 'basic';
 126         my $x = $mic->search(qw(smaller 99999));
 127         is_deeply($x, [1], 'SMALLER works with Xapian (hit)');
 128         $x = $mic->search(qw(smaller 9));
 129         is_deeply($x, [], 'SMALLER works with Xapian (miss)');
 130
 131         $x = $mic->search(qw(larger 99999));
 132         is_deeply($x, [], 'LARGER works with Xapian (miss)');
 133         $x = $mic->search(qw(larger 9));
 134         is_deeply($x, [1], 'LARGER works with Xapian (hit)');
 135
 136         $x = $mic->search(qw(HEADER Message-ID testmessage@example.com));
 137         is_deeply($x, [1], 'HEADER Message-ID works');
 138         $x = $mic->search(qw(HEADER Message-ID miss));
 139         is_deeply($x, [], 'HEADER Message-ID can miss');
 140 }
 141
 142 is_deeply(scalar $mic->flags('1'), [], '->flags works');
 143 {
 144         # RFC 3501 section 6.4.8 states:
 145         # Also note that a UID range of 559:* always includes the
 146         # UID of the last message in the mailbox, even if 559 is
 147         # higher than any assigned UID value.
 148         my $exp = $mic->fetch_hash(1, 'UID');
 149         $ret = $mic->fetch_hash('559:*', 'UID');
 150         is_deeply($ret, $exp, 'beginning range too big');
 151         {
 152                 my @w; # Mail::IMAPClient hits a warning via overload
 153                 local $SIG{__WARN__} = sub { push @w, @_ };
 154                 $ret = $mic->fetch_hash(my $r = '559:558', 'UID');
 155                 is_deeply($ret, {}, "out-of-range UID FETCH $r");
 156                 @w = grep(!/\boverload\.pm\b/, @w);
 157                 is_deeply(\@w, [], 'no unexpected warning');
 158         }
 159         $ret = $mic->fetch_hash(my $r = '558:559', 'UID');
 160         is_deeply($ret, {}, "out-of-range UID FETCH $r");
 161 }
 162
 163 for my $r ('1:*', '1') {
 164         $ret = $mic->fetch_hash($r, 'RFC822') or BAIL_OUT "FETCH $@";
 165         is_deeply([keys %$ret], [1]);
 166         like($ret->{1}->{RFC822}, qr/\r\n\r\nThis is a test/, 'read full');
 167
 168         # ensure Mail::IMAPClient behaves
 169         my $str = $mic->message_string($r) or BAIL_OUT "->message_string: $@";
 170         is($str, $ret->{1}->{RFC822}, '->message_string works as expected');
 171
 172         my $sz = $mic->fetch_hash($r, 'RFC822.size') or BAIL_OUT "FETCH $@";
 173         is($sz->{1}->{'RFC822.SIZE'}, length($ret->{1}->{RFC822}),
 174                 'RFC822.SIZE');
 175
 176         $ret = $mic->fetch_hash($r, 'RFC822.HEADER') or BAIL_OUT "FETCH $@";
 177         is_deeply([keys %$ret], [1]);
 178         like($ret->{1}->{'RFC822.HEADER'},
 179                 qr/^Message-ID: <testmessage\@example\.com>/ms, 'read header');
 180
 181         $ret = $mic->fetch_hash($r, 'INTERNALDATE') or BAIL_OUT "FETCH $@";
 182         is($ret->{1}->{'INTERNALDATE'}, '01-Jan-1970 00:00:00 +0000',
 183                 'internaldate matches');
 184         ok(!$mic->fetch_hash($r, 'INFERNALDATE'), 'bogus attribute fails');
 185
 186         my $envelope = $mic->get_envelope($r) or BAIL_OUT("get_envelope: $@");
 187         is($envelope->{bcc}, 'NIL', 'empty bcc');
 188         is($envelope->{messageid}, '<testmessage@example.com>', 'messageid');
 189         is(scalar @{$envelope->{to}}, 1, 'one {to} header');
 190         # *sigh* too much to verify...
 191         #use Data::Dumper; diag Dumper($envelope);
 192
 193         $ret = $mic->fetch_hash($r, 'FLAGS') or BAIL_OUT "FETCH $@";
 194         is_deeply($ret->{1}->{FLAGS}, '', 'no flags');
 195
 196         $ret = $mic->fetch_hash($r, 'BODY[1]') or BAIL_OUT "FETCH $@";
 197         like($ret->{1}->{'BODY[1]'}, qr/\AThis is a test message/, 'BODY[1]');
 198
 199         $ret = $mic->fetch_hash($r, 'BODY[1]<1>') or BAIL_OUT "FETCH $@";
 200         like($ret->{1}->{'BODY[1]<1>'}, qr/\Ahis is a test message/,
 201                         'BODY[1]<1>');
 202
 203         $ret = $mic->fetch_hash($r, 'BODY[1]<2.3>') or BAIL_OUT "FETCH $@";
 204         is($ret->{1}->{'BODY[1]<2>'}, "is ", 'BODY[1]<2.3>');
 205         $ret = $mic->bodypart_string($r, 1, 3, 2) or
 206                                         BAIL_OUT "bodypart_string $@";
 207         is($ret, "is ", 'bodypart string');
 208
 209         $ret = $mic->fetch_hash($r, 'BODY[HEADER.FIELDS.NOT (Message-ID)]')
 210                 or BAIL_OUT "FETCH $@";
 211         $ret = $ret->{1}->{'BODY[HEADER.FIELDS.NOT (MESSAGE-ID)]'};
 212         unlike($ret, qr/message-id/i, 'Message-ID excluded');
 213         like($ret, qr/\r\n\r\n\z/s, 'got header end');
 214
 215         $ret = $mic->fetch_hash($r, 'BODY[HEADER.FIELDS (Message-ID)]')
 216                 or BAIL_OUT "FETCH $@";
 217         is($ret->{1}->{'BODY[HEADER.FIELDS (MESSAGE-ID)]'},
 218                 'Message-ID: <testmessage@example.com>'."\r\n\r\n",
 219                 'got only Message-ID');
 220
 221         my $bs = $mic->get_bodystructure($r) or BAIL_OUT("bodystructure: $@");
 222         ok($bs, 'got a bodystructure');
 223         is(lc($bs->bodytype), 'text', '->bodytype');
 224         is(lc($bs->bodyenc), '8bit', '->bodyenc');
 225 }
 226 ok($mic->has_capability('COMPRESS') ||
 227         $mic->has_capability('COMPRESS=DEFLATE'), 'deflate cap');
 228 SKIP: {
 229         skip 'Mail::IMAPClient too old for ->compress', 2 if !$can_compress;
 230         my $c = $imap_client->new(%mic_opt);
 231         ok($c && $c->compress, 'compress enabled');
 232         ok($c->examine($mailbox1), 'EXAMINE succeeds after COMPRESS');
 233         $ret = $c->search('uid 1:*') or BAIL_OUT "SEARCH FAIL $@";
 234         is_deeply($ret, [ 1 ], 'search UID 1:* works after compression');
 235 }
 236
 237 ok($mic->logout, 'logout works');
 238
 239 my $have_inotify = eval { require Linux::Inotify2; 1 };
 240
 241 my $pi_config = PublicInbox::Config->new;
 242 $pi_config->each_inbox(sub {
 243         my ($ibx) = @_;
 244         my $env = { ORIGINAL_RECIPIENT => $ibx->{-primary_address} };
 245         my $name = $ibx->{name};
 246         my $ng = $ibx->{newsgroup};
 247         my $mic = $imap_client->new(%mic_opt);
 248         ok($mic && $mic->login && $mic->IsAuthenticated, "authed $name");
 249         my $mb = "$ng.$first_range";
 250         my $uidnext = $mic->uidnext($mb); # we'll fetch BODYSTRUCTURE on this
 251         ok($uidnext, 'got uidnext for later fetch');
 252         ok($mic->has_capability('IDLE'), "IDLE capa $name");
 253         ok(!$mic->idle, "IDLE fails w/o SELECT/EXAMINE $name");
 254         ok($mic->examine($mb), "EXAMINE $ng succeeds");
 255         ok(my $idle_tag = $mic->idle, "IDLE succeeds on $ng");
 256
 257         open(my $fh, '<', 't/data/message_embed.eml') or BAIL_OUT("open: $!");
 258         run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or
 259                 BAIL_OUT('-mda delivery');
 260         my $t0 = Time::HiRes::time();
 261         ok(my @res = $mic->idle_data(11), "IDLE succeeds on $ng");
 262         is(grep(/\A\* [0-9] EXISTS\b/, @res), 1, 'got EXISTS message');
 263         ok((Time::HiRes::time() - $t0) < 10, 'IDLE client notified');
 264
 265         my (@ino_info, $ino_fdinfo);
 266         SKIP: {
 267                 skip 'no inotify support', 1 unless $have_inotify;
 268                 skip 'missing /proc/$PID/fd', 1 if !-d "/proc/$td->{pid}/fd";
 269                 my @ino = grep {
 270                         readlink($_) =~ /\binotify\b/
 271                 } glob("/proc/$td->{pid}/fd/*");
 272                 is(scalar(@ino), 1, 'only one inotify FD');
 273                 my $ino_fd = (split('/', $ino[0]))[-1];
 274                 $ino_fdinfo = "/proc/$td->{pid}/fdinfo/$ino_fd";
 275                 if (open my $fh, '<', $ino_fdinfo) {
 276                         local $/ = "\n";
 277                         @ino_info = grep(/^inotify wd:/, <$fh>);
 278                         ok(scalar(@ino_info), 'inotify has watches');
 279                 } else {
 280                         skip "$ino_fdinfo missing: $!", 1;
 281                 }
 282         };
 283
 284         # ensure IDLE persists across HUP, w/o extra watches or FDs
 285         $td->kill('HUP') or BAIL_OUT "failed to kill -imapd: $!";
 286         SKIP: {
 287                 skip 'no inotify fdinfo (or support)', 2 if !@ino_info;
 288                 my (@tmp, %prev);
 289                 local $/ = "\n";
 290                 my $end = time + 5;
 291                 until (time > $end) {
 292                         select undef, undef, undef, 0.01;
 293                         open my $fh, '<', $ino_fdinfo or
 294                                                 BAIL_OUT "$ino_fdinfo: $!";
 295                         %prev = map { $_ => 1 } @ino_info;
 296                         @tmp = grep(/^inotify wd:/, <$fh>);
 297                         if (scalar(@tmp) == scalar(@ino_info)) {
 298                                 delete @prev{@tmp};
 299                                 last if scalar(keys(%prev)) == @ino_info;
 300                         }
 301                 }
 302                 is(scalar @tmp, scalar @ino_info,
 303                         'old inotify watches replaced');
 304                 is(scalar keys %prev, scalar @ino_info,
 305                         'no previous watches overlap');
 306         };
 307
 308         open($fh, '<', 't/data/0001.patch') or BAIL_OUT("open: $!");
 309         run_script(['-mda', '--no-precheck'], $env, { 0 => $fh }) or
 310                 BAIL_OUT('-mda delivery');
 311         $t0 = Time::HiRes::time();
 312         ok(@res = $mic->idle_data(11), "IDLE succeeds on $ng after HUP");
 313         is(grep(/\A\* [0-9] EXISTS\b/, @res), 1, 'got EXISTS message');
 314         ok((Time::HiRes::time() - $t0) < 10, 'IDLE client notified');
 315         ok($mic->done($idle_tag), 'IDLE DONE');
 316         my $bs = $mic->get_bodystructure($uidnext);
 317         ok($bs, 'BODYSTRUCTURE ok for deeply nested');
 318         $ret = $mic->fetch_hash($uidnext, 'BODY') or BAIL_OUT "FETCH $@";
 319         ok($ret->{$uidnext}->{BODY}, 'got something in BODY');
 320
 321         # this matches dovecot behavior
 322         $ret = $mic->fetch_hash($uidnext, 'BODY[1]') or BAIL_OUT "FETCH $@";
 323         is($ret->{$uidnext}->{'BODY[1]'},
 324                 "testing embedded message harder\r\n", 'BODY[1]');
 325         $ret = $mic->fetch_hash($uidnext, 'BODY[2]') or BAIL_OUT "FETCH $@";
 326         like($ret->{$uidnext}->{'BODY[2]'},
 327                 qr/\ADate: Sat, 18 Apr 2020 22:20:20 /, 'BODY[2]');
 328
 329         $ret = $mic->fetch_hash($uidnext, 'BODY[2.1.1]') or BAIL_OUT "FETCH $@";
 330         is($ret->{$uidnext}->{'BODY[2.1.1]'},
 331                 "testing embedded message\r\n", 'BODY[2.1.1]');
 332
 333         $ret = $mic->fetch_hash($uidnext, 'BODY[2.1.2]') or BAIL_OUT "FETCH $@";
 334         like($ret->{$uidnext}->{'BODY[2.1.2]'}, qr/\AFrom: /,
 335                 'BODY[2.1.2] tip matched');
 336         like($ret->{$uidnext}->{'BODY[2.1.2]'},
 337                  # trailing CRLF may vary depending on MIME parser
 338                  qr/done_testing;(?:\r\n){1,2}\z/,
 339                 'BODY[2.1.2] tail matched');
 340
 341         $ret = $mic->fetch_hash("1:$uidnext", 'BODY[2.HEADER]') or
 342                                                 BAIL_OUT "2.HEADER $@";
 343         like($ret->{$uidnext}->{'BODY[2.HEADER]'},
 344                 qr/\ADate: Sat, 18 Apr 2020 22:20:20 /,
 345                 '2.HEADER of message/rfc822');
 346
 347         $ret = $mic->fetch_hash($uidnext, 'BODY[2.MIME]') or
 348                 BAIL_OUT "2.MIME $@";
 349         is($ret->{$uidnext}->{'BODY[2.MIME]'}, <<EOF, 'BODY[2.MIME]');
 350 Content-Type: message/rfc822\r
 351 Content-Disposition: attachment; filename="embed2x\.eml"\r
 352 \r
 353 EOF
 354
 355         my @hits = $mic->search('SENTON' => '18-Apr-2020');
 356         is_deeply(\@hits, [ $uidnext ], 'search with date condition works');
 357         ok($mic->examine($ng), 'EXAMINE on dummy');
 358         @hits = $mic->search('SENTSINCE' => '18-Apr-2020');
 359         is_deeply(\@hits, [], 'search on dummy with condition works');
 360 }); # each_inbox
 361
 362 # message sequence numbers :<
 363 is($mic->Uid(0), 0, 'disable UID on '.ref($mic));
 364 ok($mic->reconnect, 'reconnected');
 365 $ret = $mic->fetch_hash('1,2:3', 'RFC822') or BAIL_OUT "FETCH $@";
 366 is(scalar keys %$ret, 3, 'got all 3 messages with comma-separated sequence');
 367 $ret = $mic->fetch_hash('1:*', 'RFC822') or BAIL_OUT "FETCH $@";
 368 is(scalar keys %$ret, 3, 'got all 3 messages');
 369
 370 SKIP: {
 371         # do any clients use non-UID IMAP SEARCH?
 372         skip 'Xapian missing', 2 if $level eq 'basic';
 373         my $x = $mic->search('all');
 374         is_deeply($x, [1, 2, 3], 'MSN SEARCH works before rm');
 375         $x = $mic->search(qw(header subject embedded));
 376         is_deeply($x, [2], 'MSN SEARCH on Subject works before rm');
 377 }
 378
 379 {
 380         my $rdr = { 0 => \($ret->{1}->{RFC822}) };
 381         my $env = { HOME => $ENV{HOME} };
 382         my @cmd = qw(-learn rm --all);
 383         run_script(\@cmd, $env, $rdr) or BAIL_OUT('-learn rm');
 384 }
 385
 386 SKIP: {
 387         # do any clients use non-UID IMAP SEARCH?  We only ensure
 388         # MSN "SEARCH" can return a result which can be retrieved
 389         # via MSN "FETCH"
 390         skip 'Xapian missing', 3 if $level eq 'basic';
 391         my $x = $mic->search(qw(header subject embedded));
 392         is(scalar(@$x), 1, 'MSN SEARCH on Subject works after rm');
 393         $x = $mic->message_string($x->[0]);
 394         is($x, $ret->{2}->{RFC822}, 'message 2 unchanged');
 395 }
 396
 397 # FIXME? no EXPUNGE response, yet
 398 my $r2 = $mic->fetch_hash('1:*', 'BODY.PEEK[]') or BAIL_OUT "FETCH $@";
 399 is(scalar keys %$r2, 2, 'did not get all 3 messages');
 400 is($r2->{2}->{'BODY[]'}, $ret->{2}->{RFC822}, 'message 2 unchanged');
 401 is($r2->{3}->{'BODY[]'}, $ret->{3}->{RFC822}, 'message 3 unchanged');
 402 $r2 = $mic->fetch_hash(2, 'BODY.PEEK[HEADER.FIELDS (message-id)]')
 403                         or BAIL_OUT "FETCH $@";
 404 is($r2->{2}->{'BODY[HEADER.FIELDS (MESSAGE-ID)]'},
 405         'Message-ID: <20200418222508.GA13918@dcvr>'."\r\n\r\n",
 406         'BODY.PEEK[HEADER.FIELDS ...] drops .PEEK');
 407
 408 {
 409         my @new_list = $mic->list;
 410         # tag differs in [-1]
 411         like($orig_list[-1], qr/\A\S+ OK List done\r\n/, 'orig LIST');
 412         like($new_list[-1], qr/\A\S+ OK List done\r\n/, 'new LIST');
 413         pop @new_list;
 414         pop @orig_list;
 415         # TODO: not sure if sort order matters, imapd_refresh_finalize
 416         # doesn't sort, hopefully clients don't care...
 417         @new_list = sort @new_list;
 418         @orig_list = sort @orig_list;
 419         is_deeply(\@new_list, \@orig_list, 'LIST identical');
 420 }
 421 ok($mic->close, 'CLOSE works');
 422 ok(!$mic->close, 'CLOSE not idempotent');
 423 ok($mic->logout, 'logged out');
 424
 425 {
 426         my $c = tcp_connect($sock);
 427         $c->autoflush(1);
 428         like(<$c>, qr/\* OK/, 'got a greeting');
 429         print $c "\r\n";
 430         like(<$c>, qr/\A\* BAD Error in IMAP command/, 'empty line');
 431         print $c "tagonly\r\n";
 432         like(<$c>, qr/\Atagonly BAD Error in IMAP command/, 'tag-only line');
 433 }
 434
 435 $td->kill;
 436 $td->join;
 437 is($?, 0, 'no error in exited process');
 438 open my $fh, '<', $err or BAIL_OUT("open $err failed: $!");
 439 my $eout = do { local $/; <$fh> };
 440 unlike($eout, qr/wide/i, 'no Wide character warnings');
 441 unlike($eout, qr/uninitialized/i, 'no uninitialized warnings');
 442
 443 done_testing;