t/lei-daemon.t

   1 #!perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
   6
   7 test_lei({ daemon_only => 1 }, sub {
   8         my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
   9                 require PublicInbox::CmdIPC4;
  10                 PublicInbox::CmdIPC4->can('send_cmd4');
  11         } // do {
  12                 require PublicInbox::Syscall;
  13                 PublicInbox::Syscall->can('send_cmd4');
  14         };
  15         $send_cmd or BAIL_OUT 'started testing lei-daemon w/o send_cmd4!';
  16
  17         my $sock = "$ENV{XDG_RUNTIME_DIR}/lei/5.seq.sock";
  18         my $err_log = "$ENV{XDG_RUNTIME_DIR}/lei/errors.log";
  19         lei_ok('daemon-pid');
  20         ignore_inline_c_missing($lei_err);
  21         is($lei_err, '', 'no error from daemon-pid');
  22         like($lei_out, qr/\A[0-9]+\n\z/s, 'pid returned') or BAIL_OUT;
  23         chomp(my $pid = $lei_out);
  24         ok(kill(0, $pid), 'pid is valid');
  25         ok(-S $sock, 'sock created');
  26         is(-s $err_log, 0, 'nothing in errors.log');
  27         lei_ok('daemon-pid');
  28         chomp(my $pid_again = $lei_out);
  29         is($pid, $pid_again, 'daemon-pid idempotent');
  30
  31         SKIP: {
  32                 skip 'only testing open files on Linux', 1 if $^O ne 'linux';
  33                 my $d = "/proc/$pid/fd";
  34                 skip "no $d on Linux" unless -d $d;
  35                 my @before = sort(glob("$d/*"));
  36                 my $addr = pack_sockaddr_un($sock);
  37                 open my $null, '<', '/dev/null' or BAIL_OUT "/dev/null: $!";
  38                 my @fds = map { fileno($null) } (0..2);
  39                 for (0..10) {
  40                         socket(my $c, AF_UNIX, SOCK_SEQPACKET, 0) or
  41                                                         BAIL_OUT "socket: $!";
  42                         connect($c, $addr) or BAIL_OUT "connect: $!";
  43                         $send_cmd->($c, \@fds, 'hi',  MSG_EOR);
  44                 }
  45                 lei_ok('daemon-pid');
  46                 chomp($pid = $lei_out);
  47                 is($pid, $pid_again, 'pid unchanged after failed reqs');
  48                 my @after = sort(glob("$d/*"));
  49                 is_deeply(\@before, \@after, 'open files unchanged') or
  50                         diag explain([\@before, \@after]);;
  51         }
  52         lei_ok(qw(daemon-kill));
  53         is($lei_out, '', 'no output from daemon-kill');
  54         is($lei_err, '', 'no error from daemon-kill');
  55         for (0..100) {
  56                 kill(0, $pid) or last;
  57                 tick();
  58         }
  59         ok(-S $sock, 'sock still exists');
  60         ok(!kill(0, $pid), 'pid gone after stop');
  61
  62         lei_ok(qw(daemon-pid));
  63         chomp(my $new_pid = $lei_out);
  64         ok(kill(0, $new_pid), 'new pid is running');
  65         ok(-S $sock, 'sock still exists');
  66
  67         for my $sig (qw(-0 -CHLD)) {
  68                 lei_ok('daemon-kill', $sig, \"handles $sig");
  69         }
  70         is($lei_out.$lei_err, '', 'no output on innocuous signals');
  71         lei_ok('daemon-pid');
  72         chomp $lei_out;
  73         is($lei_out, $new_pid, 'PID unchanged after -0/-CHLD');
  74         unlink $sock or BAIL_OUT "unlink($sock) $!";
  75         for (0..100) {
  76                 kill('CHLD', $new_pid) or last;
  77                 tick();
  78         }
  79         ok(!kill(0, $new_pid), 'daemon exits after unlink');
  80 });
  81
  82 done_testing;