t/lei-convert.t

   1 #!perl -w
   2 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use PublicInbox::MboxReader;
   6 use PublicInbox::MdirReader;
   7 use PublicInbox::NetReader;
   8 require_git 2.6;
   9 require_mods(qw(DBD::SQLite Search::Xapian));
  10 my ($tmpdir, $for_destroy) = tmpdir;
  11 my $sock = tcp_server;
  12 my $cmd = [ '-imapd', '-W0', "--stdout=$tmpdir/1", "--stderr=$tmpdir/2" ];
  13 my ($ro_home, $cfg_path) = setup_public_inboxes;
  14 my $env = { PI_CONFIG => $cfg_path };
  15 my $td = start_script($cmd, $env, { 3 => $sock }) or BAIL_OUT("-imapd: $?");
  16 my $host_port = tcp_host_port($sock);
  17 undef $sock;
  18 test_lei({ tmpdir => $tmpdir }, sub {
  19         my $d = $ENV{HOME};
  20         my $dig = Digest::SHA->new(256);
  21         lei_ok('convert', '-o', "mboxrd:$d/foo.mboxrd",
  22                 "imap://$host_port/t.v2.0");
  23         ok(-f "$d/foo.mboxrd", 'mboxrd created');
  24         my (@mboxrd, @mboxcl2);
  25         open my $fh, '<', "$d/foo.mboxrd" or BAIL_OUT $!;
  26         PublicInbox::MboxReader->mboxrd($fh, sub { push @mboxrd, shift });
  27         ok(scalar(@mboxrd) > 1, 'got multiple messages');
  28
  29         lei_ok('convert', '-o', "mboxcl2:$d/cl2", "mboxrd:$d/foo.mboxrd");
  30         ok(-s "$d/cl2", 'mboxcl2 non-empty') or diag $lei_err;
  31         open $fh, '<', "$d/cl2" or BAIL_OUT $!;
  32         PublicInbox::MboxReader->mboxcl2($fh, sub {
  33                 my $eml = shift;
  34                 $eml->header_set($_) for (qw(Content-Length Lines));
  35                 push @mboxcl2, $eml;
  36         });
  37         is_deeply(\@mboxcl2, \@mboxrd, 'mboxrd and mboxcl2 have same mail');
  38
  39         lei_ok('convert', '-o', "$d/md", "mboxrd:$d/foo.mboxrd");
  40         ok(-d "$d/md", 'Maildir created');
  41         my @md;
  42         PublicInbox::MdirReader::maildir_each_eml("$d/md", sub {
  43                 push @md, $_[1];
  44         });
  45         is(scalar(@md), scalar(@mboxrd), 'got expected emails in Maildir');
  46         @md = sort { ${$a->{bdy}} cmp ${$b->{bdy}} } @md;
  47         @mboxrd = sort { ${$a->{bdy}} cmp ${$b->{bdy}} } @mboxrd;
  48         my @rd_nostatus = map {
  49                 my $eml = PublicInbox::Eml->new(\($_->as_string));
  50                 $eml->header_set('Status');
  51                 $eml;
  52         } @mboxrd;
  53         is_deeply(\@md, \@rd_nostatus, 'Maildir output matches mboxrd');
  54
  55         my @bar;
  56         lei_ok('convert', '-o', "mboxrd:$d/bar.mboxrd", "$d/md");
  57         open $fh, '<', "$d/bar.mboxrd" or BAIL_OUT $!;
  58         PublicInbox::MboxReader->mboxrd($fh, sub { push @bar, shift });
  59         @bar = sort { ${$a->{bdy}} cmp ${$b->{bdy}} } @bar;
  60         is_deeply(\@mboxrd, \@bar,
  61                         'mboxrd round-tripped through Maildir w/ flags');
  62
  63         open my $in, '<', "$d/foo.mboxrd" or BAIL_OUT;
  64         my $rdr = { 0 => $in, 1 => \(my $out), 2 => \$lei_err };
  65         lei_ok([qw(convert --stdin -F mboxrd -o mboxrd:/dev/stdout)],
  66                 undef, $rdr);
  67         open $fh, '<', "$d/foo.mboxrd" or BAIL_OUT;
  68         my $exp = do { local $/; <$fh> };
  69         is($out, $exp, 'stdin => stdout');
  70 });
  71 done_testing;