t/lei-daemon.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
   6 use PublicInbox::Spawn qw(which);
   7
   8 test_lei({ daemon_only => 1 }, sub {
   9         my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
  10                 require PublicInbox::CmdIPC4;
  11                 PublicInbox::CmdIPC4->can('send_cmd4');
  12         };
  13         $send_cmd or BAIL_OUT 'started testing lei-daemon w/o send_cmd4!';
  14
  15         my $sock = "$ENV{XDG_RUNTIME_DIR}/lei/5.seq.sock";
  16         my $err_log = "$ENV{XDG_RUNTIME_DIR}/lei/errors.log";
  17         lei_ok('daemon-pid');
  18         is($lei_err, '', 'no error from daemon-pid');
  19         like($lei_out, qr/\A[0-9]+\n\z/s, 'pid returned') or BAIL_OUT;
  20         chomp(my $pid = $lei_out);
  21         ok(kill(0, $pid), 'pid is valid');
  22         ok(-S $sock, 'sock created');
  23         is(-s $err_log, 0, 'nothing in errors.log');
  24         open my $efh, '>>', $err_log or BAIL_OUT $!;
  25         print $efh "phail\n" or BAIL_OUT $!;
  26         close $efh or BAIL_OUT $!;
  27
  28         lei_ok('daemon-pid');
  29         chomp(my $pid_again = $lei_out);
  30         is($pid, $pid_again, 'daemon-pid idempotent');
  31         like($lei_err, qr/phail/, 'got mock "phail" error previous run');
  32
  33         SKIP: {
  34                 skip 'only testing open files on Linux', 1 if $^O ne 'linux';
  35                 my $d = "/proc/$pid/fd";
  36                 skip "no $d on Linux" unless -d $d;
  37                 my @before = sort(glob("$d/*"));
  38                 my $addr = pack_sockaddr_un($sock);
  39                 open my $null, '<', '/dev/null' or BAIL_OUT "/dev/null: $!";
  40                 my @fds = map { fileno($null) } (0..2);
  41                 for (0..10) {
  42                         socket(my $c, AF_UNIX, SOCK_SEQPACKET, 0) or
  43                                                         BAIL_OUT "socket: $!";
  44                         connect($c, $addr) or BAIL_OUT "connect: $!";
  45                         $send_cmd->($c, \@fds, 'hi',  MSG_EOR);
  46                 }
  47                 lei_ok('daemon-pid');
  48                 chomp($pid = $lei_out);
  49                 is($pid, $pid_again, 'pid unchanged after failed reqs');
  50                 my @after = sort(glob("$d/*"));
  51                 is_deeply(\@before, \@after, 'open files unchanged') or
  52                         diag explain([\@before, \@after]);;
  53         }
  54         lei_ok(qw(daemon-kill));
  55         is($lei_out, '', 'no output from daemon-kill');
  56         is($lei_err, '', 'no error from daemon-kill');
  57         for (0..100) {
  58                 kill(0, $pid) or last;
  59                 tick();
  60         }
  61         ok(-S $sock, 'sock still exists');
  62         ok(!kill(0, $pid), 'pid gone after stop');
  63
  64         lei_ok(qw(daemon-pid));
  65         chomp(my $new_pid = $lei_out);
  66         ok(kill(0, $new_pid), 'new pid is running');
  67         ok(-S $sock, 'sock still exists');
  68
  69         for my $sig (qw(-0 -CHLD)) {
  70                 lei_ok('daemon-kill', $sig, \"handles $sig");
  71         }
  72         is($lei_out.$lei_err, '', 'no output on innocuous signals');
  73         lei_ok('daemon-pid');
  74         chomp $lei_out;
  75         is($lei_out, $new_pid, 'PID unchanged after -0/-CHLD');
  76
  77         if ('socket inaccessible') {
  78                 chmod 0000, $sock or BAIL_OUT "chmod 0000: $!";
  79                 lei_ok('help', \'connect fail, one-shot fallback works');
  80                 like($lei_err, qr/\bconnect\(/, 'connect error noted');
  81                 like($lei_out, qr/^usage: /, 'help output works');
  82                 chmod 0700, $sock or BAIL_OUT "chmod 0700: $!";
  83         }
  84         unlink $sock or BAIL_OUT "unlink($sock) $!";
  85         for (0..100) {
  86                 kill('CHLD', $new_pid) or last;
  87                 tick();
  88         }
  89         ok(!kill(0, $new_pid), 'daemon exits after unlink');
  90 });
  91
  92 done_testing;