t/indexlevels-mirror.t

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::Inbox;
   8 use PublicInbox::InboxWritable;
   9 require PublicInbox::Admin;
  10 require './t/common.perl';
  11 my $PI_TEST_VERSION = $ENV{PI_TEST_VERSION} || 2;
  12 require_git('2.6') if $PI_TEST_VERSION == 2;
  13
  14 foreach my $mod (qw(DBD::SQLite)) {
  15         eval "require $mod";
  16         plan skip_all => "$mod missing for $0" if $@;
  17 }
  18
  19 my @xcpdb = qw(-xcpdb -q);
  20
  21 my $mime = PublicInbox::MIME->create(
  22         header => [
  23                 From => 'a@example.com',
  24                 To => 'test@example.com',
  25                 Subject => 'this is a subject',
  26                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  27         ],
  28         body => "hello world\n",
  29 );
  30
  31 sub import_index_incremental {
  32         my ($v, $level) = @_;
  33         my $this = "pi-$v-$level-indexlevels";
  34         my ($tmpdir, $for_destroy) = tmpdir();
  35         my $ibx = PublicInbox::Inbox->new({
  36                 inboxdir => "$tmpdir/testbox",
  37                 name => $this,
  38                 version => $v,
  39                 -primary_address => 'test@example.com',
  40                 indexlevel => $level,
  41         });
  42         my $im = PublicInbox::InboxWritable->new($ibx, {nproc=>1})->importer;
  43         $mime->header_set('Message-ID', '<m@1>');
  44         ok($im->add($mime), 'first message added');
  45         $im->done;
  46
  47         # index master (required for v1)
  48         ok(run_script(['-index', $ibx->{inboxdir}, "-L$level"]),
  49                 'index master OK');
  50         my $ro_master = PublicInbox::Inbox->new({
  51                 inboxdir => $ibx->{inboxdir},
  52                 indexlevel => $level
  53         });
  54         my ($nr, $msgs) = $ro_master->recent;
  55         is($nr, 1, 'only one message in master, so far');
  56         is($msgs->[0]->{mid}, 'm@1', 'first message in master indexed');
  57
  58         # clone
  59         my @cmd = (qw(git clone --mirror -q));
  60         my $mirror = "$tmpdir/mirror-$v";
  61         if ($v == 1) {
  62                 push @cmd, $ibx->{inboxdir}, $mirror;
  63         } else {
  64                 push @cmd, "$ibx->{inboxdir}/git/0.git", "$mirror/git/0.git";
  65         }
  66         my $fetch_dir = $cmd[-1];
  67         is(system(@cmd), 0, "v$v clone OK");
  68
  69         # inbox init
  70         local $ENV{PI_CONFIG} = "$tmpdir/.picfg";
  71         @cmd = ('-init', '-L', $level,
  72                 'mirror', $mirror, '//example.com/test', 'test@example.com');
  73         push @cmd, '-V2' if $v == 2;
  74         ok(run_script(\@cmd), "v$v init OK");
  75
  76         # index mirror
  77         ok(run_script(['-index', $mirror]), "v$v index mirror OK");
  78
  79         # read-only access
  80         my $ro_mirror = PublicInbox::Inbox->new({
  81                 inboxdir => $mirror,
  82                 indexlevel => $level,
  83         });
  84         ($nr, $msgs) = $ro_mirror->recent;
  85         is($nr, 1, 'only one message, so far');
  86         is($msgs->[0]->{mid}, 'm@1', 'read first message');
  87
  88         # update master
  89         $mime->header_set('Message-ID', '<m@2>');
  90         ok($im->add($mime), '2nd message added');
  91         $im->done;
  92
  93         # mirror updates
  94         is(system('git', "--git-dir=$fetch_dir", qw(fetch -q)), 0, 'fetch OK');
  95         ok(run_script(['-index', $mirror]), "v$v index mirror again OK");
  96         ($nr, $msgs) = $ro_mirror->recent;
  97         is($nr, 2, '2nd message seen in mirror');
  98         is_deeply([sort { $a cmp $b } map { $_->{mid} } @$msgs],
  99                 ['m@1','m@2'], 'got both messages in mirror');
 100
 101         # incremental index master (required for v1)
 102         ok(run_script(['-index', $ibx->{inboxdir}, "-L$level"]),
 103                 'index master OK');
 104         ($nr, $msgs) = $ro_master->recent;
 105         is($nr, 2, '2nd message seen in master');
 106         is_deeply([sort { $a cmp $b } map { $_->{mid} } @$msgs],
 107                 ['m@1','m@2'], 'got both messages in master');
 108
 109         my @rw_nums = map { $_->{num} } @{$ibx->over->query_ts(0, 0)};
 110         is_deeply(\@rw_nums, [1, 2], 'master has expected NNTP articles');
 111
 112         my @ro_nums = map { $_->{num} } @{$ro_mirror->over->query_ts(0, 0)};
 113         is_deeply(\@ro_nums, [1, 2], 'mirror has expected NNTP articles');
 114
 115         # remove message from master
 116         ok($im->remove($mime), '2nd message removed');
 117         $im->done;
 118         @rw_nums = map { $_->{num} } @{$ibx->over->query_ts(0, 0)};
 119         is_deeply(\@rw_nums, [1], 'unindex NNTP article'.$v.$level);
 120
 121         if ($level ne 'basic') {
 122                 ok(run_script([@xcpdb, $mirror]), "v$v xcpdb OK");
 123                 is(PublicInbox::Admin::detect_indexlevel($ro_mirror), $level,
 124                    'indexlevel detectable by Admin after xcpdb v' .$v.$level);
 125                 delete $ro_mirror->{$_} for (qw(over search));
 126                 ($nr, $msgs) = $ro_mirror->search->query('m:m@2');
 127                 is($nr, 1, "v$v found m\@2 via Xapian on $level");
 128         }
 129
 130         # sync the mirror
 131         is(system('git', "--git-dir=$fetch_dir", qw(fetch -q)), 0, 'fetch OK');
 132         ok(run_script(['-index', $mirror]), "v$v index mirror again OK");
 133         ($nr, $msgs) = $ro_mirror->recent;
 134         is($nr, 1, '2nd message gone from mirror');
 135         is_deeply([map { $_->{mid} } @$msgs], ['m@1'],
 136                 'message unavailable in mirror');
 137
 138         if ($v == 2 && $level eq 'basic') {
 139                 is_deeply([glob("$ibx->{inboxdir}/xap*/?/")], [],
 140                          'no Xapian shard directories for v2 basic');
 141         }
 142         if ($level ne 'basic') {
 143                 ($nr, $msgs) = $ro_mirror->search->reopen->query('m:m@2');
 144                 is($nr, 0, "v$v m\@2 gone from Xapian in mirror on $level");
 145         }
 146
 147         # add another message to master and have the mirror
 148         # sync and reindex it
 149         my @expect = map { $_->{num} } @{$ibx->over->query_ts(0, 0)};
 150         foreach my $i (3..5) {
 151                 $mime->header_set('Message-ID', "<m\@$i>");
 152                 ok($im->add($mime), "#$i message added");
 153                 push @expect, $i;
 154         }
 155         $im->done;
 156         is(system('git', "--git-dir=$fetch_dir", qw(fetch -q)), 0, 'fetch OK');
 157         ok(run_script(['-index', '--reindex', $mirror]),
 158                 "v$v index --reindex mirror OK");
 159         @ro_nums = map { $_->{num} } @{$ro_mirror->over->query_ts(0, 0)};
 160         @rw_nums = map { $_->{num} } @{$ibx->over->query_ts(0, 0)};
 161         is_deeply(\@rw_nums, \@expect, "v$v master has expected NNTP articles");
 162         is_deeply(\@ro_nums, \@expect, "v$v mirror matches master articles");
 163
 164         is(PublicInbox::Admin::detect_indexlevel($ro_mirror), $level,
 165            'indexlevel detectable by Admin '.$v.$level);
 166 }
 167
 168 # we can probably cull some other tests
 169 import_index_incremental($PI_TEST_VERSION, 'basic');
 170
 171 SKIP: {
 172         require PublicInbox::Search;
 173         PublicInbox::Search::load_xapian() or skip 'Search::Xapian missing', 2;
 174         foreach my $l (qw(medium full)) {
 175                 import_index_incremental($PI_TEST_VERSION, $l);
 176         }
 177 }
 178
 179 done_testing();