t/lei-daemon.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5
   6 test_lei({ daemon_only => 1 }, sub {
   7         my $sock = "$ENV{XDG_RUNTIME_DIR}/lei/5.seq.sock";
   8         my $err_log = "$ENV{XDG_RUNTIME_DIR}/lei/errors.log";
   9         lei_ok('daemon-pid');
  10         is($lei_err, '', 'no error from daemon-pid');
  11         like($lei_out, qr/\A[0-9]+\n\z/s, 'pid returned') or BAIL_OUT;
  12         chomp(my $pid = $lei_out);
  13         ok(kill(0, $pid), 'pid is valid');
  14         ok(-S $sock, 'sock created');
  15         is(-s $err_log, 0, 'nothing in errors.log');
  16         open my $efh, '>>', $err_log or BAIL_OUT $!;
  17         print $efh "phail\n" or BAIL_OUT $!;
  18         close $efh or BAIL_OUT $!;
  19
  20         lei_ok('daemon-pid');
  21         chomp(my $pid_again = $lei_out);
  22         is($pid, $pid_again, 'daemon-pid idempotent');
  23         like($lei_err, qr/phail/, 'got mock "phail" error previous run');
  24
  25         lei_ok(qw(daemon-kill));
  26         is($lei_out, '', 'no output from daemon-kill');
  27         is($lei_err, '', 'no error from daemon-kill');
  28         for (0..100) {
  29                 kill(0, $pid) or last;
  30                 tick();
  31         }
  32         ok(-S $sock, 'sock still exists');
  33         ok(!kill(0, $pid), 'pid gone after stop');
  34
  35         lei_ok(qw(daemon-pid));
  36         chomp(my $new_pid = $lei_out);
  37         ok(kill(0, $new_pid), 'new pid is running');
  38         ok(-S $sock, 'sock still exists');
  39
  40         for my $sig (qw(-0 -CHLD)) {
  41                 lei_ok('daemon-kill', $sig, \"handles $sig");
  42         }
  43         is($lei_out.$lei_err, '', 'no output on innocuous signals');
  44         lei_ok('daemon-pid');
  45         chomp $lei_out;
  46         is($lei_out, $new_pid, 'PID unchanged after -0/-CHLD');
  47
  48         if ('socket inaccessible') {
  49                 chmod 0000, $sock or BAIL_OUT "chmod 0000: $!";
  50                 lei_ok('help', \'connect fail, one-shot fallback works');
  51                 like($lei_err, qr/\bconnect\(/, 'connect error noted');
  52                 like($lei_out, qr/^usage: /, 'help output works');
  53                 chmod 0700, $sock or BAIL_OUT "chmod 0700: $!";
  54         }
  55         unlink $sock or BAIL_OUT "unlink($sock) $!";
  56         for (0..100) {
  57                 kill('CHLD', $new_pid) or last;
  58                 tick();
  59         }
  60         ok(!kill(0, $new_pid), 'daemon exits after unlink');
  61 });
  62
  63 done_testing;