t/indexlevels-mirror.t

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::Inbox;
   8 use PublicInbox::InboxWritable;
   9 require PublicInbox::Admin;
  10 require './t/common.perl';
  11 my $PI_TEST_VERSION = $ENV{PI_TEST_VERSION} || 2;
  12 require_git('2.6') if $PI_TEST_VERSION == 2;
  13
  14 foreach my $mod (qw(DBD::SQLite)) {
  15         eval "require $mod";
  16         plan skip_all => "$mod missing for $0" if $@;
  17 }
  18
  19 my @xcpdb = qw(-xcpdb -q);
  20
  21 my $mime = PublicInbox::MIME->create(
  22         header => [
  23                 From => 'a@example.com',
  24                 To => 'test@example.com',
  25                 Subject => 'this is a subject',
  26                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  27         ],
  28         body => "hello world\n",
  29 );
  30
  31 sub import_index_incremental {
  32         my ($v, $level) = @_;
  33         my $this = "pi-$v-$level-indexlevels";
  34         my ($tmpdir, $for_destroy) = tmpdir();
  35         local $ENV{PI_CONFIG} = "$tmpdir/config";
  36         my $ibx = PublicInbox::Inbox->new({
  37                 inboxdir => "$tmpdir/testbox",
  38                 name => $this,
  39                 version => $v,
  40                 -primary_address => 'test@example.com',
  41                 indexlevel => $level,
  42         });
  43         my $im = PublicInbox::InboxWritable->new($ibx, {nproc=>1})->importer;
  44         $mime->header_set('Message-ID', '<m@1>');
  45         ok($im->add($mime), 'first message added');
  46         $im->done;
  47
  48         # index master (required for v1)
  49         ok(run_script(['-index', $ibx->{inboxdir}, "-L$level"]),
  50                 'index master OK');
  51         my $ro_master = PublicInbox::Inbox->new({
  52                 inboxdir => $ibx->{inboxdir},
  53                 indexlevel => $level
  54         });
  55         my ($nr, $msgs) = $ro_master->recent;
  56         is($nr, 1, 'only one message in master, so far');
  57         is($msgs->[0]->{mid}, 'm@1', 'first message in master indexed');
  58
  59         # clone
  60         my @cmd = (qw(git clone --mirror -q));
  61         my $mirror = "$tmpdir/mirror-$v";
  62         if ($v == 1) {
  63                 push @cmd, $ibx->{inboxdir}, $mirror;
  64         } else {
  65                 push @cmd, "$ibx->{inboxdir}/git/0.git", "$mirror/git/0.git";
  66         }
  67         my $fetch_dir = $cmd[-1];
  68         is(system(@cmd), 0, "v$v clone OK");
  69
  70         # inbox init
  71         local $ENV{PI_CONFIG} = "$tmpdir/.picfg";
  72         @cmd = ('-init', '-L', $level,
  73                 'mirror', $mirror, '//example.com/test', 'test@example.com');
  74         push @cmd, '-V2' if $v == 2;
  75         ok(run_script(\@cmd), "v$v init OK");
  76
  77         # index mirror
  78         ok(run_script(['-index', $mirror]), "v$v index mirror OK");
  79
  80         # read-only access
  81         my $ro_mirror = PublicInbox::Inbox->new({
  82                 inboxdir => $mirror,
  83                 indexlevel => $level,
  84         });
  85         ($nr, $msgs) = $ro_mirror->recent;
  86         is($nr, 1, 'only one message, so far');
  87         is($msgs->[0]->{mid}, 'm@1', 'read first message');
  88
  89         # update master
  90         $mime->header_set('Message-ID', '<m@2>');
  91         ok($im->add($mime), '2nd message added');
  92         $im->done;
  93
  94         # mirror updates
  95         is(system('git', "--git-dir=$fetch_dir", qw(fetch -q)), 0, 'fetch OK');
  96         ok(run_script(['-index', $mirror]), "v$v index mirror again OK");
  97         ($nr, $msgs) = $ro_mirror->recent;
  98         is($nr, 2, '2nd message seen in mirror');
  99         is_deeply([sort { $a cmp $b } map { $_->{mid} } @$msgs],
 100                 ['m@1','m@2'], 'got both messages in mirror');
 101
 102         # incremental index master (required for v1)
 103         ok(run_script(['-index', $ibx->{inboxdir}, "-L$level"]),
 104                 'index master OK');
 105         ($nr, $msgs) = $ro_master->recent;
 106         is($nr, 2, '2nd message seen in master');
 107         is_deeply([sort { $a cmp $b } map { $_->{mid} } @$msgs],
 108                 ['m@1','m@2'], 'got both messages in master');
 109
 110         my @rw_nums = map { $_->{num} } @{$ibx->over->query_ts(0, 0)};
 111         is_deeply(\@rw_nums, [1, 2], 'master has expected NNTP articles');
 112
 113         my @ro_nums = map { $_->{num} } @{$ro_mirror->over->query_ts(0, 0)};
 114         is_deeply(\@ro_nums, [1, 2], 'mirror has expected NNTP articles');
 115
 116         # remove message from master
 117         ok($im->remove($mime), '2nd message removed');
 118         $im->done;
 119         @rw_nums = map { $_->{num} } @{$ibx->over->query_ts(0, 0)};
 120         is_deeply(\@rw_nums, [1], 'unindex NNTP article'.$v.$level);
 121
 122         if ($level ne 'basic') {
 123                 ok(run_script([@xcpdb, $mirror]), "v$v xcpdb OK");
 124                 is(PublicInbox::Admin::detect_indexlevel($ro_mirror), $level,
 125                    'indexlevel detectable by Admin after xcpdb v' .$v.$level);
 126                 delete $ro_mirror->{$_} for (qw(over search));
 127                 ($nr, $msgs) = $ro_mirror->search->query('m:m@2');
 128                 is($nr, 1, "v$v found m\@2 via Xapian on $level");
 129         }
 130
 131         # sync the mirror
 132         is(system('git', "--git-dir=$fetch_dir", qw(fetch -q)), 0, 'fetch OK');
 133         ok(run_script(['-index', $mirror]), "v$v index mirror again OK");
 134         ($nr, $msgs) = $ro_mirror->recent;
 135         is($nr, 1, '2nd message gone from mirror');
 136         is_deeply([map { $_->{mid} } @$msgs], ['m@1'],
 137                 'message unavailable in mirror');
 138
 139         if ($v == 2 && $level eq 'basic') {
 140                 is_deeply([glob("$ibx->{inboxdir}/xap*/?/")], [],
 141                          'no Xapian shard directories for v2 basic');
 142         }
 143         if ($level ne 'basic') {
 144                 ($nr, $msgs) = $ro_mirror->search->reopen->query('m:m@2');
 145                 is($nr, 0, "v$v m\@2 gone from Xapian in mirror on $level");
 146         }
 147
 148         # add another message to master and have the mirror
 149         # sync and reindex it
 150         my @expect = map { $_->{num} } @{$ibx->over->query_ts(0, 0)};
 151         foreach my $i (3..5) {
 152                 $mime->header_set('Message-ID', "<m\@$i>");
 153                 ok($im->add($mime), "#$i message added");
 154                 push @expect, $i;
 155         }
 156         $im->done;
 157         is(system('git', "--git-dir=$fetch_dir", qw(fetch -q)), 0, 'fetch OK');
 158         ok(run_script(['-index', '--reindex', $mirror]),
 159                 "v$v index --reindex mirror OK");
 160         @ro_nums = map { $_->{num} } @{$ro_mirror->over->query_ts(0, 0)};
 161         @rw_nums = map { $_->{num} } @{$ibx->over->query_ts(0, 0)};
 162         is_deeply(\@rw_nums, \@expect, "v$v master has expected NNTP articles");
 163         is_deeply(\@ro_nums, \@expect, "v$v mirror matches master articles");
 164
 165         is(PublicInbox::Admin::detect_indexlevel($ro_mirror), $level,
 166            'indexlevel detectable by Admin '.$v.$level);
 167 }
 168
 169 # we can probably cull some other tests
 170 import_index_incremental($PI_TEST_VERSION, 'basic');
 171
 172 SKIP: {
 173         require PublicInbox::Search;
 174         PublicInbox::Search::load_xapian() or skip 'Search::Xapian missing', 2;
 175         foreach my $l (qw(medium full)) {
 176                 import_index_incremental($PI_TEST_VERSION, $l);
 177         }
 178 }
 179
 180 done_testing();