t/inbox_idle.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use Test::More;
   5 use PublicInbox::TestCommon;
   6 use PublicInbox::Config;
   7 require_git 2.6;
   8 require_mods(qw(DBD::SQLite));
   9 require PublicInbox::SearchIdx;
  10 use_ok 'PublicInbox::InboxIdle';
  11 use PublicInbox::InboxWritable;
  12 my ($tmpdir, $for_destroy) = tmpdir();
  13
  14 for my $V (1, 2) {
  15         my $inboxdir = "$tmpdir/$V";
  16         mkdir $inboxdir or BAIL_OUT("mkdir: $!");
  17         my %opt = (
  18                 inboxdir => $inboxdir,
  19                 name => 'inbox-idle',
  20                 version => $V,
  21                 -primary_address => 'test@example.com',
  22                 indexlevel => 'basic',
  23         );
  24         my $ibx = PublicInbox::Inbox->new({ %opt });
  25         $ibx = PublicInbox::InboxWritable->new($ibx);
  26         my $obj = InboxIdleTestObj->new;
  27         $ibx->init_inbox(0);
  28         my $im = $ibx->importer(0);
  29         if ($V == 1) {
  30                 my $sidx = PublicInbox::SearchIdx->new($ibx, 1);
  31                 $sidx->idx_acquire;
  32                 $sidx->set_metadata_once;
  33                 $sidx->idx_release; # allow watching on lockfile
  34         }
  35         my $pi_cfg = PublicInbox::Config->new(\<<EOF);
  36 publicinbox.inbox-idle.inboxdir=$inboxdir
  37 publicinbox.inbox-idle.indexlevel=basic
  38 publicinbox.inbox-idle.address=test\@example.com
  39 EOF
  40         my $ident = 'whatever';
  41         $pi_cfg->each_inbox(sub { shift->subscribe_unlock($ident, $obj) });
  42         my $ii = PublicInbox::InboxIdle->new($pi_cfg);
  43         ok($ii, 'InboxIdle created');
  44         SKIP: {
  45                 skip('inotify or kqueue missing', 1) unless $ii->{sock};
  46                 ok(fileno($ii->{sock}) >= 0, 'fileno() gave valid FD');
  47         }
  48         ok($im->add(eml_load('t/utf8.eml')), "$V added");
  49         $im->done;
  50         PublicInbox::SearchIdx->new($ibx)->index_sync if $V == 1;
  51         $ii->event_step;
  52         is(scalar @{$obj->{called}}, 1, 'called on unlock');
  53         $pi_cfg->each_inbox(sub { shift->unsubscribe_unlock($ident) });
  54         ok($im->add(eml_load('t/data/0001.patch')), "$V added #2");
  55         $im->done;
  56         PublicInbox::SearchIdx->new($ibx)->index_sync if $V == 1;
  57         $ii->event_step;
  58         is(scalar @{$obj->{called}}, 1, 'not called when unsubbed');
  59         $ii->close;
  60 }
  61
  62 done_testing;
  63
  64 package InboxIdleTestObj;
  65 use strict;
  66
  67 sub new { bless {}, shift }
  68
  69 sub on_inbox_unlock {
  70         my ($self, $ibx) = @_;
  71         push @{$self->{called}}, $ibx;
  72 }