t/lei-externals.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use Fcntl qw(SEEK_SET);
   6 use PublicInbox::Spawn qw(which);
   7 require_git 2.6;
   8 require_mods(qw(json DBD::SQLite Search::Xapian));
   9 use POSIX qw(WTERMSIG WIFSIGNALED SIGPIPE);
  10
  11 my @onions = map { "http://$_.onion/meta/" } qw(
  12         4uok3hntl7oi7b4uf4rtfwefqeexfzil2w6kgk2jn5z2f764irre7byd
  13         ie5yzdi7fg72h7s4sdcztq5evakq23rdt33mfyfcddc5u3ndnw24ogqd
  14         7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd);
  15
  16 my $test_external_remote = sub {
  17         my ($url, $k) = @_;
  18 SKIP: {
  19         skip "$k unset", 1 if !$url;
  20         state $curl = which('curl');
  21         $curl or skip 'no curl', 1;
  22         which('torsocks') or skip 'no torsocks', 1 if $url =~ m!\.onion/!;
  23         my $mid = '20140421094015.GA8962@dcvr.yhbt.net';
  24         my @cmd = ('q', '--only', $url, '-q', "m:$mid");
  25         lei_ok(@cmd, \"query $url");
  26         is($lei_err, '', "no errors on $url");
  27         my $res = json_utf8->decode($lei_out);
  28         is($res->[0]->{'m'}, $mid, "got expected mid from $url") or
  29                 skip 'further remote tests', 1;
  30         lei_ok(@cmd, 'd:..20101002', \'no results, no error');
  31         is($lei_err, '', 'no output on 404, matching local FS behavior');
  32         is($lei_out, "[null]\n", 'got null results');
  33         my ($pid_before, $pid_after);
  34         if (-d $ENV{XDG_RUNTIME_DIR} && -w _) {
  35                 lei_ok 'daemon-pid';
  36                 chomp($pid_before = $lei_out);
  37                 ok($pid_before, 'daemon is live');
  38         }
  39         for my $out ([], [qw(-f mboxcl2)]) {
  40                 pipe(my ($r, $w)) or BAIL_OUT $!;
  41                 open my $err, '+>', undef or BAIL_OUT $!;
  42                 my $opt = { run_mode => 0, 1 => $w, 2 => $err };
  43                 my $cmd = [qw(lei q -qt), @$out, 'z:1..'];
  44                 my $tp = start_script($cmd, undef, $opt);
  45                 close $w;
  46                 sysread($r, my $buf, 1);
  47                 close $r; # trigger SIGPIPE
  48                 $tp->join;
  49                 ok(WIFSIGNALED($?), "signaled @$out");
  50                 is(WTERMSIG($?), SIGPIPE, "got SIGPIPE @$out");
  51                 seek($err, 0, 0);
  52                 my @err = <$err>;
  53                 is_deeply(\@err, [], "no errors @$out");
  54         }
  55         if (-d $ENV{XDG_RUNTIME_DIR} && -w _) {
  56                 lei_ok 'daemon-pid';
  57                 chomp(my $pid_after = $lei_out);
  58                 is($pid_after, $pid_before, 'pid unchanged') or
  59                         skip 'daemon died', 1;
  60                 skip 'not killing persistent lei-daemon', 2 if
  61                                 $ENV{TEST_LEI_DAEMON_PERSIST_DIR};
  62                 lei_ok 'daemon-kill';
  63                 my $alive = 1;
  64                 for (1..100) {
  65                         $alive = kill(0, $pid_after) or last;
  66                         tick();
  67                 }
  68                 ok(!$alive, 'daemon-kill worked');
  69         }
  70 } # /SKIP
  71 }; # /sub
  72
  73 my ($ro_home, $cfg_path) = setup_public_inboxes;
  74 test_lei(sub {
  75         my $home = $ENV{HOME};
  76         my $config_file = "$home/.config/lei/config";
  77         my $store_dir = "$home/.local/share/lei";
  78         lei_ok 'ls-external', \'ls-external on fresh install';
  79         is($lei_out.$lei_err, '', 'ls-external no output, yet');
  80         ok(!-e $config_file && !-e $store_dir,
  81                 'nothing created by ls-external');
  82
  83         ok(!lei('add-external', "$home/nonexistent"),
  84                 "fails on non-existent dir");
  85         like($lei_err, qr/not a directory/, 'noted non-existence');
  86         mkdir "$home/new\nline" or BAIL_OUT "mkdir: $!";
  87         ok(!lei('add-external', "$home/new\nline"), "fails on newline");
  88         like($lei_err, qr/`\\n' not allowed/, 'newline noted in error');
  89         lei_ok('ls-external', \'ls-external works after add failure');
  90         is($lei_out.$lei_err, '', 'ls-external still has no output');
  91         my $cfg = PublicInbox::Config->new($cfg_path);
  92         $cfg->each_inbox(sub {
  93                 my ($ibx) = @_;
  94                 lei_ok(qw(add-external -q), $ibx->{inboxdir},
  95                                 \'added external');
  96                 is($lei_out.$lei_err, '', 'no output');
  97         });
  98         ok(-s $config_file, 'add-external created config');
  99         my $lcfg = PublicInbox::Config->new($config_file);
 100         $cfg->each_inbox(sub {
 101                 my ($ibx) = @_;
 102                 is($lcfg->{"external.$ibx->{inboxdir}.boost"}, 0,
 103                         "configured boost on $ibx->{name}");
 104         });
 105         lei_ok 'ls-external';
 106         like($lei_out, qr/boost=0\n/s, 'ls-external has output');
 107         lei_ok qw(add-external -q https://EXAMPLE.com/ibx), \'add remote';
 108         is($lei_err, '', 'no warnings after add-external');
 109
 110         {
 111                 lei_ok qw(ls-external --remote);
 112                 my $r_only = +{ map { $_ => 1 } split(/^/m, $lei_out) };
 113                 lei_ok qw(ls-external --local);
 114                 my $l_only = +{ map { $_ => 1 } split(/^/m, $lei_out) };
 115                 lei_ok 'ls-external';
 116                 is_deeply([grep { $l_only->{$_} } keys %$r_only], [],
 117                         'no locals in --remote');
 118                 is_deeply([grep { $r_only->{$_} } keys %$l_only], [],
 119                         'no remotes in --local');
 120                 my $all = +{ map { $_ => 1 } split(/^/m, $lei_out) };
 121                 is_deeply($all, { %$r_only, %$l_only },
 122                                 'default output combines remote + local');
 123                 lei_ok qw(ls-external --remote --local);
 124                 my $both = +{ map { $_ => 1 } split(/^/m, $lei_out) };
 125                 is_deeply($all, $both, '--remote --local == no args');
 126         }
 127
 128         lei_ok qw(_complete lei forget-external), \'complete for externals';
 129         my %comp = map { $_ => 1 } split(/\s+/, $lei_out);
 130         ok($comp{'https://example.com/ibx/'}, 'forget external completion');
 131         my @dirs;
 132         $cfg->each_inbox(sub {
 133                 my ($ibx) = @_;
 134                 push @dirs, $ibx->{inboxdir};
 135                 ok($comp{$ibx->{inboxdir}}, "local $ibx->{name} completion");
 136         });
 137         for my $u (qw(h http https https: https:/ https:// https://e
 138                         https://example https://example. https://example.co
 139                         https://example.com https://example.com/
 140                         https://example.com/i https://example.com/ibx)) {
 141                 lei_ok(qw(_complete lei forget-external), $u,
 142                         \"partial completion for URL $u");
 143                 is($lei_out, "https://example.com/ibx/\n",
 144                         "completed partial URL $u");
 145                 for my $qo (qw(-I --include --exclude --only)) {
 146                         lei_ok(qw(_complete lei q), $qo, $u,
 147                                 \"partial completion for URL q $qo $u");
 148                         is($lei_out, "https://example.com/ibx/\n",
 149                                 "completed partial URL $u on q $qo");
 150                 }
 151         }
 152         lei_ok(qw(_complete lei add-external), 'https://',
 153                 \'add-external hostname completion');
 154         is($lei_out, "https://example.com/\n", 'completed up to hostname');
 155
 156         lei_ok('ls-external');
 157         like($lei_out, qr!https://example\.com/ibx/!s, 'added canonical URL');
 158         is($lei_err, '', 'no warnings on ls-external');
 159         lei_ok(qw(forget-external -q https://EXAMPLE.com/ibx));
 160         lei_ok('ls-external');
 161         unlike($lei_out, qr!https://example\.com/ibx/!s,
 162                 'removed canonical URL');
 163
 164         # do some queries
 165         ok(!lei(qw(q s:prefix -o maildir:/dev/null)), 'bad maildir');
 166         like($lei_err, qr!/dev/null exists and is not a directory!,
 167                 'error shown');
 168         is($? >> 8, 1, 'errored out with exit 1');
 169
 170         ok(!lei(qw(q s:prefix -o), "mboxcl2:$home"), 'bad mbox');
 171         like($lei_err, qr!\Q$home\E exists and is not a writable file!,
 172                 'error shown');
 173         is($? >> 8, 1, 'errored out with exit 1');
 174
 175         ok(!lei(qw(q s:prefix -o Mbox2:/dev/stdout)), 'bad format');
 176         like($lei_err, qr/bad mbox format: mbox2/, 'error shown');
 177         is($? >> 8, 1, 'errored out with exit 1');
 178
 179         # note, on a Bourne shell users should be able to use either:
 180         #       s:"use boolean prefix"
 181         #       "s:use boolean prefix"
 182         # or use single quotes, it should not matter.  Users only need
 183         # to know shell quoting rules, not Xapian quoting rules.
 184         # No double-quoting should be imposed on users on the CLI
 185         lei_ok('q', 's:use boolean prefix');
 186         like($lei_out, qr/search: use boolean prefix/,
 187                 'phrase search got result');
 188         my $res = json_utf8->decode($lei_out);
 189         is(scalar(@$res), 2, 'only 2 element array (1 result)');
 190         is($res->[1], undef, 'final element is undef'); # XXX should this be?
 191         is(ref($res->[0]), 'HASH', 'first element is hashref');
 192         lei_ok('q', '--pretty', 's:use boolean prefix');
 193         my $pretty = json_utf8->decode($lei_out);
 194         is_deeply($res, $pretty, '--pretty is identical after decode');
 195
 196         {
 197                 open my $fh, '+>', undef or BAIL_OUT $!;
 198                 $fh->autoflush(1);
 199                 print $fh 's:use d:..5.days.from.now' or BAIL_OUT $!;
 200                 seek($fh, 0, SEEK_SET) or BAIL_OUT $!;
 201                 lei_ok([qw(q -q --stdin)], undef, { %$lei_opt, 0 => $fh },
 202                                 \'--stdin on regular file works');
 203                 like($lei_out, qr/use boolean/, '--stdin on regular file');
 204         }
 205         {
 206                 pipe(my ($r, $w)) or BAIL_OUT $!;
 207                 print $w 's:use' or BAIL_OUT $!;
 208                 close $w or BAIL_OUT $!;
 209                 lei_ok([qw(q -q --stdin)], undef, { %$lei_opt, 0 => $r },
 210                                 \'--stdin on pipe file works');
 211                 like($lei_out, qr/use boolean prefix/, '--stdin on pipe');
 212         }
 213         ok(!lei(qw(q -q --stdin s:use)), "--stdin and argv don't mix");
 214
 215         for my $fmt (qw(ldjson ndjson jsonl)) {
 216                 lei_ok('q', '-f', $fmt, 's:use boolean prefix');
 217                 is($lei_out, json_utf8->encode($pretty->[0])."\n", "-f $fmt");
 218         }
 219
 220         require IO::Uncompress::Gunzip;
 221         for my $sfx ('', '.gz') {
 222                 my $f = "$home/mbox$sfx";
 223                 lei_ok('q', '-o', "mboxcl2:$f", 's:use boolean prefix');
 224                 my $cat = $sfx eq '' ? sub {
 225                         open my $mb, '<', $f or fail "no mbox: $!";
 226                         <$mb>
 227                 } : sub {
 228                         my $z = IO::Uncompress::Gunzip->new($f, MultiStream=>1);
 229                         <$z>;
 230                 };
 231                 my @s = grep(/^Subject:/, $cat->());
 232                 is(scalar(@s), 1, "1 result in mbox$sfx");
 233                 lei_ok('q', '-a', '-o', "mboxcl2:$f", 's:see attachment');
 234                 is(grep(!/^#/, $lei_err), 0, 'no errors from augment') or
 235                         diag $lei_err;
 236                 @s = grep(/^Subject:/, my @wtf = $cat->());
 237                 is(scalar(@s), 2, "2 results in mbox$sfx");
 238
 239                 lei_ok('q', '-a', '-o', "mboxcl2:$f", 's:nonexistent');
 240                 is(grep(!/^#/, $lei_err), 0, "no errors on no results ($sfx)")
 241                         or diag $lei_err;
 242
 243                 my @s2 = grep(/^Subject:/, $cat->());
 244                 is_deeply(\@s2, \@s,
 245                         "same 2 old results w/ --augment and bad search $sfx");
 246
 247                 lei_ok('q', '-o', "mboxcl2:$f", 's:nonexistent');
 248                 my @res = $cat->();
 249                 is_deeply(\@res, [], "clobber w/o --augment $sfx");
 250         }
 251         ok(!lei('q', '-o', "$home/mbox", 's:nope'),
 252                         'fails if mbox format unspecified');
 253         ok(!lei(qw(q --no-local s:see)), '--no-local');
 254         is($? >> 8, 1, 'proper exit code');
 255         like($lei_err, qr/no local or remote.+? to search/, 'no inbox');
 256
 257         for my $no (['--no-local'], ['--no-external'],
 258                         [qw(--no-local --no-external)]) {
 259                 lei_ok(qw(q mid:testmessage@example.com), @$no,
 260                         '-I', $dirs[0], \"-I and @$no combine");
 261                 $res = json_utf8->decode($lei_out);
 262                 is($res->[0]->{'m'}, 'testmessage@example.com',
 263                         "-I \$DIR got results regardless of @$no");
 264         }
 265
 266         {
 267                 skip 'TEST_LEI_DAEMON_PERSIST_DIR in use', 1 if
 268                                         $ENV{TEST_LEI_DAEMON_PERSIST_DIR};
 269                 my @q = qw(q -o mboxcl2:rel.mboxcl2 bye);
 270                 lei_ok('-C', $home, @q);
 271                 is(unlink("$home/rel.mboxcl2"), 1, '-C works before q');
 272
 273                 # we are more flexible than git, here:
 274                 lei_ok(@q, '-C', $home);
 275                 is(unlink("$home/rel.mboxcl2"), 1, '-C works after q');
 276                 mkdir "$home/deep" or BAIL_OUT $!;
 277                 lei_ok('-C', $home, @q, '-C', 'deep');
 278                 is(unlink("$home/deep/rel.mboxcl2"), 1, 'multiple -C works');
 279
 280                 lei_ok('-C', '', '-C', $home, @q, '-C', 'deep', '-C', '');
 281                 is(unlink("$home/deep/rel.mboxcl2"), 1, "-C '' accepted");
 282                 ok(!-f "$home/rel.mboxcl2", 'wrong path not created');
 283         }
 284         my %e = (
 285                 TEST_LEI_EXTERNAL_HTTPS => 'https://public-inbox.org/meta/',
 286                 TEST_LEI_EXTERNAL_ONION => $onions[int(rand(scalar(@onions)))],
 287         );
 288         for my $k (keys %e) {
 289                 my $url = $ENV{$k} // '';
 290                 $url = $e{$k} if $url eq '1';
 291                 $test_external_remote->($url, $k);
 292         }
 293 }); # test_lei
 294 done_testing;